matita/matita/contribs/lambdadelta/delayed_updating/reduction/ibfr_unwind.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "delayed_updating/reduction/ibfr.ma".
  16
  17 include "delayed_updating/unwind/unwind2_preterm_fsubst.ma".
  18 include "delayed_updating/unwind/unwind2_preterm_eq.ma".
  19 include "delayed_updating/unwind/unwind2_prototerm_lift.ma".
  20 include "delayed_updating/unwind/unwind2_rmap_closed.ma".
  21
  22 include "delayed_updating/substitution/fsubst_eq.ma".
  23 include "delayed_updating/substitution/lift_prototerm_eq.ma".
  24
  25 include "delayed_updating/syntax/path_closed_structure.ma".
  26 include "delayed_updating/syntax/path_structure_depth.ma".
  27
  28 (* IMMEDIATE BALANCED FOCUSED REDUCTION *************************************)
  29
  30 (* Constructions with unwind2 ***********************************************)
  31
  32 lemma ibfr_unwind_bi (f) (t1) (t2) (r):
  33       t1 ϵ 𝐓 → r ϵ 𝐈 →
  34       t1 ➡𝐢𝐛𝐟[r] t2 → ▼[f]t1 ➡𝐢𝐛𝐟[⊗r] ▼[f]t2.
  35 #f #t1 #t2 #r #H1t1 #H2r
  36 * #p #b #q #m #n #Hr #Hb #Hm #Hn #Ht1 #Ht2 destruct
  37 @(ex6_5_intro … (⊗p) (⊗b) (⊗q) (♭b) (♭q))
  38 [ -H1t1 -H2r -Hb -Hm -Hn -Ht1 -Ht2 //
  39 | -H1t1 -H2r -Hm -Hn -Ht1 -Ht2 //
  40 | -H1t1 -H2r -Hb -Hn -Ht1 -Ht2
  41   /2 width=2 by path_closed_structure_depth/
  42 | -H1t1 -H2r -Hb -Hm -Ht1 -Ht2
  43   /2 width=2 by path_closed_structure_depth/
  44 | lapply (in_comp_unwind2_path_term f … Ht1) -Ht2 -Ht1 -H1t1 -H2r -Hb
  45   <unwind2_path_d_dx <tr_pap_succ_nap <list_append_rcons_sn >list_append_assoc
  46   <nap_unwind2_rmap_append_closed_Lq_dx_depth //
  47 | lapply (unwind2_term_eq_repl_dx f … Ht2) -Ht2 #Ht2
  48   @(subset_eq_trans … Ht2) -t2
  49   @(subset_eq_trans … (unwind2_term_fsubst_pic …))
  50   [ @fsubst_eq_repl [ // | // ]
  51     @(subset_eq_canc_sn … (lift_term_eq_repl_dx …))
  52     [ @unwind2_term_grafted_S /2 width=2 by ex_intro/ | skip ] -Ht1
  53     @(subset_eq_trans … (lift_unwind2_term_after …))
  54     @(subset_eq_canc_dx … (unwind2_lift_term_after …))
  55     @unwind2_term_eq_repl_sn
  56 (* Note: crux of the proof begins *)
  57     <list_append_rcons_sn
  58     @(stream_eq_trans … (tr_compose_uni_dx_pap …)) <tr_pap_succ_nap
  59     @tr_compose_eq_repl
  60     [ <nap_plus_unwind2_rmap_append_closed_bLq_dx_depth //
  61     | >unwind2_rmap_A_dx
  62       /2 width=2 by tls_succ_plus_unwind2_rmap_append_closed_bLq_dx/
  63     ]
  64 (* Note: crux of the proof ends *)
  65   | //
  66   | /2 width=2 by ex_intro/
  67   | //
  68   ]
  69 ]
  70 qed.