matita/matita/contribs/lambdadelta/delayed_updating/substitution/lift_constructors.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "delayed_updating/substitution/lift_prototerm_id.ma".
  16 include "delayed_updating/substitution/lift_path_uni.ma".
  17 include "delayed_updating/syntax/prototerm_constructors_eq.ma".
  18
  19 (* LIFT FOR PROTOTERM *******************************************************)
  20
  21 lemma lift_term_iref_sn (f) (t:prototerm) (k:pnat):
  22       (𝛕f＠⧣❨k❩.↑[⇂*[k]f]t) ⊆ ↑[f](𝛕k.t).
  23 #f #t #k #p * #q * #r #Hr #H1 #H2 destruct
  24 @(ex2_intro … (𝗱k◗𝗺◗r))
  25 /2 width=1 by in_comp_iref/
  26 qed-.
  27
  28 lemma lift_term_iref_dx (f) (t) (k:pnat):
  29       ↑[f](𝛕k.t) ⊆ 𝛕f＠⧣❨k❩.↑[⇂*[k]f]t.
  30 #f #t #k #p * #q #Hq #H0 destruct
  31 elim (in_comp_inv_iref … Hq) -Hq #p #H0 #Hp destruct
  32 <lift_path_d_sn <lift_path_m_sn
  33 /3 width=1 by in_comp_iref, in_comp_lift_path_term/
  34 qed-.
  35
  36 lemma lift_term_iref (f) (t) (k:pnat):
  37       (𝛕f＠⧣❨k❩.↑[⇂*[k]f]t) ⇔ ↑[f](𝛕k.t).
  38 /3 width=1 by conj, lift_term_iref_sn, lift_term_iref_dx/
  39 qed.
  40
  41 lemma lift_term_iref_uni (t) (n) (k):
  42       (𝛕(k+n).t) ⇔ ↑[𝐮❨n❩](𝛕k.t).
  43 #t #n #k
  44 @(subset_eq_trans … (lift_term_iref …))
  45 <tr_uni_pap >nsucc_pnpred <tr_tls_succ_uni
  46 /3 width=1 by iref_eq_repl, lift_term_id/
  47 qed.