matita/matita/contribs/lambdadelta/delayed_updating/unwind/unwind2_rmap_closed.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "delayed_updating/unwind/unwind2_rmap_eq.ma".
  16 include "delayed_updating/syntax/path_closed.ma".
  17 include "delayed_updating/syntax/path_depth.ma".
  18 include "ground/relocation/nap.ma".
  19 include "ground/lib/stream_tls_plus.ma".
  20 include "ground/lib/stream_eq_eq.ma".
  21
  22 (* TAILED UNWIND FOR RELOCATION MAP *****************************************)
  23
  24 (* Destructions with cpp ****************************************************)
  25
  26 lemma nap_plus_unwind2_rmap_closed (o) (f) (q) (m) (n):
  27       q ϵ 𝐂❨o,n❩ →
  28       f＠§❨m❩+♭q = ▶[f]q＠§❨m+n❩.
  29 #o #f #q #m #n #Hq elim Hq -q -n //
  30 #q #n [ #k #_ ] #_ #IH
  31 [ <depth_d_dx <unwind2_rmap_d_dx
  32   <tr_compose_nap <tr_uni_nap //
  33 | <depth_L_dx <unwind2_rmap_L_dx
  34   <tr_nap_push <nplus_succ_dx //
  35 ]
  36 qed-.
  37
  38 lemma nap_plus_unwind2_rmap_append_closed_Lq_dx (o) (f) (p) (q) (m) (n):
  39       q ϵ 𝐂❨o,n❩ →
  40       (⫯▶[f]p)＠§❨m❩+♭q = ▶[f](p●𝗟◗q)＠§❨m+n❩.
  41 #o #f #p #q #m #n #Hn
  42 /2 width=2 by nap_plus_unwind2_rmap_closed/
  43 qed-.
  44
  45 lemma nap_unwind2_rmap_append_closed_Lq_dx (o) (f) (p) (q) (n):
  46       q ϵ 𝐂❨o,n❩ →
  47       ♭q = ▶[f](p●𝗟◗q)＠§❨n❩.
  48 #o #f #p #q #n #Hn
  49 >(nplus_zero_sn n)
  50 <(nap_plus_unwind2_rmap_append_closed_Lq_dx … Hn) -Hn
  51 <nplus_zero_sn //
  52 qed-.
  53
  54 lemma tls_succ_plus_unwind2_rmap_push_closed (o) (f) (q) (n):
  55       q ϵ 𝐂❨o,n❩ →
  56       ∀m. ⇂*[m]f ≗ ⇂*[↑(m+n)]▶[⫯f]q.
  57 #o #f #q #n #Hn elim Hn -q -n //
  58 #q #n #k #_ #_ #IH #m
  59 @(stream_eq_trans … (tls_unwind2_rmap_d_dx …))
  60 >nrplus_inj_dx >nrplus_inj_sn >nsucc_unfold //
  61 qed-.
  62
  63 lemma tls_succ_unwind2_rmap_push_closed (o) (f) (q) (n):
  64       q ϵ 𝐂❨o,n❩ →
  65       f ≗ ⇂*[↑n]▶[⫯f](q).
  66 #o #f #q #n #Hn
  67 /2 width=2 by tls_succ_plus_unwind2_rmap_push_closed/
  68 qed-.
  69
  70 lemma tls_succ_plus_unwind2_rmap_append_closed_Lq_dx (o) (f) (p) (q) (n):
  71       q ϵ 𝐂❨o,n❩ →
  72       ∀m. ⇂*[m]▶[f]p ≗ ⇂*[↑(m+n)]▶[f](p●𝗟◗q).
  73 #o #f #p #q #n #Hn #m
  74 /2 width=2 by tls_succ_plus_unwind2_rmap_push_closed/
  75 qed-.