matita/matita/contribs/lambdadelta/ground/counters/rtc_ist_plus.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/xoa/ex_3_2.ma".
  16 include "ground/counters/rtc_plus.ma".
  17 include "ground/counters/rtc_ist.ma".
  18
  19 (* T-BOUND RT-TRANSITION COUNTERS *******************************************)
  20
  21 (* Constructions with rtc_plus **********************************************)
  22
  23 lemma rtc_ist_plus (n1) (n2) (c1) (c2): 𝐓❨n1,c1❩ → 𝐓❨n2,c2❩ → 𝐓❨n1+n2,c1+c2❩.
  24 #n1 #n2 #c1 #c2 #H1 #H2 destruct //
  25 qed.
  26
  27 lemma rtc_ist_plus_zero_sn (n) (c1) (c2): 𝐓❨𝟎,c1❩ → 𝐓❨n,c2❩ → 𝐓❨n,c1+c2❩.
  28 #n #c1 #c2 #H1 #H2 >(nplus_zero_sn n)
  29 /2 width=1 by rtc_ist_plus/
  30 qed.
  31
  32 lemma rtc_ist_plus_zero_dx (n) (c1) (c2): 𝐓❨n,c1❩ → 𝐓❨𝟎,c2❩ → 𝐓❨n,c1+c2❩.
  33 /2 width=1 by rtc_ist_plus/ qed.
  34
  35 lemma rtc_ist_succ (n) (c): 𝐓❨n,c❩ → 𝐓❨↑n,c+𝟘𝟙❩.
  36 #n #c #H >nplus_unit_dx
  37 /2 width=1 by rtc_ist_plus/
  38 qed.
  39
  40 (* Inversions with rtc_plus *************************************************)
  41
  42 lemma rtc_ist_inv_plus (n) (c1) (c2): 𝐓❨n,c1 + c2❩ →
  43       ∃∃n1,n2. 𝐓❨n1,c1❩ & 𝐓❨n2,c2❩ & n1 + n2 = n.
  44 #n #c1 #c2 #H
  45 elim (rtc_plus_inv_dx … H) -H #ri1 #rs1 #ti1 #ts1 #ri2 #rs2 #ti2 #ts2 #H1 #H2 #H3 #H4 #H5 #H6 destruct
  46 elim (eq_inv_nplus_zero … H1) -H1 #H11 #H12 destruct
  47 elim (eq_inv_nplus_zero … H2) -H2 #H21 #H22 destruct
  48 elim (eq_inv_nplus_zero … H3) -H3 #H31 #H32 destruct
  49 /3 width=5 by ex3_2_intro/
  50 qed-.
  51
  52 lemma rtc_ist_inv_plus_zero_dx (n) (c1) (c2): 𝐓❨n,c1 + c2❩ → 𝐓❨𝟎,c2❩ → 𝐓❨n,c1❩.
  53 #n #c1 #c2 #H #H2
  54 elim (rtc_ist_inv_plus … H) -H #n1 #n2 #Hn1 #Hn2 #H destruct //
  55 qed-.
  56
  57 lemma rtc_ist_inv_plus_unit_dx:
  58       ∀n,c1,c2. 𝐓❨n,c1 + c2❩ → 𝐓❨𝟏,c2❩ →
  59       ∃∃m. 𝐓❨m,c1❩ & n = ↑m.
  60 #n #c1 #c2 #H #H2 destruct
  61 elim (rtc_ist_inv_plus … H) -H #n1 #n2 #Hn1 #Hn2 #H destruct
  62 /2 width=3 by ex2_intro/
  63 qed-.
  64
  65 lemma rtc_ist_inv_plus_zu_dx (n) (c): 𝐓❨n,c+𝟙𝟘❩ → ⊥.
  66 #n #c #H
  67 elim (rtc_ist_inv_plus … H) -H #n1 #n2 #_ #H #_
  68 /2 width=2 by rtc_ist_inv_uz/
  69 qed-.