matita/matita/contribs/lambdadelta/ground/lib/ltc.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/generated/insert_eq_1.ma".
  16 include "ground/lib/functions.ma".
  17
  18 (* LABELLED TRANSITIVE CLOSURE FOR RELATIONS ********************************)
  19
  20 inductive ltc (A:Type[0]) (f) (B) (R:relation3 A B B): relation3 A B B ≝
  21 | ltc_rc   : ∀a,b1,b2. R a b1 b2 → ltc … a b1 b2
  22 | ltc_trans: ∀a1,a2,b1,b,b2. ltc … a1 b1 b → ltc … a2 b b2 → ltc … (f a1 a2) b1 b2
  23 .
  24
  25 (* Basic constructions ******************************************************)
  26
  27 lemma ltc_sn (A) (f) (B) (R):
  28       ∀a1,b1,b. R a1 b1 b →
  29       ∀a2,b2. ltc A f B R a2 b b2 → ltc … f … R (f a1 a2) b1 b2.
  30 /3 width=3 by ltc_rc, ltc_trans/ qed.
  31
  32 lemma ltc_dx (A) (f) (B) (R):
  33       ∀a1,b1,b. ltc A f B R a1 b1 b →
  34       ∀a2,b2. R a2 b b2 → ltc … f … R (f a1 a2) b1 b2.
  35 /3 width=3 by ltc_rc, ltc_trans/ qed.
  36
  37 (* Basic eliminations *******************************************************)
  38
  39 lemma ltc_ind_sn (A) (f) (B) (R) (Q:relation2 A B) (b2):
  40       associative … f →
  41       (∀a,b1. R a b1 b2 → Q a b1) →
  42       (∀a1,a2,b1,b. R a1 b1 b → ltc … f … R a2 b b2 → Q a2 b → Q (f a1 a2) b1) →
  43       ∀a,b1. ltc … f … R a b1 b2 → Q a b1.
  44 #A #f #B #R #Q #b2 #Hf #IH1 #IH2 #a #b1 @(insert_eq_1 … b2)
  45 #b0 #H elim H -a -b1 -b0 /2 width=2 by/
  46 #a1 #a2 #b1 #b #b0 #H #Hb2 #_
  47 generalize in match Hb2; generalize in match a2; -Hb2 -a2
  48 elim H -a1 -b1 -b /4 width=4 by ltc_trans/
  49 qed-.
  50
  51 lemma ltc_ind_dx (A) (f) (B) (R) (Q:A→predicate B) (b1):
  52       associative … f →
  53       (∀a,b2. R a b1 b2 → Q a b2) →
  54       (∀a1,a2,b,b2. ltc … f … R a1 b1 b → Q a1 b → R a2 b b2 → Q (f a1 a2) b2) →
  55       ∀a,b2. ltc … f … R a b1 b2 → Q a b2.
  56 #A #f #B #R #Q #b1 #Hf #IH1 #IH2 #a #b2 @(insert_eq_1 … b1)
  57 #b0 #H elim H -a -b0 -b2 /2 width=2 by/
  58 #a1 #a2 #b0 #b #b2 #Hb0 #H #IHb0 #_
  59 generalize in match IHb0; generalize in match Hb0; generalize in match a1; -IHb0 -Hb0 -a1
  60 elim H -a2 -b -b2 /4 width=4 by ltc_trans/
  61 qed-.
  62
  63 (* Advanced eliminations (with reflexivity) *********************************)
  64
  65 lemma ltc_ind_sn_refl (A) (i) (f) (B) (R) (Q:relation2 A B) (b2):
  66       associative … f → right_identity … f i → reflexive B (R i) →
  67       Q i b2 →
  68       (∀a1,a2,b1,b. R a1 b1 b → ltc … f … R a2 b b2 → Q a2 b → Q (f a1 a2) b1) →
  69       ∀a,b1. ltc … f … R a b1 b2 → Q a b1.
  70 #A #i #f #B #R #Q #b2 #H1f #H2f #HR #IH1 #IH2 #a #b1 #H
  71 @(ltc_ind_sn … R … H1f … IH2 … H) -a -b1 -H1f #a #b1 #Hb12
  72 >(H2f a) -H2f /3 width=4 by ltc_rc/
  73 qed-.
  74
  75 lemma ltc_ind_dx_refl (A) (i) (f) (B) (R) (Q:A→predicate B) (b1):
  76       associative … f → left_identity … f i → reflexive B (R i) →
  77       Q i b1 →
  78       (∀a1,a2,b,b2. ltc … f … R a1 b1 b → Q a1 b → R a2 b b2 → Q (f a1 a2) b2) →
  79       ∀a,b2. ltc … f … R a b1 b2 → Q a b2.
  80 #A #i #f #B #R #Q #b1 #H1f #H2f #HR #IH1 #IH2 #a #b2 #H
  81 @(ltc_ind_dx … R … H1f … IH2 … H) -a -b2 -H1f #a #b2 #Hb12
  82 >(H2f a) -H2f /3 width=4 by ltc_rc/
  83 qed-.
  84
  85 (* Constructions with lsub **************************************************)
  86
  87 lemma ltc_lsub_trans (A) (f) (B) (C) (R) (S):
  88       associative … f →
  89       (∀n. lsub_trans B C (λL. R L n) S) →
  90       ∀n. lsub_trans B C (λL. ltc A f … (R L) n) S.
  91 #A #f #B #C #R #S #Hf #HRS #n #L2 #T1 #T2 #H
  92 @(ltc_ind_dx … Hf ???? H) -n -T2
  93 /3 width=5 by ltc_dx, ltc_rc/
  94 qed-.