matita/matita/contribs/lambdadelta/ground/arith/nat_minus_plus.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/arith/nat_plus.ma".
  16 include "ground/arith/nat_minus.ma".
  17
  18 (* SUBTRACTION FOR NON-NEGATIVE INTEGERS ************************************)
  19
  20 (* Constructions with nplus *************************************************)
  21
  22 (*** minus_plus_m_m *)
  23 lemma nminus_plus_sn_refl_sn (m) (n): m = m + n - n.
  24 #m #n @(nat_ind_succ … n) -n //
  25 #n #IH <nplus_succ_dx <nminus_succ_bi //
  26 qed.
  27
  28 lemma nminus_plus_sn_refl_dx (m) (n): m = n + m - n.
  29 #m #n <nplus_comm //
  30 qed.
  31
  32 (*** minus_plus *)
  33 theorem nminus_plus_assoc (o) (m) (n): o-m-n = o-(m+n).
  34 #o #m #n @(nat_ind_succ … n) -n //
  35 #n #IH <nplus_succ_dx <nminus_succ_dx <nminus_succ_dx //
  36 qed-.
  37
  38 (*** minus_plus_plus_l *)
  39 lemma nminus_plus_dx_bi (m) (n) (o): m - n = (m + o) - (n + o).
  40 #m #n #o <nminus_plus_assoc <nminus_minus_comm //
  41 qed.
  42
  43 (*** plus_minus_plus_plus_l *) (**)
  44 lemma plus_minus_plus_plus_l: ∀z,x,y,h. z + (x + h) - (y + h) = z + x - y.
  45 // qed-.
  46
  47 (* Helper constructions with nplus ******************************************)
  48
  49 (*** plus_to_minus *)
  50 lemma nminus_plus_dx (o) (m) (n): o = m+n → n = o-m.
  51 #o #m #n #H destruct //
  52 qed-.
  53
  54 lemma nminus_plus_sn (o) (m) (n): o = m+n → m = o-n.
  55 #o #m #n #H destruct //
  56 qed-.
  57
  58 (* Inversions with nplus ****************************************************)
  59
  60 (*** discr_plus_xy_minus_xz *)
  61 lemma eq_inv_plus_nminus_refl_sn (m) (n) (o):
  62       m + o = m - n →
  63       ∨∨ ∧∧ 𝟎 = m & 𝟎 = o
  64        | ∧∧ 𝟎 = n & 𝟎 = o.
  65 #m #n @(nat_ind_succ_2 … m n) -m -n
  66 [ /3 width=1 by or_introl, conj/
  67 | #m #o #Ho
  68   lapply (eq_inv_nplus_bi_sn … (𝟎) Ho) -Ho
  69   /3 width=1 by or_intror, conj/
  70 | #m #n #IH #o
  71   <nminus_succ_bi >nplus_succ_shift #Ho
  72   elim (IH … Ho) -IH -Ho * #_ #H
  73   elim (eq_inv_nzero_succ … H)
  74 ]
  75 qed-.
  76
  77 (*** discr_minus_x_xy *)
  78 lemma eq_inv_nminus_refl_sn (m) (n): m = m - n → ∨∨ 𝟎 = m | 𝟎 = n.
  79 #m #n #Hmn
  80 elim (eq_inv_plus_nminus_refl_sn … (𝟎) Hmn) -Hmn * #H1 #H2
  81 /2 width=1 by or_introl, or_intror/
  82 qed-.