matita/matita/contribs/lambdadelta/ground/lib/list_length.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/lib/arith.ma".
  16 include "ground/lib/list.ma".
  17
  18 (* LENGTH OF A LIST *********************************************************)
  19
  20 rec definition length A (l:list A) on l ≝ match l with
  21 [ nil      ⇒ 0
  22 | cons _ l ⇒ ↑(length A l)
  23 ].
  24
  25 interpretation "length (list)"
  26    'card l = (length ? l).
  27
  28 (* Basic properties *********************************************************)
  29
  30 lemma length_nil (A:Type[0]): |nil A| = 0.
  31 // qed.
  32
  33 lemma length_cons (A:Type[0]) (l:list A) (a:A): |a⨮l| = ↑|l|.
  34 // qed.
  35
  36 (* Basic inversion lemmas ***************************************************)
  37
  38 lemma length_inv_zero_dx (A:Type[0]) (l:list A): |l| = 0 → l = Ⓔ.
  39 #A * // #a #l >length_cons #H destruct
  40 qed-.
  41
  42 lemma length_inv_zero_sn (A:Type[0]) (l:list A): 0 = |l| → l = Ⓔ.
  43 /2 width=1 by length_inv_zero_dx/ qed-.
  44
  45 lemma length_inv_succ_dx (A:Type[0]) (l:list A) (x): |l| = ↑x →
  46                          ∃∃tl,a. x = |tl| & l = a ⨮ tl.
  47 #A *
  48 [ #x >length_nil #H destruct
  49 | #a #l #x >length_cons #H destruct /2 width=4 by ex2_2_intro/
  50 ]
  51 qed-.
  52
  53 lemma length_inv_succ_sn (A:Type[0]) (l:list A) (x): ↑x = |l| →
  54                          ∃∃tl,a. x = |tl| & l = a ⨮ tl.
  55 /2 width=1 by length_inv_succ_dx/ qed.