matita/matita/contribs/lambdadelta/delayed_updating/syntax/path_structure.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "delayed_updating/syntax/path.ma".
  16 include "delayed_updating/notation/functions/circled_times_1.ma".
  17
  18 (* STRUCTURE FOR PATH *******************************************************)
  19
  20 rec definition structure (p) on p ≝
  21 match p with
  22 [ list_empty     ⇒ 𝐞
  23 | list_lcons l q ⇒
  24    match l with
  25    [ label_node_d n ⇒ structure q
  26    | label_edge_L   ⇒ 𝗟◗structure q
  27    | label_edge_A   ⇒ 𝗔◗structure q
  28    | label_edge_S   ⇒ 𝗦◗structure q
  29    ]
  30 ].
  31
  32 interpretation
  33   "structure (path)"
  34   'CircledTimes p = (structure p).
  35
  36 (* Basic constructions ******************************************************)
  37
  38 lemma structure_empty:
  39       𝐞 = ⊗𝐞.
  40 // qed.
  41
  42 lemma structure_d_sn (p) (n):
  43       ⊗p = ⊗(𝗱❨n❩◗p).
  44 // qed.
  45
  46 lemma structure_L_sn (p):
  47       𝗟◗⊗p = ⊗(𝗟◗p).
  48 // qed.
  49
  50 lemma structure_A_sn (p):
  51       𝗔◗⊗p = ⊗(𝗔◗p).
  52 // qed.
  53
  54 lemma structure_S_sn (p):
  55       𝗦◗⊗p = ⊗(𝗦◗p).
  56 // qed.
  57
  58 (* Main constructions *******************************************************)
  59
  60 theorem structure_idem (p):
  61         ⊗p = ⊗⊗p.
  62 #p elim p -p [| * [ #n ] #p #IH ] //
  63 qed.
  64
  65 theorem structure_append (p1) (p2):
  66         ⊗p1●⊗p2 = ⊗(p1●p2).
  67 #p1 elim p1 -p1 [| * [ #n ] #p1 #IH ] #p2
  68 [||*: <list_append_lcons_sn ] //
  69 qed.
  70
  71 (* Constructions with list_rcons ********************************************)
  72
  73 lemma structure_d_dx (p) (n):
  74       ⊗p = ⊗(p◖𝗱❨n❩).
  75 #p #n <structure_append //
  76 qed.
  77
  78 lemma structure_L_dx (p):
  79       (⊗p)◖𝗟 = ⊗(p◖𝗟).
  80 #p <structure_append //
  81 qed.
  82
  83 lemma structure_A_dx (p):
  84       (⊗p)◖𝗔 = ⊗(p◖𝗔).
  85 #p <structure_append //
  86 qed.
  87
  88 lemma structure_S_dx (p):
  89       (⊗p)◖𝗦 = ⊗(p◖𝗦).
  90 #p <structure_append //
  91 qed.