matita/matita/contribs/lambdadelta/ground/arith/ynat_lt_succ.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/arith/ynat_succ.ma".
  16 include "ground/arith/ynat_lt.ma".
  17
  18 (* STRICT ORDER FOR NON-NEGATIVE INTEGERS WITH INFINITY *********************)
  19
  20 (* Constructions with ysucc *************************************************)
  21
  22 (*** ylt_O_succ *)
  23 lemma ylt_zero_succ (y): 𝟎 < ↑y.
  24 #y @(ynat_split_nat_inf … y) -y
  25 /2 width=1 by ylt_inj/
  26 qed.
  27
  28 (*** ylt_succ *)
  29 lemma ylt_succ_bi (x) (y): x < y → ↑x < ↑y.
  30 #x #y * -x -y
  31 /3 width=1 by ylt_inj, ylt_inf, nlt_succ_bi/
  32 qed.
  33
  34 (*** ylt_succ_Y *)
  35 lemma ylt_succ_inf (x): x < ∞ → ↑x < ∞.
  36 #x @(ynat_split_nat_inf … x) -x //
  37 qed.
  38
  39 (*** ylt_succ2_refl *)
  40 lemma ylt_succ_dx_refl (x) (y): x < y → x < ↑x.
  41 #x #y #H
  42 elim (ylt_des_gen_sn … H) -y #n #H destruct
  43 /2 width=1 by ylt_inj/
  44 qed.
  45
  46 (* Inversions with ysucc ****************************************************)
  47
  48 lemma ylt_inv_succ_inf (x): ↑x < ∞ → x < ∞.
  49 #x #H
  50 elim (ylt_des_gen_sn … H) -H #m0 #H
  51 elim (eq_inv_ysucc_inj … H) -H #m #H1 #H2 destruct //
  52 qed-.
  53
  54 (*** ylt_inv_succ *)
  55 lemma ylt_inv_succ_bi (x) (y): ↑x < ↑y → x < y.
  56 #x #y @(ynat_split_nat_inf … y) -y
  57 [ #n <ysucc_inj #H
  58   elim (ylt_inv_inj_dx … H) -H #m0 #Hmn #H
  59   elim (eq_inv_ysucc_inj … H) -H #m #H1 #H2 destruct
  60   /3 width=1 by ylt_inj, nlt_inv_succ_bi/
  61 | /2 width=1 by ylt_inv_succ_inf/
  62 ]
  63 qed-.