matita/matita/contribs/lambdadelta/delayed_updating/substitution/lift_eq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "delayed_updating/substitution/lift.ma".
  16 include "ground/relocation/tr_pap_eq.ma".
  17 include "ground/relocation/tr_pn_eq.ma".
  18
  19 (* LIFT FOR PATH ***********************************************************)
  20
  21 definition lift_exteq (A): relation2 (lift_continuation A) (lift_continuation A) ≝
  22            λk1,k2. ∀f1,f2,p. f1 ≗ f2 → k1 f1 p = k2 f2 p.
  23
  24 interpretation
  25   "extensional equivalence (lift continuation)"
  26   'RingEq A k1 k2 = (lift_exteq A k1 k2).
  27
  28 (* Constructions with lift_exteq ********************************************)
  29
  30 lemma lift_eq_repl (A) (p) (k1) (k2):
  31       k1 ≗{A} k2 → stream_eq_repl … (λf1,f2. ↑❨k1, f1, p❩ = ↑❨k2, f2, p❩).
  32 #A #p elim p -p [| * [ #n ] #q #IH ]
  33 #k1 #k2 #Hk #f1 #f2 #Hf
  34 [ <lift_empty <lift_empty /2 width=1 by/
  35 | <lift_d_sn <lift_d_sn <(tr_pap_eq_repl … Hf)
  36   /3 width=1 by stream_eq_refl/
  37 | /3 width=1 by/
  38 | /3 width=1 by tr_push_eq_repl/
  39 | /3 width=1 by/
  40 | /3 width=1 by/
  41 ]
  42 qed-.
  43
  44 (* Advanced constructions ***************************************************)
  45
  46 lemma lift_lcons_alt (A) (k) (f) (p) (l): k ≗ k →
  47       ↑❨λg,p2. k g (l◗p2), f, p❩ = ↑{A}❨λg,p2. k g ((l◗𝐞)●p2), f, p❩.
  48 #A #k #f #p #l #Hk
  49 @lift_eq_repl // #g1 #g2 #p2 #Hg @Hk -Hk // (**) (* auto fail *)
  50 qed.
  51
  52 lemma lift_append_rcons_sn (A) (k) (f) (p1) (p) (l): k ≗ k →
  53       ↑❨λg,p2. k g (p1●l◗p2), f, p❩ = ↑{A}❨λg,p2. k g (p1◖l●p2), f, p❩.
  54 #A #k #f #p1 #p #l #Hk
  55 @lift_eq_repl // #g1 #g2 #p2 #Hg
  56 <list_append_rcons_sn @Hk -Hk // (**) (* auto fail *)
  57 qed.
  58
  59 (* Advanced constructions with proj_path ************************************)
  60
  61 lemma proj_path_proper:
  62       proj_path ≗ proj_path.
  63 // qed.
  64
  65 lemma lift_path_eq_repl (p):
  66       stream_eq_repl … (λf1,f2. ↑[f1]p = ↑[f2]p).
  67 /2 width=1 by lift_eq_repl/ qed.
  68
  69 lemma lift_path_append_sn (p) (f) (q):
  70       q●↑[f]p = ↑❨(λg,p. proj_path g (q●p)), f, p❩.
  71 #p elim p -p // * [ #n ] #p #IH #f #q
  72 [ <lift_d_sn <lift_d_sn
  73 | <lift_m_sn <lift_m_sn
  74 | <lift_L_sn <lift_L_sn
  75 | <lift_A_sn <lift_A_sn
  76 | <lift_S_sn <lift_S_sn
  77 ]
  78 >lift_lcons_alt // >lift_append_rcons_sn //
  79 <IH <IH -IH <list_append_rcons_sn //
  80 qed.
  81
  82 lemma lift_path_lcons (f) (p) (l):
  83       l◗↑[f]p = ↑❨(λg,p. proj_path g (l◗p)), f, p❩.
  84 #f #p #l
  85 >lift_lcons_alt <lift_path_append_sn //
  86 qed.
  87
  88 lemma lift_path_d_sn (f) (p) (n):
  89       (𝗱(f@❨n❩)◗↑[𝐢]p) = ↑[f](𝗱n◗p).
  90 // qed.
  91
  92 lemma lift_path_m_sn (f) (p):
  93       (𝗺◗↑[f]p) = ↑[f](𝗺◗p).
  94 // qed.
  95
  96 lemma lift_path_L_sn (f) (p):
  97       (𝗟◗↑[⫯f]p) = ↑[f](𝗟◗p).
  98 // qed.
  99
 100 lemma lift_path_A_sn (f) (p):
 101       (𝗔◗↑[f]p) = ↑[f](𝗔◗p).
 102 // qed.
 103
 104 lemma lift_path_S_sn (f) (p):
 105       (𝗦◗↑[f]p) = ↑[f](𝗦◗p).
 106 // qed.
 107
 108 lemma lift_path_id (p):
 109       p = ↑[𝐢]p.
 110 #p elim p -p //
 111 * [ #n ] #p #IH //
 112 [ <lift_path_d_sn //
 113 | <lift_path_L_sn //
 114 ]
 115 qed.
 116
 117 lemma lift_path_append (p2) (p1) (f):
 118       (↑[f]p1)●(↑[↑[p1]f]p2) = ↑[f](p1●p2).
 119 #p2 #p1 elim p1 -p1 //
 120 * [ #n1 ] #p1 #IH #f
 121 [ <lift_path_d_sn <lift_path_d_sn <IH //
 122 | <lift_path_m_sn <lift_path_m_sn <IH //
 123 | <lift_path_L_sn <lift_path_L_sn <IH //
 124 | <lift_path_A_sn <lift_path_A_sn <IH //
 125 | <lift_path_S_sn <lift_path_S_sn <IH //
 126 ]
 127 qed.
 128
 129 lemma lift_path_d_dx (n) (p) (f):
 130       (↑[f]p)◖𝗱((↑[p]f)@❨n❩) = ↑[f](p◖𝗱n).
 131 #n #p #f <lift_path_append //
 132 qed.
 133
 134 lemma lift_path_m_dx (p) (f):
 135       (↑[f]p)◖𝗺 = ↑[f](p◖𝗺).
 136 #p #f <lift_path_append //
 137 qed.
 138
 139 lemma lift_path_L_dx (p) (f):
 140       (↑[f]p)◖𝗟 = ↑[f](p◖𝗟).
 141 #p #f <lift_path_append //
 142 qed.
 143
 144 lemma lift_path_A_dx (p) (f):
 145       (↑[f]p)◖𝗔 = ↑[f](p◖𝗔).
 146 #p #f <lift_path_append //
 147 qed.
 148
 149 lemma lift_path_S_dx (p) (f):
 150       (↑[f]p)◖𝗦 = ↑[f](p◖𝗦).
 151 #p #f <lift_path_append //
 152 qed.
 153
 154 (* COMMENT
 155
 156 (* Advanced constructions with proj_rmap and stream_tls *********************)
 157
 158 lemma lift_rmap_tls_d_dx (f) (p) (m) (n):
 159       ⇂*[m+n]↑[p]f ≗ ⇂*[m]↑[p◖𝗱n]f.
 160 #f #p #m #n
 161 <lift_rmap_d_dx >nrplus_inj_dx
 162 /2 width=1 by tr_tls_compose_uni_dx/
 163 qed.
 164 *)