matita/matita/contribs/lambdadelta/delayed_updating/reduction/ifr_unwind.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "delayed_updating/reduction/ifr.ma".
  16
  17 include "delayed_updating/unwind/unwind2_preterm_fsubst.ma".
  18 include "delayed_updating/unwind/unwind2_preterm_eq.ma".
  19 include "delayed_updating/unwind/unwind2_prototerm_lift.ma".
  20 include "delayed_updating/unwind/unwind2_rmap_closed.ma".
  21
  22 include "delayed_updating/substitution/fsubst_eq.ma".
  23 include "delayed_updating/substitution/lift_prototerm_eq.ma".
  24
  25 include "delayed_updating/syntax/path_closed_structure.ma".
  26 include "delayed_updating/syntax/path_structure_depth.ma".
  27
  28 (* IMMEDIATE FOCUSED REDUCTION **********************************************)
  29
  30 (* Constructions with unwind2 ***********************************************)
  31
  32 lemma ifr_unwind_bi (f) (t1) (t2) (r):
  33       t1 ϵ 𝐓 → r ϵ 𝐈 →
  34       t1 ➡𝐢𝐟[r] t2 → ▼[f]t1 ➡𝐢𝐟[⊗r] ▼[f]t2.
  35 #f #t1 #t2 #r #H1t1 #H2r
  36 * #p #q #n #Hr #Hn #Ht1 #Ht2 destruct
  37 @(ex4_3_intro … (⊗p) (⊗q) (♭q))
  38 [ -H1t1 -H2r -Hn -Ht1 -Ht2 //
  39 | -H1t1 -H2r -Ht1 -Ht2
  40   /2 width=2 by path_closed_structure_depth/
  41 | lapply (in_comp_unwind2_path_term f … Ht1) -Ht2 -Ht1 -H1t1 -H2r
  42   <unwind2_path_d_dx <tr_pap_succ_nap <list_append_rcons_sn
  43   <unwind2_rmap_append_closed_nap //
  44 | lapply (unwind2_term_eq_repl_dx f … Ht2) -Ht2 #Ht2
  45   @(subset_eq_trans … Ht2) -t2
  46   @(subset_eq_trans … (unwind2_term_fsubst_pic …))
  47   [ @fsubst_eq_repl [ // | // ]
  48     @(subset_eq_canc_sn … (lift_term_eq_repl_dx …))
  49     [ @unwind2_term_grafted_S /2 width=2 by ex_intro/ | skip ] -Ht1
  50     @(subset_eq_trans … (lift_unwind2_term_after …))
  51     @(subset_eq_canc_dx … (unwind2_lift_term_after …))
  52     @unwind2_term_eq_repl_sn
  53 (* Note: crux of the proof begins *)
  54     <list_append_rcons_sn
  55     @(stream_eq_trans … (tr_compose_uni_dx_pap …)) <tr_pap_succ_nap
  56     @tr_compose_eq_repl
  57     [ <unwind2_rmap_append_closed_nap //
  58     | /2 width=1 by tls_succ_unwind2_rmap_append_L_closed_dx/
  59     ]
  60 (* Note: crux of the proof ends *)
  61   | //
  62   | /2 width=2 by ex_intro/
  63   | //
  64   ]
  65 ]
  66 qed.