matita/matita/contribs/lambdadelta/ground/lib/relations.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basics/relations.ma".
  16 include "ground/xoa/and_3.ma".
  17 include "ground/xoa/ex_2_2.ma".
  18 include "ground/lib/logic.ma".
  19
  20 (* RELATIONS ****************************************************************)
  21
  22 definition relation5: Type[0] → Type[0] → Type[0] → Type[0] → Type[0] → Type[0] ≝
  23            λA,B,C,D,E.A→B→C→D→E→Prop.
  24
  25 definition relation6: Type[0] → Type[0] → Type[0] → Type[0] → Type[0] → Type[0] → Type[0] ≝
  26            λA,B,C,D,E,F.A→B→C→D→E→F→Prop.
  27
  28 definition replace_2 (A) (B): relation3 (relation2 A B) (relation A) (relation B) ≝
  29            λR,Sa,Sb. ∀a1,b1. R a1 b1 → ∀a2. Sa a1 a2 → ∀b2. Sb b1 b2 → R a2 b2.
  30
  31 (* * we don't use "∀a. reflexive … (R a)" since auto seems to dislike repeatd δ-expansion *)
  32 definition c_reflexive (A) (B): predicate (relation3 A B B) ≝
  33            λR. ∀a,b. R a b b.
  34
  35 definition Decidable: Prop → Prop ≝ λR. R ∨ (R → ⊥).
  36
  37 definition Transitive (A) (R:relation A): Prop ≝
  38            ∀a1,a0. R a1 a0 → ∀a2. R a0 a2 → R a1 a2.
  39
  40 definition left_cancellable (A) (R:relation A): Prop ≝
  41            ∀a0,a1. R a0 a1 → ∀a2. R a0 a2 → R a1 a2.
  42
  43 definition right_cancellable (A) (R:relation A): Prop ≝
  44            ∀a1,a0. R a1 a0 → ∀a2. R a2 a0 → R a1 a2.
  45
  46 definition pw_confluent2 (A) (R1,R2:relation A): predicate A ≝
  47            λa0.
  48            ∀a1. R1 a0 a1 → ∀a2. R2 a0 a2 →
  49            ∃∃a. R2 a1 a & R1 a2 a.
  50
  51 definition confluent2 (A): relation (relation A) ≝
  52            λR1,R2.
  53            ∀a0. pw_confluent2 A R1 R2 a0.
  54
  55 definition transitive2 (A) (R1,R2:relation A): Prop ≝
  56            ∀a1,a0. R1 a1 a0 → ∀a2. R2 a0 a2 →
  57            ∃∃a. R2 a1 a & R1 a a2.
  58
  59 definition confluent1 (A) (B): relation2 (relation2 A B) (relation A) ≝
  60            λR1,R2. ∀a1,b. R1 a1 b → ∀a2. R2 a1 a2 → R1 a2 b.
  61
  62 definition bi_confluent (A) (B) (R: bi_relation A B): Prop ≝
  63            ∀a0,a1,b0,b1. R a0 b0 a1 b1 → ∀a2,b2. R a0 b0 a2 b2 →
  64            ∃∃a,b. R a1 b1 a b & R a2 b2 a b.
  65
  66 definition lsub_trans (A) (B): relation2 (A→relation B) (relation A) ≝
  67            λR1,R2.
  68            ∀L2,T1,T2. R1 L2 T1 T2 → ∀L1. R2 L1 L2 → R1 L1 T1 T2.
  69
  70 definition s_r_confluent1 (A) (B): relation2 (A→relation B) (B→relation A) ≝
  71            λR1,R2.
  72            ∀L1,T1,T2. R1 L1 T1 T2 → ∀L2. R2 T1 L1 L2 → R2 T2 L1 L2.
  73
  74 definition is_mono (B:Type[0]): predicate (predicate B) ≝
  75            λR. ∀b1. R b1 → ∀b2. R b2 → b1 = b2.
  76
  77 definition is_inj2 (A,B:Type[0]): predicate (relation2 A B) ≝
  78            λR. ∀a1,b. R a1 b → ∀a2. R a2 b → a1 = a2.
  79
  80 (* NOTE: Normal form and strong normalization *******************************)
  81
  82 definition NF (A): relation A → relation A → predicate A ≝
  83            λR,S,a1. ∀a2. R a1 a2 → S a1 a2.
  84
  85 definition NF_dec (A): relation A → relation A → Prop ≝
  86            λR,S. ∀a1. NF … R S a1 ∨
  87            ∃∃a2. R … a1 a2 & (S a1 a2 → ⊥).
  88
  89 inductive SN (A) (R,S:relation A): predicate A ≝
  90 | SN_intro: ∀a1. (∀a2. R a1 a2 → (S a1 a2 → ⊥) → SN … R S a2) → SN … R S a1
  91 .
  92
  93 lemma NF_to_SN (A) (R) (S): ∀a. NF A R S a → SN A R S a.
  94 #A #R #S #a1 #Ha1
  95 @SN_intro #a2 #HRa12 #HSa12
  96 elim HSa12 -HSa12 /2 width=1 by/
  97 qed.
  98
  99 definition NF_sn (A): relation A → relation A → predicate A ≝
 100            λR,S,a2. ∀a1. R a1 a2 → S a1 a2.
 101
 102 inductive SN_sn (A) (R,S:relation A): predicate A ≝
 103 | SN_sn_intro: ∀a2. (∀a1. R a1 a2 → (S a1 a2 → ⊥) → SN_sn … R S a1) → SN_sn … R S a2
 104 .
 105
 106 lemma NF_to_SN_sn (A) (R) (S): ∀a. NF_sn A R S a → SN_sn A R S a.
 107 #A #R #S #a2 #Ha2
 108 @SN_sn_intro #a1 #HRa12 #HSa12
 109 elim HSa12 -HSa12 /2 width=1 by/
 110 qed.
 111
 112 (* NOTE: Normal form and strong normalization with unboxed triples **********)
 113
 114 inductive SN3 (A) (B) (C) (R,S:relation6 A B C A B C): relation3 A B C ≝
 115 | SN3_intro: ∀a1,b1,c1. (∀a2,b2,c2. R a1 b1 c1 a2 b2 c2 → (S a1 b1 c1 a2 b2 c2 → ⊥) → SN3 … R S a2 b2 c2) → SN3 … R S a1 b1 c1
 116 .
 117
 118 (* NOTE: Reflexive closure with unboxed triples *****************************)
 119
 120 definition tri_RC (A,B,C): tri_relation A B C → tri_relation A B C ≝
 121            λR,a1,b1,c1,a2,b2,c2.
 122            ∨∨ R … a1 b1 c1 a2 b2 c2
 123             | ∧∧ a1 = a2 & b1 = b2 & c1 = c2.
 124
 125 lemma tri_RC_reflexive (A) (B) (C): ∀R. tri_reflexive A B C (tri_RC … R).
 126 /3 width=1 by and3_intro, or_intror/ qed.
 127
 128 (* NOTE: Inclusion for relations ********************************************)
 129
 130 definition subR2 (S1) (S2): relation (relation2 S1 S2) ≝
 131            λR1,R2. (∀a1,a2. R1 a1 a2 → R2 a1 a2).
 132
 133 interpretation
 134   "2-relation inclusion"
 135   'subseteq R1 R2 = (subR2 ?? R1 R2).
 136
 137 definition subR3 (S1) (S2) (S3): relation (relation3 S1 S2 S3) ≝
 138            λR1,R2. (∀a1,a2,a3. R1 a1 a2 a3 → R2 a1 a2 a3).
 139
 140 interpretation
 141   "3-relation inclusion"
 142   'subseteq R1 R2 = (subR3 ??? R1 R2).
 143
 144 (* Main constructions with eq ***********************************************)
 145
 146 theorem canc_sn_eq (A): left_cancellable A (eq …).
 147 // qed-.
 148
 149 theorem canc_dx_eq (A): right_cancellable A (eq …).
 150 // qed-.