matita/matita/contribs/lambdadelta/delayed_updating/substitution/lift_gen_eq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "delayed_updating/substitution/lift_gen.ma".
  16 include "ground/relocation/tr_pap_pap.ma".
  17 include "ground/relocation/tr_pap_eq.ma".
  18 include "ground/relocation/tr_pn_eq.ma".
  19 include "ground/lib/stream_tls_plus.ma".
  20 include "ground/lib/stream_tls_eq.ma".
  21 include "ground/arith/nat_plus_rplus.ma".
  22 include "ground/arith/nat_rplus_pplus.ma".
  23
  24 (* LIFT FOR PATH ************************************************************)
  25
  26 definition lift_exteq (A): relation2 (lift_continuation A) (lift_continuation A) ≝
  27            λk1,k2. ∀f1,f2,p. f1 ≗ f2 → k1 f1 p = k2 f2 p.
  28
  29 interpretation
  30   "extensional equivalence (lift continuation)"
  31   'RingEq A k1 k2 = (lift_exteq A k1 k2).
  32
  33 (* Constructions with lift_exteq ********************************************)
  34
  35 lemma lift_eq_repl (A) (p) (k1) (k2):
  36       k1 ≗{A} k2 → stream_eq_repl … (λf1,f2. ↑❨k1, f1, p❩ = ↑❨k2, f2, p❩).
  37 #A #p elim p -p [| * [ #n ] #q #IH ]
  38 #k1 #k2 #Hk #f1 #f2 #Hf
  39 [ <lift_empty <lift_empty /2 width=1 by/
  40 | <lift_d_sn <lift_d_sn <(tr_pap_eq_repl … Hf)
  41   /3 width=3 by stream_tls_eq_repl, compose_repl_fwd_sn/
  42 | /3 width=1 by/
  43 | /3 width=1 by tr_push_eq_repl/
  44 | /3 width=1 by/
  45 | /3 width=1 by/
  46 ]
  47 qed-.
  48
  49 (* Advanced constructions ***************************************************)
  50
  51 lemma lift_lcons_alt (A) (k) (f) (p) (l): k ≗ k →
  52       ↑❨λg,p2. k g (l◗p2), f, p❩ = ↑{A}❨λg,p2. k g ((l◗𝐞)●p2), f, p❩.
  53 #A #k #f #p #l #Hk
  54 @lift_eq_repl // #g1 #g2 #p2 #Hg @Hk -Hk // (**) (* auto fail *)
  55 qed.
  56
  57 lemma lift_append_rcons_sn (A) (k) (f) (p1) (p) (l): k ≗ k →
  58       ↑❨λg,p2. k g (p1●l◗p2), f, p❩ = ↑{A}❨λg,p2. k g (p1◖l●p2), f, p❩.
  59 #A #k #f #p1 #p #l #Hk
  60 @lift_eq_repl // #g1 #g2 #p2 #Hg
  61 <list_append_rcons_sn @Hk -Hk // (**) (* auto fail *)
  62 qed.
  63
  64 (* Advanced constructions with proj_path ************************************)
  65
  66 lemma proj_path_proper:
  67       proj_path ≗ proj_path.
  68 // qed.
  69
  70 lemma lift_path_eq_repl (p):
  71       stream_eq_repl … (λf1,f2. ↑[f1]p = ↑[f2]p).
  72 /2 width=1 by lift_eq_repl/ qed.
  73
  74 lemma lift_path_append_sn (p) (f) (q):
  75       q●↑[f]p = ↑❨(λg,p. proj_path g (q●p)), f, p❩.
  76 #p elim p -p // * [ #n ] #p #IH #f #q
  77 [ <lift_d_sn <lift_d_sn
  78 | <lift_m_sn <lift_m_sn
  79 | <lift_L_sn <lift_L_sn
  80 | <lift_A_sn <lift_A_sn
  81 | <lift_S_sn <lift_S_sn
  82 ]
  83 >lift_lcons_alt // >lift_append_rcons_sn //
  84 <IH <IH -IH <list_append_rcons_sn //
  85 qed.
  86
  87 lemma lift_path_lcons (f) (p) (l):
  88       l◗↑[f]p = ↑❨(λg,p. proj_path g (l◗p)), f, p❩.
  89 #f #p #l
  90 >lift_lcons_alt <lift_path_append_sn //
  91 qed.
  92
  93 lemma lift_path_d_sn (f) (p) (n):
  94       (𝗱(f＠⧣❨n❩)◗↑[⇂*[n]f]p) = ↑[f](𝗱n◗p).
  95 // qed.
  96
  97 lemma lift_path_m_sn (f) (p):
  98       (𝗺◗↑[f]p) = ↑[f](𝗺◗p).
  99 // qed.
 100
 101 lemma lift_path_L_sn (f) (p):
 102       (𝗟◗↑[⫯f]p) = ↑[f](𝗟◗p).
 103 // qed.
 104
 105 lemma lift_path_A_sn (f) (p):
 106       (𝗔◗↑[f]p) = ↑[f](𝗔◗p).
 107 // qed.
 108
 109 lemma lift_path_S_sn (f) (p):
 110       (𝗦◗↑[f]p) = ↑[f](𝗦◗p).
 111 // qed.
 112
 113 lemma lift_path_append (p2) (p1) (f):
 114       (↑[f]p1)●(↑[↑[p1]f]p2) = ↑[f](p1●p2).
 115 #p2 #p1 elim p1 -p1 //
 116 * [ #n1 ] #p1 #IH #f
 117 [ <lift_path_d_sn <lift_path_d_sn <IH //
 118 | <lift_path_m_sn <lift_path_m_sn <IH //
 119 | <lift_path_L_sn <lift_path_L_sn <IH //
 120 | <lift_path_A_sn <lift_path_A_sn <IH //
 121 | <lift_path_S_sn <lift_path_S_sn <IH //
 122 ]
 123 qed.
 124
 125 lemma lift_path_d_dx (f) (p) (n):
 126       (↑[f]p)◖𝗱((↑[p]f)＠⧣❨n❩) = ↑[f](p◖𝗱n).
 127 #f #p #n <lift_path_append //
 128 qed.
 129
 130 lemma lift_path_m_dx (f) (p):
 131       (↑[f]p)◖𝗺 = ↑[f](p◖𝗺).
 132 #f #p <lift_path_append //
 133 qed.
 134
 135 lemma lift_path_L_dx (f) (p):
 136       (↑[f]p)◖𝗟 = ↑[f](p◖𝗟).
 137 #f #p <lift_path_append //
 138 qed.
 139
 140 lemma lift_path_A_dx (f) (p):
 141       (↑[f]p)◖𝗔 = ↑[f](p◖𝗔).
 142 #f #p <lift_path_append //
 143 qed.
 144
 145 lemma lift_path_S_dx (f) (p):
 146       (↑[f]p)◖𝗦 = ↑[f](p◖𝗦).
 147 #f #p <lift_path_append //
 148 qed.
 149
 150 (* Advanced constructions with proj_rmap ************************************)
 151
 152 lemma lift_rmap_eq_repl (p):
 153       stream_eq_repl … (λf1,f2. ↑[p]f1 ≗ ↑[p]f2).
 154 #p elim p -p //
 155 * [ #n ] #p #IH #f1 #f2 #Hf
 156 [ /3 width=1 by stream_tls_eq_repl/
 157 | /2 width=1 by/
 158 | /3 width=1 by tr_push_eq_repl/
 159 | /2 width=1 by/
 160 | /2 width=1 by/
 161 ]
 162 qed.
 163
 164 lemma tls_lift_rmap_d_dx (f) (p) (m) (n):
 165       ⇂*[m+n]↑[p]f ≗ ⇂*[m]↑[p◖𝗱n]f.
 166 #f #p #m #n
 167 <lift_rmap_d_dx >nrplus_inj_dx >nrplus_inj_sn //
 168 qed.
 169
 170 (* Advanced inversions with proj_path ***************************************)
 171
 172 lemma lift_path_inv_empty (f) (p):
 173       (𝐞) = ↑[f]p → 𝐞 = p.
 174 #f * // * [ #n ] #p
 175 [ <lift_path_d_sn
 176 | <lift_path_m_sn
 177 | <lift_path_L_sn
 178 | <lift_path_A_sn
 179 | <lift_path_S_sn
 180 ] #H destruct
 181 qed-.
 182
 183 lemma lift_path_inv_d_sn (f) (p) (q) (k):
 184       (𝗱k◗q) = ↑[f]p →
 185       ∃∃r,h. k = f＠⧣❨h❩ & q = ↑[⇂*[h]f]r & 𝗱h◗r = p.
 186 #f * [| * [ #n ] #p ] #q #k
 187 [ <lift_path_empty
 188 | <lift_path_d_sn
 189 | <lift_path_m_sn
 190 | <lift_path_L_sn
 191 | <lift_path_A_sn
 192 | <lift_path_S_sn
 193 ] #H destruct
 194 /2 width=5 by ex3_2_intro/
 195 qed-.
 196
 197 lemma lift_path_inv_m_sn (f) (p) (q):
 198       (𝗺◗q) = ↑[f]p →
 199       ∃∃r. q = ↑[f]r & 𝗺◗r = p.
 200 #f * [| * [ #n ] #p ] #q
 201 [ <lift_path_empty
 202 | <lift_path_d_sn
 203 | <lift_path_m_sn
 204 | <lift_path_L_sn
 205 | <lift_path_A_sn
 206 | <lift_path_S_sn
 207 ] #H destruct
 208 /2 width=3 by ex2_intro/
 209 qed-.
 210
 211 lemma lift_path_inv_L_sn (f) (p) (q):
 212       (𝗟◗q) = ↑[f]p →
 213       ∃∃r. q = ↑[⫯f]r & 𝗟◗r = p.
 214 #f * [| * [ #n ] #p ] #q
 215 [ <lift_path_empty
 216 | <lift_path_d_sn
 217 | <lift_path_m_sn
 218 | <lift_path_L_sn
 219 | <lift_path_A_sn
 220 | <lift_path_S_sn
 221 ] #H destruct
 222 /2 width=3 by ex2_intro/
 223 qed-.
 224
 225 lemma lift_path_inv_A_sn (f) (p) (q):
 226       (𝗔◗q) = ↑[f]p →
 227       ∃∃r. q = ↑[f]r & 𝗔◗r = p.
 228 #f * [| * [ #n ] #p ] #q
 229 [ <lift_path_empty
 230 | <lift_path_d_sn
 231 | <lift_path_m_sn
 232 | <lift_path_L_sn
 233 | <lift_path_A_sn
 234 | <lift_path_S_sn
 235 ] #H destruct
 236 /2 width=3 by ex2_intro/
 237 qed-.
 238
 239 lemma lift_path_inv_S_sn (f) (p) (q):
 240       (𝗦◗q) = ↑[f]p →
 241       ∃∃r. q = ↑[f]r & 𝗦◗r = p.
 242 #f * [| * [ #n ] #p ] #q
 243 [ <lift_path_empty
 244 | <lift_path_d_sn
 245 | <lift_path_m_sn
 246 | <lift_path_L_sn
 247 | <lift_path_A_sn
 248 | <lift_path_S_sn
 249 ] #H destruct
 250 /2 width=3 by ex2_intro/
 251 qed-.
 252
 253 lemma lift_path_inv_append_sn (q2) (q1) (p) (f):
 254       q1●q2 = ↑[f]p →
 255       ∃∃p1,p2. q1 = ↑[f]p1 & q2 = ↑[↑[p1]f]p2 & p1●p2 = p.
 256 #q2 #q1 elim q1 -q1
 257 [| * [ #n1 ] #q1 #IH ] #p #f
 258 [ <list_append_empty_sn #H0 destruct
 259   /2 width=5 by ex3_2_intro/
 260 | <list_append_lcons_sn #H0
 261   elim (lift_path_inv_d_sn … H0) -H0 #r1 #m1 #H1 #H0 #H2 destruct
 262   elim (IH … H0) -IH -H0 #p1 #p2 #H1 #H2 #H3 destruct
 263   /2 width=5 by ex3_2_intro/
 264 | <list_append_lcons_sn #H0
 265   elim (lift_path_inv_m_sn … H0) -H0 #r1 #H0 #H1 destruct
 266   elim (IH … H0) -IH -H0 #p1 #p2 #H1 #H2 #H3 destruct
 267   /2 width=5 by ex3_2_intro/
 268 | <list_append_lcons_sn #H0
 269   elim (lift_path_inv_L_sn … H0) -H0 #r1 #H0 #H1 destruct
 270   elim (IH … H0) -IH -H0 #p1 #p2 #H1 #H2 #H3 destruct
 271   /2 width=5 by ex3_2_intro/
 272 | <list_append_lcons_sn #H0
 273   elim (lift_path_inv_A_sn … H0) -H0 #r1 #H0 #H1 destruct
 274   elim (IH … H0) -IH -H0 #p1 #p2 #H1 #H2 #H3 destruct
 275   /2 width=5 by ex3_2_intro/
 276 | <list_append_lcons_sn #H0
 277   elim (lift_path_inv_S_sn … H0) -H0 #r1 #H0 #H1 destruct
 278   elim (IH … H0) -IH -H0 #p1 #p2 #H1 #H2 #H3 destruct
 279   /2 width=5 by ex3_2_intro/
 280 ]
 281 qed-.
 282
 283 (* Main inversions with proj_path *******************************************)
 284
 285 theorem lift_path_inj (q:path) (p) (f):
 286         ↑[f]q = ↑[f]p → q = p.
 287 #q elim q -q [| * [ #k ] #q #IH ] #p #f
 288 [ <lift_path_empty #H0
 289   <(lift_path_inv_empty … H0) -H0 //
 290 | <lift_path_d_sn #H0
 291   elim (lift_path_inv_d_sn … H0) -H0 #r #h #H0
 292   >(tr_pap_inj ???? H0) -k [1,3: // ] #Hr #H0 destruct
 293 | <lift_path_m_sn #H0
 294   elim (lift_path_inv_m_sn … H0) -H0 #r #Hr #H0 destruct
 295 | <lift_path_L_sn #H0
 296   elim (lift_path_inv_L_sn … H0) -H0 #r #Hr #H0 destruct
 297 | <lift_path_A_sn #H0
 298   elim (lift_path_inv_A_sn … H0) -H0 #r #Hr #H0 destruct
 299 | <lift_path_S_sn #H0
 300   elim (lift_path_inv_S_sn … H0) -H0 #r #Hr #H0 destruct
 301 ]
 302 <(IH … Hr) -r -IH //
 303 qed-.
 304