matita/matita/contribs/lambdadelta/delayed_updating/syntax/prototerm_constructors.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "delayed_updating/syntax/prototerm.ma".
  16 include "delayed_updating/notation/functions/m_hook_1.ma".
  17 include "delayed_updating/notation/functions/hash_1.ma".
  18 include "delayed_updating/notation/functions/tau_2.ma".
  19 include "delayed_updating/notation/functions/lamda_1.ma".
  20 include "delayed_updating/notation/functions/at_2.ma".
  21
  22 (* CONSTRUCTORS FOR PROTOTERM ***********************************************)
  23
  24 definition prototerm_node_0 (l): prototerm ≝
  25            λp. l◗𝐞 = p.
  26
  27 definition prototerm_node_1 (l): prototerm → prototerm ≝
  28            λt,p. ∃∃q. q ϵ t & l◗q = p.
  29
  30 definition prototerm_node_1_2 (l1) (l2): prototerm → prototerm ≝
  31            λt,p. ∃∃q. q ϵ t & l1◗l2◗q = p.
  32
  33 definition prototerm_node_2 (l1) (l2): prototerm → prototerm → prototerm ≝
  34            λt1,t2,p.
  35            ∨∨ ∃∃q. q ϵ t1 & l1◗q = p
  36             | ∃∃q. q ϵ t2 & l2◗q = p.
  37
  38 interpretation
  39   "mark (prototerm)"
  40   'MHook t = (prototerm_node_1 label_m t).
  41
  42 interpretation
  43   "outer variable reference by depth (prototerm)"
  44   'Hash k = (prototerm_node_0 (label_d k)).
  45
  46 interpretation
  47   "inner variable reference by depth (prototerm)"
  48   'Tau k t = (prototerm_node_1_2 (label_d k) label_m t).
  49
  50 interpretation
  51   "name-free functional abstraction (prototerm)"
  52   'Lamda t = (prototerm_node_1 label_L t).
  53
  54 interpretation
  55   "application (prototerm)"
  56   'At u t = (prototerm_node_2 label_S label_A u t).
  57
  58 (* Basic constructions *******************************************************)
  59
  60 lemma in_comp_oref_hd (k):
  61       (𝗱k◗𝐞) ϵ ⧣k.
  62 // qed.
  63
  64 lemma in_comp_iref_hd (t) (q) (k):
  65       q ϵ t → 𝗱k◗𝗺◗q ϵ 𝛕k.t.
  66 /2 width=3 by ex2_intro/ qed.
  67
  68 lemma in_comp_abst_hd (t) (q):
  69       q ϵ t → 𝗟◗q ϵ 𝛌.t.
  70 /2 width=3 by ex2_intro/ qed.
  71
  72 lemma in_comp_appl_sd (u) (t) (q):
  73       q ϵ u → 𝗦◗q ϵ ＠u.t.
  74 /3 width=3 by ex2_intro, or_introl/ qed.
  75
  76 lemma in_comp_appl_hd (u) (t) (q):
  77       q ϵ t → 𝗔◗q ϵ ＠u.t.
  78 /3 width=3 by ex2_intro, or_intror/ qed.
  79
  80 (* Basic inversions *********************************************************)
  81
  82 lemma in_comp_inv_iref (t) (p) (k):
  83       p ϵ 𝛕k.t →
  84       ∃∃q. 𝗱k◗𝗺◗q = p & q ϵ t.
  85 #t #p #k * #q #Hq #Hp
  86 /2 width=3 by ex2_intro/
  87 qed-.
  88
  89 lemma in_comp_inv_abst (t) (p):
  90       p ϵ 𝛌.t →
  91       ∃∃q. 𝗟◗q = p & q ϵ t.
  92 #t #p * #q #Hq #Hp
  93 /2 width=3 by ex2_intro/
  94 qed-.
  95
  96 lemma in_comp_inv_appl (u) (t) (p):
  97       p ϵ ＠u.t →
  98       ∨∨ ∃∃q. 𝗦◗q = p & q ϵ u
  99        | ∃∃q. 𝗔◗q = p & q ϵ t.
 100 #u #t #p * * #q #Hq #Hp
 101 /3 width=3 by ex2_intro, or_introl, or_intror/
 102 qed-.
 103
 104 (* Advanced inversions ******************************************************)
 105
 106 lemma in_comp_inv_abst_hd (t) (p):
 107       (𝗟◗p) ϵ 𝛌.t → p ϵ t.
 108 #t #p #H0
 109 elim (in_comp_inv_abst … H0) -H0 #q #H0 #Hq
 110 elim (eq_inv_list_rcons_bi ????? H0) -H0 #H1 #H2 destruct //
 111 qed-.
 112
 113 lemma in_comp_inv_appl_sd (u) (t) (p):
 114       (𝗦◗p) ϵ ＠u.t → p ϵ u.
 115 #u #t #p #H0
 116 elim (in_comp_inv_appl … H0) -H0 * #q #H0 #Hq
 117 elim (eq_inv_list_rcons_bi ????? H0) -H0 #H1 #H2 destruct //
 118 qed-.
 119
 120 lemma in_comp_inv_appl_hd (u) (t) (p):
 121       (𝗔◗p) ϵ ＠u.t → p ϵ t.
 122 #u #t #p #H0
 123 elim (in_comp_inv_appl … H0) -H0 * #q #H0 #Hq
 124 elim (eq_inv_list_rcons_bi ????? H0) -H0 #H1 #H2 destruct //
 125 qed-.