matita/matita/contribs/lambdadelta/delayed_updating/reduction/dfr_ifr.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "delayed_updating/reduction/dfr.ma".
  16 include "delayed_updating/reduction/ifr.ma".
  17
  18 include "delayed_updating/unwind/unwind2_constructors.ma".
  19 include "delayed_updating/unwind/unwind2_preterm_fsubst.ma".
  20 include "delayed_updating/unwind/unwind2_preterm_eq.ma".
  21 include "delayed_updating/unwind/unwind2_rmap_head.ma".
  22
  23 include "delayed_updating/substitution/fsubst_eq.ma".
  24
  25 include "delayed_updating/syntax/prototerm_proper_constructors.ma".
  26 include "delayed_updating/syntax/path_head_structure.ma".
  27 include "delayed_updating/syntax/path_structure_depth.ma".
  28 include "delayed_updating/syntax/path_structure_reverse.ma".
  29 include "delayed_updating/syntax/path_depth_reverse.ma".
  30
  31 (* DELAYED FOCUSED REDUCTION ************************************************)
  32
  33 (* Main destructions with ifr ***********************************************)
  34
  35 theorem dfr_des_ifr (f) (p) (q) (t1) (t2): t1 ϵ 𝐓 →
  36         t1 ➡𝐝𝐟[p,q] t2 → ▼[f]t1 ➡𝐟[⊗p,⊗q] ▼[f]t2.
  37 #f #p #q #t1 #t2 #H0t1
  38 * #n * #H1n #Ht1 #Ht2
  39 @(ex_intro … (↑♭q)) @and3_intro
  40 [ -H0t1 -Ht1 -Ht2
  41   >structure_L_sn >structure_reverse
  42   >H1n >path_head_structure_depth <H1n -H1n //
  43 | lapply (in_comp_unwind2_path_term f … Ht1) -Ht2 -Ht1 -H0t1
  44   <unwind2_path_d_dx
  45   >list_append_rcons_sn in H1n; <reverse_append #H1n
  46   lapply (unwind2_rmap_append_pap_closed f … H1n)
  47   <reverse_lcons <depth_L_dx #H2n
  48   lapply (eq_inv_ninj_bi … H2n) -H2n #H2n <H2n -H2n -H1n #Ht1 //
  49 | lapply (unwind2_term_eq_repl_dx f … Ht2) -Ht2 #Ht2
  50   @(subset_eq_trans … Ht2) -t2
  51   @(subset_eq_trans … (unwind2_term_fsubst …))
  52   [ @fsubst_eq_repl [ // | // ]
  53     @(subset_eq_trans … (unwind2_term_iref …))
  54     @(subset_eq_canc_sn … (unwind2_term_eq_repl_dx …))
  55     [ @unwind2_term_grafted_S /2 width=2 by ex_intro/ | skip ] -Ht1
  56     @(subset_eq_trans … (unwind2_term_after …))
  57     @unwind2_term_eq_repl_sn
  58 (* Note: crux of the proof begins *)
  59     @nstream_eq_inv_ext #m
  60     <tr_compose_pap <tr_compose_pap
  61     <tr_uni_pap <tr_uni_pap <tr_pap_plus
  62     >list_append_rcons_sn in H1n; <reverse_append #H1n
  63     lapply (unwind2_rmap_append_pap_closed f … H1n) #H2n
  64     >nrplus_inj_dx in ⊢ (???%); <H2n -H2n
  65     lapply (tls_unwind2_rmap_append_closed f … H1n) -H1n #H2n
  66     <(tr_pap_eq_repl … H2n) -H2n //
  67 (* Note: crux of the proof ends *)
  68   | //
  69   | /2 width=2 by ex_intro/
  70   | //
  71   ]
  72 ]
  73 qed.