matita/matita/contribs/lambdadelta/ground/counters/rtc_plus.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/xoa/ex_6_8.ma".
  16 include "ground/arith/nat_plus.ma".
  17 include "ground/counters/rtc.ma".
  18
  19 (* ADDITION FOR RT-TRANSITION COUNTERS **************************************)
  20
  21 definition rtc_plus (c1:rtc) (c2:rtc): rtc ≝
  22 match c1 with
  23 [ mk_rtc ri1 rs1 ti1 ts1 ⇒
  24   match c2 with
  25   [ mk_rtc ri2 rs2 ti2 ts2 ⇒ 〈ri1+ri2,rs1+rs2,ti1+ti2,ts1+ts2〉
  26   ]
  27 ].
  28
  29 interpretation
  30   "plus (rtc)"
  31   'plus c1 c2 = (rtc_plus c1 c2).
  32
  33 (* Basic constructions ******************************************************)
  34
  35 lemma rtc_plus_rew (ri1) (ri2) (rs1) (rs2) (ti1) (ti2) (ts1) (ts2):
  36       〈ri1+ri2,rs1+rs2,ti1+ti2,ts1+ts2〉 = 〈ri1,rs1,ti1,ts1〉+〈ri2,rs2,ti2,ts2〉.
  37 // qed.
  38
  39 lemma rtc_plus_zz_dx (c): c = c + 𝟘𝟘.
  40 * #ri #rs #ti #ts <rtc_plus_rew //
  41 qed.
  42
  43 (* Basic inversions *********************************************************)
  44
  45 lemma rtc_plus_inv_dx (ri) (rs) (ti) (ts) (c1) (c2):
  46       〈ri,rs,ti,ts〉 = c1 + c2 →
  47       ∃∃ri1,rs1,ti1,ts1,ri2,rs2,ti2,ts2.
  48       ri1+ri2 = ri & rs1+rs2 = rs & ti1+ti2 = ti & ts1+ts2 = ts &
  49       〈ri1,rs1,ti1,ts1〉 = c1 & 〈ri2,rs2,ti2,ts2〉 = c2.
  50 #ri #rs #ti #ts * #ri1 #rs1 #ti1 #ts1 * #ri2 #rs2 #ti2 #ts2
  51 <rtc_plus_rew #H destruct /2 width=14 by ex6_8_intro/
  52 qed-.
  53
  54 (* Main constructions *******************************************************)
  55
  56 theorem rtc_plus_assoc: associative … rtc_plus.
  57 * #ri1 #rs1 #ti1 #ts1 * #ri2 #rs2 #ti2 #ts2 * #ri3 #rs3 #ti3 #ts3
  58 <rtc_plus_rew //
  59 qed.