matita/matita/contribs/lambdadelta/delayed_updating/substitution/lift_constructors.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "delayed_updating/substitution/lift_prototerm_id.ma".
  16 include "delayed_updating/substitution/lift_path_uni.ma".
  17 include "delayed_updating/syntax/prototerm_constructors_eq.ma".
  18 include "ground/relocation/nap.ma".
  19
  20 (* LIFT FOR PROTOTERM *******************************************************)
  21
  22 lemma lift_term_iref_pap_sn (f) (t:prototerm) (k:pnat):
  23       (𝛕f＠⧣❨k❩.↑[⇂*[k]f]t) ⊆ ↑[f](𝛕k.t).
  24 #f #t #k #p * #q * #r #Hr #H1 #H2 destruct
  25 @(ex2_intro … (𝗱k◗𝗺◗r))
  26 /2 width=1 by in_comp_iref/
  27 qed-.
  28
  29 lemma lift_term_iref_pap_dx (f) (t) (k:pnat):
  30       ↑[f](𝛕k.t) ⊆ 𝛕f＠⧣❨k❩.↑[⇂*[k]f]t.
  31 #f #t #k #p * #q #Hq #H0 destruct
  32 elim (in_comp_inv_iref … Hq) -Hq #p #H0 #Hp destruct
  33 <lift_path_d_sn <lift_path_m_sn
  34 /3 width=1 by in_comp_iref, in_comp_lift_path_term/
  35 qed-.
  36
  37 lemma lift_term_iref_pap (f) (t) (k:pnat):
  38       (𝛕f＠⧣❨k❩.↑[⇂*[k]f]t) ⇔ ↑[f](𝛕k.t).
  39 /3 width=1 by conj, lift_term_iref_pap_sn, lift_term_iref_pap_dx/
  40 qed.
  41
  42 lemma lift_term_iref_nap (f) (t) (n):
  43       (𝛕↑(f＠§❨n❩).↑[⇂*[↑n]f]t) ⇔ ↑[f](𝛕↑n.t).
  44 #f #t #n
  45 >tr_pap_succ_nap //
  46 qed.
  47
  48 lemma lift_term_iref_uni (t) (n) (k):
  49       (𝛕(k+n).t) ⇔ ↑[𝐮❨n❩](𝛕k.t).
  50 #t #n #k
  51 @(subset_eq_trans … (lift_term_iref_pap …))
  52 <tr_uni_pap >nsucc_pnpred <tr_tls_succ_uni
  53 /3 width=1 by iref_eq_repl, lift_term_id/
  54 qed.