matita/matita/contribs/lambdadelta/delayed_updating/reduction/ifr_unwind.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "delayed_updating/reduction/ifr.ma".
  16
  17 include "delayed_updating/unwind/unwind2_constructors.ma".
  18 include "delayed_updating/unwind/unwind2_preterm_fsubst.ma".
  19 include "delayed_updating/unwind/unwind2_preterm_eq.ma".
  20 include "delayed_updating/unwind/unwind2_prototerm_inner.ma".
  21 include "delayed_updating/unwind/unwind2_rmap_head.ma".
  22
  23 include "delayed_updating/substitution/fsubst_eq.ma".
  24
  25 include "delayed_updating/syntax/prototerm_proper_inner.ma".
  26 include "delayed_updating/syntax/path_head_structure.ma".
  27 include "delayed_updating/syntax/path_structure_depth.ma".
  28 include "delayed_updating/syntax/path_structure_reverse.ma".
  29 include "delayed_updating/syntax/path_depth_reverse.ma".
  30
  31 (* IMMEDIATE FOCUSED REDUCTION **********************************************)
  32
  33 (* Constructions with unwind ************************************************)
  34
  35 theorem ifr_unwind_bi (f) (p) (q) (t1) (t2):
  36         t1 ϵ 𝐓 → t1⋔(p◖𝗦) ⧸≬ 𝐈 →
  37         t1 ➡𝐟[p,q] t2 → ▼[f]t1 ➡𝐟[⊗p,⊗q] ▼[f]t2.
  38 #f #p #q #t1 #t2 #H1t1 #H2t1
  39 * #n * #H1n #Ht1 #Ht2
  40 @(ex_intro … (↑♭q)) @and3_intro
  41 [ -H1t1 -H2t1 -Ht1 -Ht2
  42   >structure_L_sn >structure_reverse
  43   >H1n >path_head_structure_depth <H1n -H1n //
  44 | lapply (in_comp_unwind2_path_term f … Ht1) -Ht2 -Ht1 -H1t1 -H2t1
  45   <unwind2_path_d_dx
  46   >list_append_rcons_sn in H1n; <reverse_append #H1n
  47   lapply (unwind2_rmap_append_pap_closed f … H1n)
  48   <reverse_lcons <depth_L_dx #H2n
  49   lapply (eq_inv_ninj_bi … H2n) -H2n #H2n <H2n -H2n -H1n #Ht1 //
  50 | lapply (unwind2_term_eq_repl_dx f … Ht2) -Ht2 #Ht2
  51   @(subset_eq_trans … Ht2) -t2
  52   @(subset_eq_trans … (unwind2_term_fsubst …))
  53   [ @fsubst_eq_repl [ // | // ]
  54     @(subset_eq_canc_dx … (unwind2_term_after …))
  55     @(subset_eq_canc_sn … (unwind2_term_eq_repl_dx …))
  56     [ @unwind2_term_grafted_S /2 width=2 by ex_intro/ | skip ] -Ht1
  57     @(subset_eq_trans … (unwind2_term_after …))
  58     @unwind2_term_eq_repl_sn
  59 (* Note: crux of the proof begins *)
  60     @nstream_eq_inv_ext #m
  61     <tr_compose_pap <tr_compose_pap
  62     <tr_uni_pap <tr_uni_pap <tr_pap_plus
  63     >list_append_rcons_sn in H1n; <reverse_append #H1n
  64     lapply (unwind2_rmap_append_pap_closed f … H1n) #H2n
  65     >nrplus_inj_dx in ⊢ (???%); <H2n -H2n
  66     lapply (tls_unwind2_rmap_append_closed f … H1n) -H1n #H2n
  67     <(tr_pap_eq_repl … H2n) -H2n //
  68 (* Note: crux of the proof ends *)
  69   | //
  70   | /2 width=2 by ex_intro/
  71   | @term_proper_outer #H0 (**) (* full auto does not work *)
  72     /3 width=2 by unwind2_term_des_inner/
  73   ]
  74 ]
  75 qed.