matita/matita/contribs/lambdadelta/ground/lib/arith.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basics/core_notation/exp_2.ma".
  16 include "arithmetics/nat.ma".
  17 include "ground/xoa/ex_3_1.ma".
  18 include "ground/xoa/or_3.ma".
  19 include "ground/notation/functions/uparrow_1.ma".
  20 include "ground/notation/functions/downarrow_1.ma".
  21 include "ground/pull/pull_2.ma".
  22 include "ground/lib/relations.ma".
  23
  24 (* ARITHMETICAL PROPERTIES **************************************************)
  25
  26 interpretation "nat successor" 'UpArrow m = (S m).
  27
  28 interpretation "nat predecessor" 'DownArrow m = (pred m).
  29
  30 interpretation "nat min" 'and x y = (min x y).
  31
  32 interpretation "nat max" 'or x y = (max x y).
  33
  34 (* Iota equations ***********************************************************)
  35
  36 lemma pred_O: pred 0 = 0.
  37 normalize // qed.
  38
  39 lemma pred_S: ∀m. pred (S m) = m.
  40 // qed.
  41
  42 lemma plus_S1: ∀x,y. ↑(x+y) = (↑x) + y.
  43 // qed.
  44
  45 lemma max_O1: ∀n. n = (0 ∨ n).
  46 // qed.
  47
  48 lemma max_O2: ∀n. n = (n ∨ 0).
  49 // qed.
  50
  51 lemma max_SS: ∀n1,n2. ↑(n1∨n2) = (↑n1 ∨ ↑n2).
  52 #n1 #n2 elim (decidable_le n1 n2) #H normalize
  53 [ >(le_to_leb_true … H) | >(not_le_to_leb_false … H) ] -H //
  54 qed.
  55
  56 (* Equalities ***************************************************************)
  57
  58 lemma plus_SO_sn (n): 1 + n = ↑n.
  59 // qed-.
  60
  61 lemma plus_SO_dx (n): n + 1 = ↑n.
  62 // qed.
  63
  64 lemma minus_SO_dx (n): n-1 = ↓n.
  65 // qed.
  66
  67 lemma minus_plus_m_m_commutative: ∀n,m:nat. n = m + n - m.
  68 // qed-.
  69
  70 lemma plus_minus_m_m_commutative (n) (m): m ≤ n → n = m+(n-m).
  71 /2 width=1 by plus_minus_associative/ qed-.
  72
  73 lemma plus_to_minus_2: ∀m1,m2,n1,n2. n1 ≤ m1 → n2 ≤ m2 →
  74                        m1+n2 = m2+n1 → m1-n1 = m2-n2.
  75 #m1 #m2 #n1 #n2 #H1 #H2 #H
  76 @plus_to_minus >plus_minus_associative //
  77 qed-.
  78
  79 (* Note: uses minus_minus_comm, minus_plus_m_m, commutative_plus, plus_minus *)
  80 lemma plus_minus_minus_be: ∀x,y,z. y ≤ z → z ≤ x → (x - z) + (z - y) = x - y.
  81 #x #z #y #Hzy #Hyx >plus_minus // >commutative_plus >plus_minus //
  82 qed-.
  83
  84 lemma lt_succ_pred: ∀m,n. n < m → m = ↑↓m.
  85 #m #n #Hm >S_pred /2 width=2 by ltn_to_ltO/
  86 qed-.
  87
  88 fact plus_minus_minus_be_aux: ∀i,x,y,z. y ≤ z → z ≤ x → i = z - y → x - z + i = x - y.
  89 /2 width=1 by plus_minus_minus_be/ qed-.
  90
  91 lemma le_plus_minus: ∀m,n,p. p ≤ n → m + n - p = m + (n - p).
  92 /2 by plus_minus/ qed-.
  93
  94 lemma le_plus_minus_comm: ∀n,m,p. p ≤ m → m + n - p = m - p + n.
  95 /2 by plus_minus/ qed-.
  96
  97 lemma minus_minus_comm3: ∀n,x,y,z. n-x-y-z = n-y-z-x.
  98 // qed.
  99
 100 lemma idempotent_max: ∀n:nat. n = (n ∨ n).
 101 #n normalize >le_to_leb_true //
 102 qed.
 103
 104 lemma associative_max: associative … max.
 105 #x #y #z normalize
 106 @(leb_elim x y) normalize #Hxy
 107 @(leb_elim y z) normalize #Hyz //
 108 [1,2: >le_to_leb_true /2 width=3 by transitive_le/
 109 | >not_le_to_leb_false /4 width=3 by lt_to_not_le, not_le_to_lt, transitive_lt/
 110   >not_le_to_leb_false //
 111 ]
 112 qed.
 113
 114 (* Properties ***************************************************************)
 115
 116 lemma eq_nat_dec: ∀n1,n2:nat. Decidable (n1 = n2).
 117 #n1 elim n1 -n1 [| #n1 #IHn1 ] * [2,4: #n2 ]
 118 [1,4: @or_intror #H destruct
 119 | elim (IHn1 n2) -IHn1 /3 width=1 by or_intror, or_introl/
 120 | /2 width=1 by or_introl/
 121 ]
 122 qed-.
 123
 124 lemma lt_or_eq_or_gt: ∀m,n. ∨∨ m < n | n = m | n < m.
 125 #m #n elim (lt_or_ge m n) /2 width=1 by or3_intro0/
 126 #H elim H -m /2 width=1 by or3_intro1/
 127 #m #Hm * /3 width=1 by not_le_to_lt, le_S_S, or3_intro2/
 128 qed-.
 129
 130 lemma monotonic_le_minus_l2: ∀x1,x2,y,z. x1 ≤ x2 → x1 - y - z ≤ x2 - y - z.
 131 /3 width=1 by monotonic_le_minus_l/ qed.
 132
 133 lemma minus_le_trans_sn: ∀x1,x2. x1 ≤ x2 → ∀x. x1-x ≤ x2.
 134 /2 width=3 by transitive_le/ qed.
 135
 136 lemma le_plus_to_minus_l: ∀a,b,c. a + b ≤ c → b ≤ c-a.
 137 /2 width=1 by le_plus_to_minus_r/
 138 qed-.
 139
 140 lemma le_plus_to_minus_comm: ∀n,m,p. n ≤ p+m → n-p ≤ m.
 141 /2 width=1 by le_plus_to_minus/ qed-.
 142
 143 lemma le_inv_S1: ∀m,n. ↑m ≤ n → ∃∃p. m ≤ p & ↑p = n.
 144 #m *
 145 [ #H lapply (le_n_O_to_eq … H) -H
 146   #H destruct
 147 | /3 width=3 by monotonic_pred, ex2_intro/
 148 ]
 149 qed-.
 150
 151 (* Note: this might interfere with nat.ma *)
 152 lemma monotonic_lt_pred: ∀m,n. m < n → 0 < m → pred m < pred n.
 153 #m #n #Hmn #Hm whd >(S_pred … Hm)
 154 @le_S_S_to_le >S_pred /2 width=3 by transitive_lt/
 155 qed.
 156
 157 lemma lt_S_S: ∀x,y. x < y → ↑x < ↑y.
 158 /2 width=1 by le_S_S/ qed.
 159
 160 lemma lt_S: ∀n,m. n < m → n < ↑m.
 161 /2 width=1 by le_S/ qed.
 162
 163 lemma monotonic_lt_minus_r:
 164 ∀p,q,n. q < n -> q < p → n-p < n-q.
 165 #p #q #n #Hn #H
 166 lapply (monotonic_le_minus_r … n H) -H #H
 167 @(le_to_lt_to_lt … H) -H
 168 /2 width=1 by lt_plus_to_minus/
 169 qed.
 170
 171 lemma max_S1_le_S: ∀n1,n2,n. (n1 ∨ n2) ≤ n → (↑n1 ∨ n2) ≤ ↑n.
 172 /4 width=2 by to_max, le_maxr, le_S_S, le_S/ qed-.
 173
 174 lemma max_S2_le_S: ∀n1,n2,n. (n1 ∨ n2) ≤ n → (n1 ∨ ↑n2) ≤ ↑n.
 175 /2 width=1 by max_S1_le_S/ qed-.
 176
 177 (* Inversion & forward lemmas ***********************************************)
 178
 179 lemma lt_refl_false: ∀n. n < n → ⊥.
 180 #n #H elim (lt_to_not_eq … H) -H /2 width=1 by/
 181 qed-.
 182
 183 lemma lt_zero_false: ∀n. n < 0 → ⊥.
 184 #n #H elim (lt_to_not_le … H) -H /2 width=1 by/
 185 qed-.
 186
 187 lemma lt_le_false: ∀x,y. x < y → y ≤ x → ⊥.
 188 /3 width=4 by lt_refl_false, lt_to_le_to_lt/ qed-.
 189
 190 lemma le_dec (n) (m): Decidable (n≤m).
 191 #n elim n -n [ /2 width=1 by or_introl/ ]
 192 #n #IH * [ /3 width=2 by lt_zero_false, or_intror/ ]
 193 #m elim (IH m) -IH
 194 [ /3 width=1 by or_introl, le_S_S/
 195 | /4 width=1 by or_intror, le_S_S_to_le/
 196 ]
 197 qed-.
 198
 199 lemma succ_inv_refl_sn: ∀x. ↑x = x → ⊥.
 200 #x #H @(lt_le_false x (↑x)) //
 201 qed-.
 202
 203 lemma le_plus_xSy_O_false: ∀x,y. x + S y ≤ 0 → ⊥.
 204 #x #y #H lapply (le_n_O_to_eq … H) -H <plus_n_Sm #H destruct
 205 qed-.
 206
 207 lemma le_plus_xySz_x_false: ∀y,z,x. x + y + S z ≤ x → ⊥.
 208 #y #z #x elim x -x /3 width=1 by le_S_S_to_le/
 209 #H elim (le_plus_xSy_O_false … H)
 210 qed-.
 211
 212 lemma plus_xySz_x_false: ∀z,x,y. x + y + S z = x → ⊥.
 213 /2 width=4 by le_plus_xySz_x_false/ qed-.
 214
 215 lemma plus_xSy_x_false: ∀y,x. x + S y = x → ⊥.
 216 /2 width=4 by plus_xySz_x_false/ qed-.
 217
 218 lemma pred_inv_fix_sn: ∀x. ↓x = x → 0 = x.
 219 * // #x <pred_Sn #H
 220 elim (succ_inv_refl_sn x) //
 221 qed-.
 222
 223 lemma discr_plus_xy_y: ∀x,y. x + y = y → x = 0.
 224 // qed-.
 225
 226 lemma discr_plus_x_xy: ∀x,y. x = x + y → y = 0.
 227 /2 width=2 by le_plus_minus_comm/ qed-.
 228
 229 lemma plus2_le_sn_sn: ∀m1,m2,n1,n2. m1 + n1 = m2 + n2 → m1 ≤ m2 → n2 ≤ n1.
 230 #m1 #m2 #n1 #n2 #H #Hm
 231 lapply (monotonic_le_plus_l n1 … Hm) -Hm >H -H
 232 /2 width=2 by le_plus_to_le/
 233 qed-.
 234
 235 lemma plus2_le_sn_dx: ∀m1,m2,n1,n2. m1 + n1 = n2 + m2 → m1 ≤ m2 → n2 ≤ n1.
 236 /2 width=4 by plus2_le_sn_sn/ qed-.
 237
 238 lemma plus2_le_dx_sn: ∀m1,m2,n1,n2. n1 + m1 = m2 + n2 → m1 ≤ m2 → n2 ≤ n1.
 239 /2 width=4 by plus2_le_sn_sn/ qed-.
 240
 241 lemma plus2_le_dx_dx: ∀m1,m2,n1,n2. n1 + m1 = n2 + m2 → m1 ≤ m2 → n2 ≤ n1.
 242 /2 width=4 by plus2_le_sn_sn/ qed-.
 243
 244 lemma lt_S_S_to_lt: ∀x,y. ↑x < ↑y → x < y.
 245 /2 width=1 by le_S_S_to_le/ qed-.
 246
 247 (* Note this should go in nat.ma *)
 248 lemma discr_x_minus_xy: ∀x,y. x = x - y → x = 0 ∨ y = 0.
 249 #x @(nat_ind_plus … x) -x /2 width=1 by or_introl/
 250 #x #_ #y @(nat_ind_plus … y) -y /2 width=1 by or_intror/
 251 #y #_ >minus_plus_plus_l
 252 #H lapply (discr_plus_xy_minus_xz … H) -H
 253 #H destruct
 254 qed-.
 255
 256 lemma lt_inv_O1: ∀n. 0 < n → ∃m. ↑m = n.
 257 * /2 width=2 by ex_intro/
 258 #H cases (lt_le_false … H) -H //
 259 qed-.
 260
 261 lemma lt_inv_S1: ∀m,n. ↑m < n → ∃∃p. m < p & ↑p = n.
 262 #m * /3 width=3 by lt_S_S_to_lt, ex2_intro/
 263 #H cases (lt_le_false … H) -H //
 264 qed-.
 265
 266 lemma lt_inv_gen: ∀y,x. x < y → ∃∃z. x ≤ z & ↑z = y.
 267 * /3 width=3 by le_S_S_to_le, ex2_intro/
 268 #x #H elim (lt_le_false … H) -H //
 269 qed-.
 270
 271 lemma plus_inv_O3: ∀x,y. x + y = 0 → x = 0 ∧ y = 0.
 272 /2 width=1 by plus_le_0/ qed-.
 273
 274 lemma plus_inv_S3_sn: ∀x1,x2,x3. x1+x2 = ↑x3 →
 275                       ∨∨ ∧∧ x1 = 0 & x2 = ↑x3
 276                        | ∃∃y1. x1 = ↑y1 & y1 + x2 = x3.
 277 * /3 width=1 by or_introl, conj/
 278 #x1 #x2 #x3 <plus_S1 #H destruct
 279 /3 width=3 by ex2_intro, or_intror/
 280 qed-.
 281
 282 lemma plus_inv_S3_dx: ∀x2,x1,x3. x1+x2 = ↑x3 →
 283                       ∨∨ ∧∧ x2 = 0 & x1 = ↑x3
 284                        | ∃∃y2. x2 = ↑y2 & x1 + y2 = x3.
 285 * /3 width=1 by or_introl, conj/
 286 #x2 #x1 #x3 <plus_n_Sm #H destruct
 287 /3 width=3 by ex2_intro, or_intror/
 288 qed-.
 289
 290 lemma max_inv_O3: ∀x,y. (x ∨ y) = 0 → 0 = x ∧ 0 = y.
 291 /4 width=2 by le_maxr, le_maxl, le_n_O_to_eq, conj/
 292 qed-.
 293
 294 lemma zero_eq_plus: ∀x,y. 0 = x + y → 0 = x ∧ 0 = y.
 295 * /2 width=1 by conj/ #x #y normalize #H destruct
 296 qed-.
 297
 298 lemma nat_split: ∀x. x = 0 ∨ ∃y. ↑y = x.
 299 * /3 width=2 by ex_intro, or_introl, or_intror/
 300 qed-.
 301
 302 lemma lt_elim: ∀R:relation nat.
 303                (∀n2. R O (↑n2)) →
 304                (∀n1,n2. R n1 n2 → R (↑n1) (↑n2)) →
 305                ∀n2,n1. n1 < n2 → R n1 n2.
 306 #R #IH1 #IH2 #n2 elim n2 -n2
 307 [ #n1 #H elim (lt_le_false … H) -H //
 308 | #n2 #IH * /4 width=1 by lt_S_S_to_lt/
 309 ]
 310 qed-.
 311
 312 lemma le_elim: ∀R:relation nat.
 313                (∀n2. R O (n2)) →
 314                (∀n1,n2. R n1 n2 → R (↑n1) (↑n2)) →
 315                ∀n1,n2. n1 ≤ n2 → R n1 n2.
 316 #R #IH1 #IH2 #n1 #n2 @(nat_elim2 … n1 n2) -n1 -n2
 317 /4 width=1 by monotonic_pred/ -IH1 -IH2
 318 #n1 #H elim (lt_le_false … H) -H //
 319 qed-.
 320
 321 lemma nat_elim_le_sn (Q:relation …):
 322       (∀m1,m2. (∀m. m < m2-m1 → Q (m2-m) m2) → m1 ≤ m2 → Q m1 m2) →
 323       ∀n1,n2. n1 ≤ n2 → Q n1 n2.
 324 #Q #IH #n1 #n2 #Hn
 325 <(minus_minus_m_m … Hn) -Hn
 326 lapply (minus_le n2 n1)
 327 let d ≝ (n2-n1)
 328 @(nat_elim1 … d) -d -n1 #d
 329 @pull_2 #Hd
 330 <(minus_minus_m_m … Hd) in ⊢ (%→?); -Hd
 331 let n1 ≝ (n2-d) #IHd
 332 @IH -IH [| // ] #m #Hn
 333 /4 width=3 by lt_to_le, lt_to_le_to_lt/
 334 qed-.
 335
 336 (* Iterators ****************************************************************)
 337
 338 (* Note: see also: lib/arithemetics/bigops.ma *)
 339 rec definition iter (n:nat) (B:Type[0]) (op: B → B) (nil: B) ≝
 340   match n with
 341    [ O   ⇒ nil
 342    | S k ⇒ op (iter k B op nil)
 343    ].
 344
 345 interpretation "iterated function" 'exp op n = (iter n ? op).
 346
 347 lemma iter_O: ∀B:Type[0]. ∀f:B→B.∀b. f^0 b = b.
 348 // qed.
 349
 350 lemma iter_S: ∀B:Type[0]. ∀f:B→B.∀b,l. f^(S l) b = f (f^l b).
 351 // qed.
 352
 353 lemma iter_n_Sm: ∀B:Type[0]. ∀f:B→B. ∀b,l. f^l (f b) = f (f^l b).
 354 #B #f #b #l elim l -l normalize //
 355 qed.
 356
 357 lemma iter_plus: ∀B:Type[0]. ∀f:B→B. ∀b,l1,l2. f^(l1+l2) b = f^l1 (f^l2 b).
 358 #B #f #b #l1 elim l1 -l1 normalize //
 359 qed.
 360
 361 (* Trichotomy operator ******************************************************)
 362
 363 (* Note: this is "if eqb n1 n2 then a2 else if leb n1 n2 then a1 else a3" *)
 364 rec definition tri (A:Type[0]) n1 n2 a1 a2 a3 on n1 : A ≝
 365   match n1 with
 366   [ O    ⇒ match n2 with [ O ⇒ a2 | S n2 ⇒ a1 ]
 367   | S n1 ⇒ match n2 with [ O ⇒ a3 | S n2 ⇒ tri A n1 n2 a1 a2 a3 ]
 368   ].
 369
 370 lemma tri_lt: ∀A,a1,a2,a3,n2,n1. n1 < n2 → tri A n1 n2 a1 a2 a3 = a1.
 371 #A #a1 #a2 #a3 #n2 elim n2 -n2
 372 [ #n1 #H elim (lt_zero_false … H)
 373 | #n2 #IH #n1 elim n1 -n1 /3 width=1 by monotonic_lt_pred/
 374 ]
 375 qed.
 376
 377 lemma tri_eq: ∀A,a1,a2,a3,n. tri A n n a1 a2 a3 = a2.
 378 #A #a1 #a2 #a3 #n elim n -n normalize //
 379 qed.
 380
 381 lemma tri_gt: ∀A,a1,a2,a3,n1,n2. n2 < n1 → tri A n1 n2 a1 a2 a3 = a3.
 382 #A #a1 #a2 #a3 #n1 elim n1 -n1
 383 [ #n2 #H elim (lt_zero_false … H)
 384 | #n1 #IH #n2 elim n2 -n2 /3 width=1 by monotonic_lt_pred/
 385 ]
 386 qed.
 387
 388 (* Decidability of predicates ***********************************************)
 389
 390 lemma dec_lt (R:predicate nat):
 391       (∀n. Decidable … (R n)) →
 392       ∀n. Decidable … (∃∃m. m < n & R m).
 393 #R #HR #n elim n -n [| #n * ]
 394 [ @or_intror * /2 width=2 by lt_zero_false/
 395 | * /4 width=3 by lt_S, or_introl, ex2_intro/
 396 | #H0 elim (HR n) -HR
 397   [ /3 width=3 by or_introl, ex2_intro/
 398   | #Hn @or_intror * #m #Hmn #Hm
 399     elim (le_to_or_lt_eq … Hmn) -Hmn #H destruct [ -Hn | -H0 ]
 400     /4 width=3 by lt_S_S_to_lt, ex2_intro/
 401   ]
 402 ]
 403 qed-.
 404
 405 lemma dec_min (R:predicate nat):
 406       (∀n. Decidable … (R n)) → ∀n. R n →
 407       ∃∃m. m ≤ n & R m & (∀p. p < m → R p → ⊥).
 408 #R #HR #n
 409 @(nat_elim1 n) -n #n #IH #Hn
 410 elim (dec_lt … HR n) -HR [ -Hn | -IH ]
 411 [ * #p #Hpn #Hp
 412   elim (IH … Hpn Hp) -IH -Hp #m #Hmp #Hm #HNm
 413   @(ex3_intro … Hm HNm) -HNm
 414   /3 width=3 by lt_to_le, le_to_lt_to_lt/
 415 | /4 width=4 by ex3_intro, ex2_intro/
 416 ]
 417 qed-.