matita/matita/contribs/lambdadelta/delayed_updating/syntax/prototerm_constructors.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "delayed_updating/syntax/prototerm.ma".
  16 include "delayed_updating/notation/functions/m_hook_1.ma".
  17 include "delayed_updating/notation/functions/hash_1.ma".
  18 include "delayed_updating/notation/functions/phi_2.ma".
  19 include "delayed_updating/notation/functions/lamda_1.ma".
  20 include "delayed_updating/notation/functions/at_2.ma".
  21
  22 (* CONSTRUCTORS FOR PROTOTERM ***********************************************)
  23
  24 definition prototerm_node_0 (l): prototerm ≝
  25            λp. l◗𝐞 = p.
  26
  27 definition prototerm_node_1 (l): prototerm → prototerm ≝
  28            λt,p. ∃∃q. q ϵ t & l◗q = p.
  29
  30 definition prototerm_node_1_2 (l1) (l2): prototerm → prototerm ≝
  31            λt,p. ∃∃q. q ϵ t & l1◗l2◗q = p.
  32
  33 definition prototerm_node_2 (l1) (l2): prototerm → prototerm → prototerm ≝
  34            λt1,t2,p.
  35            ∨∨ ∃∃q. q ϵ t1 & l1◗q = p
  36             | ∃∃q. q ϵ t2 & l2◗q = p.
  37
  38 interpretation
  39   "mark (prototerm)"
  40   'MHook t = (prototerm_node_1 label_m t).
  41
  42 interpretation
  43   "outer variable reference by depth (prototerm)"
  44   'Hash n = (prototerm_node_0 (label_d n)).
  45
  46 interpretation
  47   "inner variable reference by depth (prototerm)"
  48   'Phi n t = (prototerm_node_1_2 (label_d n) label_m t).
  49
  50 interpretation
  51   "name-free functional abstraction (prototerm)"
  52   'Lamda t = (prototerm_node_1 label_L t).
  53
  54 interpretation
  55   "application (prototerm)"
  56   'At u t = (prototerm_node_2 label_S label_A u t).
  57
  58 (* Basic Inversions *********************************************************)
  59
  60 lemma prototerm_in_root_inv_lcons_oref:
  61       ∀p,l,n. l◗p ϵ ▵#n →
  62       ∧∧ 𝗱n = l & 𝐞 = p.
  63 #p #l #n * #q
  64 <list_append_lcons_sn #H0 destruct -H0
  65 elim (eq_inv_list_empty_append … e0) -e0 #H0 #_
  66 /2 width=1 by conj/
  67 qed-.
  68
  69 lemma prototerm_in_root_inv_lcons_iref:
  70       ∀t,p,l,n. l◗p ϵ ▵𝛗n.t →
  71       ∧∧ 𝗱n = l & p ϵ ▵ɱ.t.
  72 #t #p #l #n * #q * #r #Hr
  73 <list_append_lcons_sn #H0 destruct -H0
  74 /4 width=4 by ex2_intro, ex_intro, conj/
  75 qed-.
  76
  77 lemma prototerm_in_root_inv_lcons_mark:
  78       ∀t,p,l. l◗p ϵ ▵ɱ.t →
  79       ∧∧ 𝗺 = l & p ϵ ▵t.
  80 #t #p #l * #q * #r #Hr
  81 <list_append_lcons_sn #H0 destruct
  82 /3 width=2 by ex_intro, conj/
  83 qed-.
  84
  85 lemma prototerm_in_root_inv_lcons_abst:
  86       ∀t,p,l. l◗p ϵ ▵𝛌.t →
  87       ∧∧ 𝗟 = l & p ϵ ▵t.
  88 #t #p #l * #q * #r #Hr
  89 <list_append_lcons_sn #H0 destruct
  90 /3 width=2 by ex_intro, conj/
  91 qed-.
  92
  93 lemma prototerm_in_root_inv_lcons_appl:
  94       ∀u,t,p,l. l◗p ϵ ▵@u.t →
  95       ∨∨ ∧∧ 𝗦 = l & p ϵ ▵u
  96        | ∧∧ 𝗔 = l & p ϵ ▵t.
  97 #u #t #p #l * #q * * #r #Hr
  98 <list_append_lcons_sn #H0 destruct
  99 /4 width=2 by ex_intro, or_introl, or_intror, conj/
 100 qed-.