matita/matita/contribs/lambdadelta/delayed_updating/syntax/path_proper.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "delayed_updating/syntax/path.ma".
  16 include "delayed_updating/notation/functions/class_p_0.ma".
  17 include "ground/lib/subset.ma".
  18 include "ground/xoa/ex_1_2.ma".
  19
  20 (* PROPER CONDITION FOR PATH ************************************************)
  21
  22 definition ppc: predicate path ≝
  23            λp. 𝐞 = p → ⊥
  24 .
  25
  26 interpretation
  27   "proper condition (path)"
  28   'ClassP = (ppc).
  29
  30 (* Basic constructions ******************************************************)
  31
  32 lemma ppc_lcons (l) (q): l◗q ϵ 𝐏.
  33 #l #q #H0 destruct
  34 qed.
  35
  36 lemma ppc_rcons (l) (q): q◖l ϵ 𝐏.
  37 #l #q #H
  38 elim (eq_inv_list_empty_rcons ??? H)
  39 qed.
  40
  41 (* Basic inversions ********************************************************)
  42
  43 lemma ppc_inv_empty:
  44       (𝐞) ϵ 𝐏 → ⊥.
  45 #H0 @H0 -H0 //
  46 qed-.
  47
  48 lemma ppc_inv_lcons (p):
  49       p ϵ 𝐏 → ∃∃l,q. l◗q = p.
  50 *
  51 [ #H0 elim (ppc_inv_empty … H0)
  52 | #l #q #_ /2 width=3 by ex1_2_intro/
  53 ]
  54 qed-.
  55
  56 lemma ppc_inv_rcons (p):
  57       p ϵ 𝐏 → ∃∃q,l. q◖l = p.
  58 #p @(list_ind_rcons … p) -p
  59 [ #H0 elim (ppc_inv_empty … H0)
  60 | #q #l #_ #_ /2 width=3 by ex1_2_intro/
  61 ]
  62 qed-.