matita/matita/contribs/lambdadelta/delayed_updating/reduction/ibfr_constructors.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "delayed_updating/reduction/ibfr.ma".
  16 include "delayed_updating/substitution/fsubst_constructors.ma".
  17 include "delayed_updating/substitution/fsubst_eq.ma".
  18 include "delayed_updating/substitution/lift_prototerm_eq.ma".
  19 include "delayed_updating/syntax/prototerm_constructors_eq.ma".
  20
  21 (* IMMEDIATE BALANCED FOCUSED REDUCTION *************************************)
  22
  23 (* Constructions with constructors for prototerm ****************************)
  24
  25 lemma ibfr_abst_hd (t1) (t2) (r):
  26       t1 ➡𝐢𝐛𝐟[r] t2 → 𝛌.t1 ➡𝐢𝐛𝐟[𝗟◗r] 𝛌.t2.
  27 #t1 #t2 #r *
  28 #p #b #q #m #n #Hr #Hb #Hm #Hn #Ht1 #Ht2 destruct
  29 @(ex6_5_intro … (𝗟◗p) … Hb Hm Hn) -Hb -Hm -Hn
  30 [ -Ht2 //
  31 | -Ht2 /2 width=1 by in_comp_abst_hd/
  32 | @(subset_eq_trans … (abst_eq_repl … Ht2)) -Ht1 -Ht2
  33   @(subset_eq_canc_sn … (fsubst_abst_hd …)) @abst_eq_repl
  34   @fsubst_eq_repl // @lift_term_eq_repl_dx
  35   >list_cons_shift @(subset_eq_canc_sn … (grafted_abst_hd … )) //
  36 ]
  37 qed.
  38
  39 lemma ibfr_appl_hd (v) (t1) (t2) (r):
  40       t1 ➡𝐢𝐛𝐟[r] t2 → ＠v.t1 ➡𝐢𝐛𝐟[𝗔◗r] ＠v.t2.
  41 #v #t1 #t2 #r *
  42 #p #b #q #m #n #Hr #Hb #Hm #Hn #Ht1 #Ht2 destruct
  43 @(ex6_5_intro … (𝗔◗p) … Hb Hm Hn) -Hb -Hm -Hn
  44 [ -Ht2 //
  45 | -Ht2 /2 width=1 by in_comp_appl_hd/
  46 | @(subset_eq_trans … (appl_eq_repl … Ht2)) -Ht1 -Ht2 [|*: // ]
  47   @(subset_eq_canc_sn … (fsubst_appl_hd …)) @appl_eq_repl [ // ]
  48   @fsubst_eq_repl // @lift_term_eq_repl_dx
  49   >list_cons_shift @(subset_eq_canc_sn … (grafted_appl_hd … )) //
  50 ]
  51 qed.
  52
  53 lemma ibfr_appl_sd (v1) (v2) (t) (r):
  54       v1 ➡𝐢𝐛𝐟[r] v2 → ＠v1.t ➡𝐢𝐛𝐟[𝗦◗r] ＠v2.t.
  55 #v1 #v2 #t #r *
  56 #p #b #q #m #n #Hr #Hb #Hm #Hn #Hv1 #Hv2 destruct
  57 @(ex6_5_intro … (𝗦◗p) … Hb Hm Hn) -Hb -Hm -Hn
  58 [ -Hv2 //
  59 | -Hv2 /2 width=1 by in_comp_appl_sd/
  60 | @(subset_eq_trans ????? (appl_eq_repl …)) [3: @Hv2 |2,4: // |5: skip ]
  61   @(subset_eq_canc_sn … (fsubst_appl_sd …)) @appl_eq_repl [| // ]
  62   @fsubst_eq_repl // @lift_term_eq_repl_dx
  63   >list_cons_shift @(subset_eq_canc_sn … (grafted_appl_sd … )) //
  64 ]
  65 qed.
  66
  67 lemma ibfr_beta_0 (v) (t) (q) (n):
  68       q ϵ 𝐂❨Ⓕ,n❩ → q◖𝗱↑n ϵ t →
  69       ＠v.𝛌.t ➡𝐢𝐛𝐟[𝗔◗𝗟◗q] ＠v.𝛌.(t[⋔q←🠡[𝐮❨↑n❩]v]).
  70 #v #t #q #n #Hn #Ht
  71 @(ex6_5_intro … (𝐞) (𝐞) q (𝟎) … Hn) -Hn //
  72 [ /3 width=1 by in_comp_appl_hd, in_comp_abst_hd/
  73 | @(subset_eq_canc_sn … (fsubst_appl_hd …)) @appl_eq_repl [ // ]
  74   @(subset_eq_canc_sn … (fsubst_abst_hd …)) @abst_eq_repl
  75   @fsubst_eq_repl // <nplus_zero_sn @lift_term_eq_repl_dx
  76   >list_cons_comm @(subset_eq_canc_sn … (grafted_appl_sd … ))
  77   @(subset_eq_canc_sn … (grafted_empty_dx … )) //
  78 ]
  79 qed.