matita/matita/contribs/lambdadelta/ground/counters/rtc_ist_max.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/xoa/ex_3_2.ma".
  16 include "ground/counters/rtc_max.ma".
  17 include "ground/counters/rtc_ist.ma".
  18
  19 (* T-BOUND RT-TRANSITION COUNTERS *******************************************)
  20
  21 (* Constructions with rtc_max ***********************************************)
  22
  23 lemma rtc_ist_max (n1) (n2) (c1) (c2): 𝐓❪n1,c1❫ → 𝐓❪n2,c2❫ → 𝐓❪n1∨n2,c1∨c2❫.
  24 #n1 #n2 #c1 #c2 #H1 #H2 destruct //
  25 qed.
  26
  27 lemma rtc_ist_max_zero_sn (n) (c1) (c2): 𝐓❪𝟎,c1❫ → 𝐓❪n,c2❫ → 𝐓❪n,c1∨c2❫.
  28 /2 width=1 by rtc_ist_max/ qed.
  29
  30 lemma rtc_ist_max_zero_dx (n) (c1) (c2): 𝐓❪n,c1❫ → 𝐓❪𝟎,c2❫ → 𝐓❪n,c1∨c2❫.
  31 // qed.
  32
  33 lemma rtc_ist_max_idem_sn (n) (c1) (c2): 𝐓❪n,c1❫ → 𝐓❪n,c2❫ → 𝐓❪n,c1∨c2❫.
  34 #n #c1 #c2 #H1 #H2 >(nmax_idem n) /2 width=1 by rtc_ist_max/
  35 qed.
  36
  37 (* Inversions with rtc_max **************************************************)
  38
  39 lemma rtc_ist_inv_max (n) (c1) (c2): 𝐓❪n,c1 ∨ c2❫ →
  40       ∃∃n1,n2. 𝐓❪n1,c1❫ & 𝐓❪n2,c2❫ & (n1 ∨ n2) = n.
  41 #n #c1 #c2 #H
  42 elim (rtc_max_inv_dx … H) -H #ri1 #rs1 #ti1 #ts1 #ri2 #rs2 #ti2 #ts2 #H1 #H2 #H3 #H4 #H5 #H6 destruct
  43 elim (eq_inv_nmax_zero … H1) -H1 #H11 #H12 destruct
  44 elim (eq_inv_nmax_zero … H2) -H2 #H21 #H22 destruct
  45 elim (eq_inv_nmax_zero … H3) -H3 #H31 #H32 destruct
  46 /2 width=5 by ex3_2_intro/
  47 qed-.
  48
  49 lemma rtc_ist_inv_zero_max (c1) (c2): 𝐓❪𝟎,c1 ∨ c2❫ → ∧∧ 𝐓❪𝟎,c1❫ & 𝐓❪𝟎,c2❫.
  50 #c1 #c2 #H
  51 elim (rtc_ist_inv_max … H) -H #n1 #n2 #Hn1 #Hn2 #H
  52 elim (eq_inv_nmax_zero … H) -H #H1 #H2 destruct
  53 /2 width=1 by conj/
  54 qed-.
  55
  56 lemma rtc_ist_inv_max_zero_dx (n) (c1) (c2): 𝐓❪n,c1 ∨ c2❫ → 𝐓❪𝟎,c2❫ → 𝐓❪n,c1❫.
  57 #n #c1 #c2 #H #H2
  58 elim (rtc_ist_inv_max … H) -H #n1 #n2 #Hn1 #Hn2 #H destruct //
  59 qed-.