matita/matita/contribs/lambdadelta/delayed_updating/substitution/lift_constructors.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/relocation/tr_compose_compose.ma".
  16 include "ground/relocation/tr_compose_pn.ma".
  17 include "delayed_updating/substitution/lift_eq.ma".
  18
  19 lemma lift_path_after (p) (f1) (f2):
  20       ↑[f2]↑[f1]p = ↑[f2∘f1]p.
  21 #p @(path_ind_lift … p) -p // [ #n #l #p | #p ] #IH #f1 #f2
  22 [ <lift_path_d_lcons_sn <lift_path_d_lcons_sn
  23   >(lift_path_eq_repl … (tr_compose_assoc …)) //
  24 | <lift_path_L_sn <lift_path_L_sn <lift_path_L_sn
  25   >tr_compose_push_bi //
  26 ]
  27 qed.
  28
  29 include "delayed_updating/substitution/lift_prototerm.ma".
  30
  31 axiom lift_term_after (t) (f1) (f2):
  32       ↑[f2]↑[f1]t ⇔ ↑[f2∘f1]t.
  33
  34 include "delayed_updating/syntax/prototerm_constructors.ma".
  35
  36 (* LIFT FOR PROTOTERM *******************************************************)
  37
  38 lemma lift_iref_after_sn (f) (t) (n:pnat):
  39       (↑[f∘𝐮❨n❩]t) ⊆ ↑[f](𝛗n.t).
  40 #f #t #n #p * #q #Hq #H0 destruct
  41 @(ex2_intro … (𝗱n◗𝗺◗q))
  42 /2 width=1 by in_comp_iref/
  43 qed-.
  44
  45 lemma lift_iref_after_dx (f) (t) (n:pnat):
  46       ↑[f](𝛗n.t) ⊆ ↑[f∘𝐮❨n❩]t.
  47 #f #t #n #p * #q #Hq #H0 destruct
  48 elim (in_comp_inv_iref … Hq) -Hq #p #Hp #Ht destruct
  49 /2 width=1 by in_comp_lift_bi/
  50 qed-.
  51
  52 lemma lift_iref_after (f) (t) (n:pnat):
  53       ↑[f∘𝐮❨n❩]t ⇔ ↑[f](𝛗n.t).
  54 /3 width=1 by conj, lift_iref_after_sn, lift_iref_after_dx/
  55 qed.
  56
  57 lemma lift_iref (f) (t) (n:pnat):
  58       ↑[f]↑[𝐮❨n❩]t ⇔ ↑[f](𝛗n.t).
  59 /3 width=3 by lift_term_after, subset_eq_trans/
  60 qed.