matita/matita/contribs/lambdadelta/ground/counters/rtc_ism_plus.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/xoa/ex_3_2.ma".
  16 include "ground/counters/rtc_plus.ma".
  17 include "ground/counters/rtc_ism.ma".
  18
  19 (* T-BOUND RT-TRANSITION COUNTERS *******************************************)
  20
  21 (* Constructions with rtc_plus **********************************************)
  22
  23 lemma rtc_ism_plus (n1) (n2) (c1) (c2):  𝐌❪n1,c1❫ → 𝐌❪n2,c2❫ → 𝐌❪n1+n2,c1+c2❫.
  24 #n1 #n2 #c1 #c2 * #ri1 #rs1 #H1 * #ri2 #rs2 #H2 destruct
  25 /2 width=3 by ex1_2_intro/
  26 qed.
  27
  28 lemma rtc_ism_plus_zero_sn (n) (c1) (c2): 𝐌❪𝟎,c1❫ → 𝐌❪n,c2❫ → 𝐌❪n,c1+c2❫.
  29 #n #c1 #c2 #H1 #H2 >(nplus_zero_sn n) /2 width=1 by rtc_ism_plus/
  30 qed.
  31
  32 lemma rtc_ism_plus_zero_dx (n) (c1) (c2): 𝐌❪n,c1❫ → 𝐌❪𝟎,c2❫ → 𝐌❪n,c1+c2❫.
  33 /2 width=1 by rtc_ism_plus/ qed.
  34
  35 lemma rtc_ism_succ (n) (c): 𝐌❪n,c❫ → 𝐌❪↑n,c+𝟘𝟙❫.
  36 #n #c #H >nplus_unit_dx
  37 /2 width=1 by rtc_ism_plus/
  38 qed.
  39
  40 (* Inversions with rtc_plus *************************************************)
  41
  42 lemma rtc_ism_inv_plus (n) (c1) (c2): 𝐌❪n,c1 + c2❫ →
  43       ∃∃n1,n2. 𝐌❪n1,c1❫ & 𝐌❪n2,c2❫ & n1 + n2 = n.
  44 #n #c1 #c2 * #ri #rs #H
  45 elim (rtc_plus_inv_dx … H) -H #ri1 #rs1 #ti1 #ts1 #ri2 #rs2 #ti2 #ts2 #_ #_ #H1 #H2 #H3 #H4
  46 elim (eq_inv_nplus_zero … H1) -H1 /3 width=5 by ex3_2_intro, ex1_2_intro/
  47 qed-.
  48
  49 lemma rtc_ism_inv_plus_zero_dx (n) (c1) (c2): 𝐌❪n,c1 + c2❫ → 𝐌❪𝟎,c2❫ → 𝐌❪n,c1❫.
  50 #n #c1 #c2 #H #H2
  51 elim (rtc_ism_inv_plus … H) -H #n1 #n2 #Hn1 #Hn2 #H destruct
  52 lapply (rtc_ism_inj … Hn2 H2) -c2 #H destruct //
  53 qed-.
  54
  55 lemma rtc_ism_inv_plus_unit_dx (n) (c1) (c2): 𝐌❪n,c1 + c2❫ → 𝐌❪𝟏,c2❫ →
  56       ∃∃m. 𝐌❪m,c1❫ & n = ↑m.
  57 #n #c1 #c2 #H #H2
  58 elim (rtc_ism_inv_plus … H) -H #n1 #n2 #Hn1 #Hn2 #H destruct
  59 lapply (rtc_ism_inj … Hn2 H2) -c2 #H destruct
  60 /2 width=3 by ex2_intro/
  61 qed-.