matita/matita/contribs/lambdadelta/delayed_updating/substitution/lift_rmap_closed.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "delayed_updating/substitution/lift_rmap_eq.ma".
  16 include "delayed_updating/syntax/path_closed.ma".
  17 include "ground/relocation/xap.ma".
  18 include "ground/lib/stream_eq_eq.ma".
  19
  20 (* LIFT MAP FOR PATH ********************************************************)
  21
  22 (* Destructions with cpp ****************************************************)
  23
  24 lemma tls_plus_lift_rmap_closed (o) (f) (q) (n):
  25       q ϵ 𝐂❨o,n,𝟎❩ →
  26       ∀m. ⇂*[m]f ≗ ⇂*[m+n]🠢[f]q.
  27 #o #f #q #n #Hq elim Hq -q -n //
  28 qed-.
  29
  30 lemma tls_lift_rmap_closed (o) (f) (q) (n):
  31       q ϵ 𝐂❨o,n,𝟎❩ →
  32       f ≗ ⇂*[n]🠢[f]q.
  33 #o #f #q #n #H0
  34 /2 width=2 by tls_plus_lift_rmap_closed/
  35 qed-.
  36
  37 lemma tls_lift_rmap_append_closed_dx (o) (f) (p) (q) (n):
  38       q ϵ 𝐂❨o,n,𝟎❩ →
  39       (🠢[f]p) ≗ ⇂*[n]🠢[f](p●q).
  40 #o #f #p #q #n #Hq
  41 /2 width=2 by tls_lift_rmap_closed/
  42 qed-.
  43
  44 lemma tls_succ_lift_rmap_append_closed_Lq_dx (o) (f) (p) (q) (n):
  45       q ϵ 𝐂❨o,n,𝟎❩ →
  46       (🠢[f]p) ≗ ⇂*[↑n]🠢[f](p●𝗟◗q).
  47 #o #f #p #q #n #Hq
  48 /3 width=2 by tls_lift_rmap_append_closed_dx, pcc_L_sn/
  49 qed-.
  50
  51 lemma tls_succ_plus_lift_rmap_append_closed_bLq_dx (o1) (o2) (f) (p) (b) (q) (m) (n):
  52       b ϵ 𝐂❨o1,m,𝟎❩ → q ϵ 𝐂❨o2,n,𝟎❩ →
  53       (🠢[f]p) ≗ ⇂*[↑(m+n)]🠢[f](p●b●𝗟◗q).
  54 #o1 #o2 #f #p #b #q #m #n #Hm #Hn
  55 >nplus_succ_dx <stream_tls_plus
  56 @(stream_eq_trans … (tls_lift_rmap_append_closed_dx … Hm))
  57 /3 width=2 by stream_tls_eq_repl, tls_succ_lift_rmap_append_closed_Lq_dx/
  58 qed-.
  59
  60 lemma nap_plus_lift_rmap_append_closed_Lq_dx (o) (f) (p) (q) (m) (n):
  61       q ϵ 𝐂❨o,n,𝟎❩ →
  62       (🠢[f]p＠❨m❩+🠢[f](p●𝗟◗q)＠§❨n❩) = 🠢[f](p●𝗟◗q)＠§❨m+n❩.
  63 #o #f #p #q #m #n #Hq
  64 <tr_nap_plus_dx_xap
  65 /4 width=2 by eq_f2, tr_xap_eq_repl, tls_succ_lift_rmap_append_closed_Lq_dx/
  66 qed-.