matita/matita/contribs/lambdadelta/delayed_updating/substitution/lift_eq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "delayed_updating/substitution/lift.ma".
  16 include "ground/relocation/tr_pap_eq.ma".
  17 include "ground/relocation/tr_pn_eq.ma".
  18 include "ground/lib/stream_tls_eq.ma".
  19
  20 (* LIFT FOR PATH ************************************************************)
  21
  22 definition lift_exteq (A): relation2 (lift_continuation A) (lift_continuation A) ≝
  23            λk1,k2. ∀f1,f2,p. f1 ≗ f2 → k1 f1 p = k2 f2 p.
  24
  25 interpretation
  26   "extensional equivalence (lift continuation)"
  27   'RingEq A k1 k2 = (lift_exteq A k1 k2).
  28
  29 (* Constructions with lift_exteq ********************************************)
  30
  31 lemma lift_eq_repl (A) (p) (k1) (k2):
  32       k1 ≗{A} k2 → stream_eq_repl … (λf1,f2. ↑❨k1, f1, p❩ = ↑❨k2, f2, p❩).
  33 #A #p elim p -p [| * [ #n ] #q #IH ]
  34 #k1 #k2 #Hk #f1 #f2 #Hf
  35 [ <lift_empty <lift_empty /2 width=1 by/
  36 | <lift_d_sn <lift_d_sn <(tr_pap_eq_repl … Hf)
  37   /3 width=3 by stream_tls_eq_repl, compose_repl_fwd_sn/
  38 | /3 width=1 by/
  39 | /3 width=1 by tr_push_eq_repl/
  40 | /3 width=1 by/
  41 | /3 width=1 by/
  42 ]
  43 qed-.
  44
  45 (* Advanced constructions ***************************************************)
  46
  47 lemma lift_lcons_alt (A) (k) (f) (p) (l): k ≗ k →
  48       ↑❨λg,p2. k g (l◗p2), f, p❩ = ↑{A}❨λg,p2. k g ((l◗𝐞)●p2), f, p❩.
  49 #A #k #f #p #l #Hk
  50 @lift_eq_repl // #g1 #g2 #p2 #Hg @Hk -Hk // (**) (* auto fail *)
  51 qed.
  52
  53 lemma lift_append_rcons_sn (A) (k) (f) (p1) (p) (l): k ≗ k →
  54       ↑❨λg,p2. k g (p1●l◗p2), f, p❩ = ↑{A}❨λg,p2. k g (p1◖l●p2), f, p❩.
  55 #A #k #f #p1 #p #l #Hk
  56 @lift_eq_repl // #g1 #g2 #p2 #Hg
  57 <list_append_rcons_sn @Hk -Hk // (**) (* auto fail *)
  58 qed.
  59
  60 (* Advanced constructions with proj_path ************************************)
  61
  62 lemma proj_path_proper:
  63       proj_path ≗ proj_path.
  64 // qed.
  65
  66 lemma lift_path_eq_repl (p):
  67       stream_eq_repl … (λf1,f2. ↑[f1]p = ↑[f2]p).
  68 /2 width=1 by lift_eq_repl/ qed.
  69
  70 lemma lift_path_append_sn (p) (f) (q):
  71       q●↑[f]p = ↑❨(λg,p. proj_path g (q●p)), f, p❩.
  72 #p elim p -p // * [ #n ] #p #IH #f #q
  73 [ <lift_d_sn <lift_d_sn
  74 | <lift_m_sn <lift_m_sn
  75 | <lift_L_sn <lift_L_sn
  76 | <lift_A_sn <lift_A_sn
  77 | <lift_S_sn <lift_S_sn
  78 ]
  79 >lift_lcons_alt // >lift_append_rcons_sn //
  80 <IH <IH -IH <list_append_rcons_sn //
  81 qed.
  82
  83 lemma lift_path_lcons (f) (p) (l):
  84       l◗↑[f]p = ↑❨(λg,p. proj_path g (l◗p)), f, p❩.
  85 #f #p #l
  86 >lift_lcons_alt <lift_path_append_sn //
  87 qed.
  88
  89 lemma lift_path_d_sn (f) (p) (n):
  90       (𝗱(f＠⧣❨n❩)◗↑[⇂*[n]f]p) = ↑[f](𝗱n◗p).
  91 // qed.
  92
  93 lemma lift_path_m_sn (f) (p):
  94       (𝗺◗↑[f]p) = ↑[f](𝗺◗p).
  95 // qed.
  96
  97 lemma lift_path_L_sn (f) (p):
  98       (𝗟◗↑[⫯f]p) = ↑[f](𝗟◗p).
  99 // qed.
 100
 101 lemma lift_path_A_sn (f) (p):
 102       (𝗔◗↑[f]p) = ↑[f](𝗔◗p).
 103 // qed.
 104
 105 lemma lift_path_S_sn (f) (p):
 106       (𝗦◗↑[f]p) = ↑[f](𝗦◗p).
 107 // qed.
 108
 109 lemma lift_path_append (p2) (p1) (f):
 110       (↑[f]p1)●(↑[↑[p1]f]p2) = ↑[f](p1●p2).
 111 #p2 #p1 elim p1 -p1 //
 112 * [ #n1 ] #p1 #IH #f
 113 [ <lift_path_d_sn <lift_path_d_sn <IH //
 114 | <lift_path_m_sn <lift_path_m_sn <IH //
 115 | <lift_path_L_sn <lift_path_L_sn <IH //
 116 | <lift_path_A_sn <lift_path_A_sn <IH //
 117 | <lift_path_S_sn <lift_path_S_sn <IH //
 118 ]
 119 qed.
 120
 121 lemma lift_path_d_dx (f) (p) (n):
 122       (↑[f]p)◖𝗱((↑[p]f)＠⧣❨n❩) = ↑[f](p◖𝗱n).
 123 #f #p #n <lift_path_append //
 124 qed.
 125
 126 lemma lift_path_m_dx (f) (p):
 127       (↑[f]p)◖𝗺 = ↑[f](p◖𝗺).
 128 #f #p <lift_path_append //
 129 qed.
 130
 131 lemma lift_path_L_dx (f) (p):
 132       (↑[f]p)◖𝗟 = ↑[f](p◖𝗟).
 133 #f #p <lift_path_append //
 134 qed.
 135
 136 lemma lift_path_A_dx (f) (p):
 137       (↑[f]p)◖𝗔 = ↑[f](p◖𝗔).
 138 #f #p <lift_path_append //
 139 qed.
 140
 141 lemma lift_path_S_dx (f) (p):
 142       (↑[f]p)◖𝗦 = ↑[f](p◖𝗦).
 143 #f #p <lift_path_append //
 144 qed.
 145
 146 (* COMMENT
 147
 148 (* Advanced constructions with proj_rmap and stream_tls *********************)
 149
 150 lemma lift_rmap_tls_d_dx (f) (p) (m) (n):
 151       ⇂*[m+n]↑[p]f ≗ ⇂*[m]↑[p◖𝗱n]f.
 152 #f #p #m #n
 153 <lift_rmap_d_dx >nrplus_inj_dx
 154 /2 width=1 by tr_tls_compose_uni_dx/
 155 qed.
 156
 157 *)