matita/matita/contribs/lambdadelta/ground/arith/ynat_le_succ.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/arith/ynat_succ.ma".
  16 include "ground/arith/ynat_le.ma".
  17
  18 (* ORDER FOR NON-NEGATIVE INTEGERS WITH INFINITY ****************************)
  19
  20 (* Constructions with ysucc *************************************************)
  21
  22 (*** yle_succ *)
  23 lemma yle_succ_bi (x) (y): x ≤ y → ↑x ≤ ↑y.
  24 #x #y * -x -y
  25 /3 width=1 by yle_inj, yle_inf, nle_succ_bi/
  26 qed.
  27
  28 (*** yle_succ_dx *)
  29 lemma yle_succ_dx (x) (y): x ≤ y → x ≤ ↑y.
  30 #x #y * -x -y
  31 /3 width=1 by yle_inj, yle_inf, nle_succ_dx/
  32 qed.
  33
  34 (*** yle_refl_S_dx *)
  35 lemma yle_succ_dx_refl (x): x ≤ ↑x.
  36 /2 width=1 by yle_succ_dx/ qed.
  37
  38 (* Inversions with ysucc ****************************************************)
  39
  40 (*** yle_inv_succ *)
  41 lemma yle_inv_succ_bi (x) (y): ↑x ≤ ↑y → x ≤ y.
  42 #x #y @(ynat_split_nat_inf … y) -y //
  43 #n <ysucc_inj #H
  44 elim (yle_inv_inj_dx … H) -H #o #Hmn #H
  45 elim (eq_inv_ysucc_inj … H) -H #m #H1 #H2 destruct
  46 /3 width=1 by yle_inj, nle_inv_succ_bi/
  47 qed-.