matita/matita/contribs/lambdadelta/ground/arith/nat_succ.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/arith/nat.ma".
  16
  17 (* NON-NEGATIVE INTEGERS ****************************************************)
  18
  19 definition nsucc: nat → nat ≝ λm. match m with
  20 [ nzero  ⇒ ninj (𝟏)
  21 | ninj p ⇒ ninj (↑p)
  22 ].
  23
  24 interpretation
  25   "successor (non-negative integers"
  26   'UpArrow m = (nsucc m).
  27
  28 (* Basic rewrites ***********************************************************)
  29
  30 lemma nsucc_zero: ninj (𝟏) = ↑𝟎.
  31 // qed.
  32
  33 lemma nsucc_inj (p): ninj (↑p) = ↑(ninj p).
  34 // qed.
  35
  36 (* Basic eliminations *******************************************************)
  37
  38 (*** nat_ind *)
  39 lemma nat_ind (Q:predicate …):
  40       Q (𝟎) → (∀n. Q n → Q (↑n)) → ∀n. Q n.
  41 #Q #IH1 #IH2 * //
  42 #p elim p -p /2 width=1 by/
  43 qed-.
  44
  45 (*** nat_elim2 *)
  46 lemma nat_ind_2 (Q:relation2 …):
  47       (∀n. Q (𝟎) n) →
  48       (∀m. Q (↑m) (𝟎)) →
  49       (∀m,n. Q m n → Q (↑m) (↑n)) →
  50       ∀m,n. Q m n.
  51 #Q #IH1 #IH2 #IH3 #m elim m -m [ // ]
  52 #m #IH #n elim n -n /2 width=1 by/
  53 qed-.
  54
  55 (* Basic inversions *********************************************************)
  56
  57 (*** injective_S *)
  58 lemma eq_inv_nsucc_bi: injective … nsucc.
  59 * [| #p1 ] * [2,4: #p2 ]
  60 [1,4: <nsucc_zero <nsucc_inj #H destruct
  61 | <nsucc_inj <nsucc_inj #H destruct //
  62 | //
  63 ]
  64 qed-.
  65
  66 lemma eq_inv_nsucc_zero (m): ↑m = 𝟎 → ⊥.
  67 * [ <nsucc_zero | #p <nsucc_inj ] #H destruct
  68 qed-.
  69
  70 lemma eq_inv_nzero_succ (m): 𝟎 = ↑m → ⊥.
  71 * [ <nsucc_zero | #p <nsucc_inj ] #H destruct
  72 qed-.