matita/matita/contribs/lambdadelta/delayed_updating/unwind0/unwind1_rmap.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "delayed_updating/substitution/lift_length.ma".
  16 include "delayed_updating/notation/functions/black_righttriangle_1.ma".
  17 include "ground/relocation/tr_uni.ma".
  18 include "ground/relocation/tr_compose.ma".
  19
  20 (* BASIC UNWIND FOR RELOCATION MAP ******************************************)
  21
  22 rec definition unwind1_rmap_pnat (n) (p) on n ≝
  23 match n with
  24 [ punit   ⇒ 𝐢
  25 | psucc m ⇒
  26   match p with
  27   [ list_empty     ⇒ 𝐢
  28   | list_lcons l q ⇒
  29     match l with
  30     [ label_d n ⇒ (unwind1_rmap_pnat m (↑[𝐮❨n❩]q))∘(↑[q]𝐮❨n❩)
  31     | label_m   ⇒ unwind1_rmap_pnat m q
  32     | label_L   ⇒ unwind1_rmap_pnat m q
  33     | label_A   ⇒ unwind1_rmap_pnat m q
  34     | label_S   ⇒ unwind1_rmap_pnat m q
  35     ]
  36   ]
  37 ].
  38
  39 definition unwind1_rmap (p) ≝
  40            unwind1_rmap_pnat (↑❘p❘) p.
  41
  42 interpretation
  43   "basic unwind (relocation map)"
  44   'BlackRightTriangle p = (unwind1_rmap p).
  45
  46 (* Basic constructions ******************************************************)
  47
  48 lemma unwind1_rmap_unfold (p):
  49       unwind1_rmap_pnat (↑❘p❘) p = ▶p.
  50 // qed-.
  51
  52 lemma unwind1_rmap_empty:
  53       (𝐢) = ▶(𝐞).
  54 // qed.
  55
  56 lemma unwind1_rmap_d_sn (p) (n:pnat):
  57       (▶(↑[𝐮❨n❩]p))∘(↑[p]𝐮❨n❩) = ▶(𝗱n◗p).
  58 #p #n
  59 <unwind1_rmap_unfold <lift_path_length //
  60 qed.
  61
  62 lemma unwind1_rmap_m_sn (p):
  63       ▶p = ▶(𝗺◗p).
  64 // qed.
  65
  66 lemma unwind1_rmap_L_sn (p):
  67       ▶p = ▶(𝗟◗p).
  68 // qed.
  69
  70 lemma unwind1_rmap_A_sn (p):
  71       ▶p = ▶(𝗔◗p).
  72 // qed.
  73
  74 lemma unwind1_rmap_S_sn (p):
  75       ▶p = ▶(𝗦◗p).
  76 // qed.