matita/matita/contribs/lambdadelta/ground/counters/rtc_ism_max.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/xoa/ex_3_2.ma".
  16 include "ground/counters/rtc_max.ma".
  17 include "ground/counters/rtc_ism.ma".
  18
  19 (* T-BOUND RT-TRANSITION COUNTERS *******************************************)
  20
  21 (* Constructions with rtc_max ***********************************************)
  22
  23 lemma rtc_ism_max (n1) (n2) (c1) (c2): 𝐌❪n1,c1❫ → 𝐌❪n2,c2❫ → 𝐌❪n1∨n2,c1∨c2❫.
  24 #n1 #n2 #c1 #c2 * #ri1 #rs1 #H1 * #ri2 #rs2 #H2 destruct
  25 /2 width=3 by ex1_2_intro/
  26 qed.
  27
  28 lemma rtc_ism_max_zero_sn (n) (c1) (c2): 𝐌❪𝟎,c1❫ → 𝐌❪n,c2❫ → 𝐌❪n,c1∨c2❫.
  29 /2 width=1 by rtc_ism_max/ qed.
  30
  31 lemma rtc_ism_max_zero_dx (n) (c1) (c2): 𝐌❪n,c1❫ → 𝐌❪𝟎,c2❫ → 𝐌❪n,c1∨c2❫.
  32 #n #c1 #c2 #H1 #H2 >(nmax_zero_dx n) /2 width=1 by rtc_ism_max/
  33 qed.
  34
  35 lemma rtc_ism_max_idem_sn (n) (c1) (c2): 𝐌❪n,c1❫ → 𝐌❪n,c2❫ → 𝐌❪n,c1∨c2❫.
  36 #n #c1 #c2 #H1 #H2 >(nmax_idem n) /2 width=1 by rtc_ism_max/
  37 qed.
  38
  39 (* Inversions with rtc_max **************************************************)
  40
  41 lemma rtc_ism_inv_max (n) (c1) (c2): 𝐌❪n,c1 ∨ c2❫ →
  42       ∃∃n1,n2. 𝐌❪n1,c1❫ & 𝐌❪n2,c2❫ & (n1 ∨ n2) = n.
  43 #n #c1 #c2 * #ri #rs #H
  44 elim (rtc_max_inv_dx … H) -H #ri1 #rs1 #ti1 #ts1 #ri2 #rs2 #ti2 #ts2 #_ #_ #H1 #H2 #H3 #H4
  45 elim (eq_inv_nmax_zero … H1) -H1 /3 width=5 by ex3_2_intro, ex1_2_intro/
  46 qed-.
  47
  48 lemma rtc_isr_inv_max (c1) (c2): 𝐌❪𝟎,c1 ∨ c2❫ → ∧∧ 𝐌❪𝟎,c1❫ & 𝐌❪𝟎,c2❫.
  49 #c1 #c2 #H
  50 elim (rtc_ism_inv_max … H) -H #n1 #n2 #Hn1 #Hn2 #H
  51 elim (eq_inv_nmax_zero … H) -H #H1 #H2 destruct
  52 /2 width=1 by conj/
  53 qed-.
  54
  55 lemma rtc_ism_inv_max_zero_dx (n) (c1) (c2): 𝐌❪n,c1 ∨ c2❫ → 𝐌❪𝟎,c2❫ → 𝐌❪n,c1❫.
  56 #n #c1 #c2 #H #H2
  57 elim (rtc_ism_inv_max … H) -H #n1 #n2 #Hn1 #Hn2 #H destruct
  58 lapply (rtc_ism_inj … Hn2 H2) -c2 #H destruct //
  59 qed-.
  60
  61 lemma rtc_ism_inv_max_eq_t (n) (c1) (c2): 𝐌❪n,c1 ∨ c2❫ → rtc_eq_t c1 c2 →
  62       ∧∧ 𝐌❪n,c1❫ & 𝐌❪n,c2❫.
  63 #n #c1 #c2 #H #Hc12
  64 elim (rtc_ism_inv_max … H) -H #n1 #n2 #Hc1 #Hc2 #H destruct
  65 lapply (rtc_ism_eq_t_trans … Hc1 … Hc12) -Hc12 #H
  66 <(rtc_ism_inj … H … Hc2) -Hc2
  67 <nmax_idem /2 width=1 by conj/
  68 qed-.