matita/matita/contribs/lambdadelta/ground/arith/nat_minus.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/arith/nat_succ_iter.ma".
  16 include "ground/arith/nat_pred_succ.ma".
  17
  18 (* SUBTRACTION FOR NON-NEGATIVE INTEGERS ************************************)
  19
  20 (*** minus *)
  21 definition nminus: nat → nat → nat ≝
  22            λm,n. npred^n m.
  23
  24 interpretation
  25   "minus (positive integers)"
  26   'minus m n = (nminus m n).
  27
  28 (* Basic rewrites ***********************************************************)
  29
  30 (*** minus_n_O *)
  31 lemma nminus_zero_dx (m): m = m - 𝟎.
  32 // qed.
  33
  34 lemma nminus_pred_sn (m) (n): ↓(m - n) = ↓m - n.
  35 #m #n @(niter_appl … npred)
  36 qed.
  37
  38 (*** eq_minus_S_pred *)
  39 lemma nminus_succ_dx (m) (n): ↓(m - n) = m - ↑n.
  40 #m #n @(niter_succ … npred)
  41 qed.
  42
  43 (*** minus_O_n *)
  44 lemma nminus_zero_sn (n): 𝟎 = 𝟎 - n.
  45 #n elim n -n //
  46 qed.
  47
  48 (*** minus_S_S *)
  49 lemma nminus_succ_bi (m) (n): m - n = ↑m - ↑n.
  50 #m #n elim n -n //
  51 qed.
  52
  53 (* Advanced rewrites ********************************************************)
  54
  55 lemma nminus_succ_dx_pred_sn (m) (n): ↓m - n = m - ↑n.
  56 // qed-.
  57
  58 (*** minus_n_n *)
  59 lemma nminus_refl (m): 𝟎 = m - m.
  60 #m elim m -m //
  61 qed.
  62
  63 (*** minus_Sn_n *)
  64 lemma nminus_succ_sn_refl (m): ninj (𝟏) = ↑m - m.
  65 #m elim m -m //
  66 qed.
  67
  68 (*** minus_minus_comm *)
  69 lemma nminus_minus_comm (o) (m) (n): o - m - n = o - n - m.
  70 #o #m #n elim n -n //
  71 qed-.