matita/matita/contribs/lambdadelta/ground/lib/relations.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basics/relations.ma".
  16 include "ground/xoa/and_3.ma".
  17 include "ground/xoa/ex_2_2.ma".
  18 include "ground/lib/logic.ma".
  19
  20 (* GENERIC RELATIONS ********************************************************)
  21
  22 definition replace_2 (A) (B): relation3 (relation2 A B) (relation A) (relation B) ≝
  23            λR,Sa,Sb. ∀a1,b1. R a1 b1 → ∀a2. Sa a1 a2 → ∀b2. Sb b1 b2 → R a2 b2.
  24
  25 (* Inclusion ****************************************************************)
  26
  27 definition subR2 (S1) (S2): relation (relation2 S1 S2) ≝
  28            λR1,R2. (∀a1,a2. R1 a1 a2 → R2 a1 a2).
  29
  30 interpretation "2-relation inclusion"
  31    'subseteq R1 R2 = (subR2 ?? R1 R2).
  32
  33 definition subR3 (S1) (S2) (S3): relation (relation3 S1 S2 S3) ≝
  34            λR1,R2. (∀a1,a2,a3. R1 a1 a2 a3 → R2 a1 a2 a3).
  35
  36 interpretation "3-relation inclusion"
  37    'subseteq R1 R2 = (subR3 ??? R1 R2).
  38
  39 (* Properties of relations **************************************************)
  40
  41 definition relation5: Type[0] → Type[0] → Type[0] → Type[0] → Type[0] → Type[0] ≝
  42            λA,B,C,D,E.A→B→C→D→E→Prop.
  43
  44 definition relation6: Type[0] → Type[0] → Type[0] → Type[0] → Type[0] → Type[0] → Type[0] ≝
  45            λA,B,C,D,E,F.A→B→C→D→E→F→Prop.
  46
  47 (**) (* we don't use "∀a. reflexive … (R a)" since auto seems to dislike repeatd δ-expansion *)
  48 definition c_reflexive (A) (B): predicate (relation3 A B B) ≝
  49            λR. ∀a,b. R a b b.
  50
  51 definition Decidable: Prop → Prop ≝ λR. R ∨ (R → ⊥).
  52
  53 definition Transitive (A) (R:relation A): Prop ≝
  54            ∀a1,a0. R a1 a0 → ∀a2. R a0 a2 → R a1 a2.
  55
  56 definition left_cancellable (A) (R:relation A): Prop ≝
  57            ∀a0,a1. R a0 a1 → ∀a2. R a0 a2 → R a1 a2.
  58
  59 definition right_cancellable (A) (R:relation A): Prop ≝
  60            ∀a1,a0. R a1 a0 → ∀a2. R a2 a0 → R a1 a2.
  61
  62 definition pw_confluent2 (A) (R1,R2:relation A): predicate A ≝
  63            λa0.
  64            ∀a1. R1 a0 a1 → ∀a2. R2 a0 a2 →
  65            ∃∃a. R2 a1 a & R1 a2 a.
  66
  67 definition confluent2 (A): relation (relation A) ≝
  68            λR1,R2.
  69            ∀a0. pw_confluent2 A R1 R2 a0.
  70
  71 definition transitive2 (A) (R1,R2:relation A): Prop ≝
  72            ∀a1,a0. R1 a1 a0 → ∀a2. R2 a0 a2 →
  73            ∃∃a. R2 a1 a & R1 a a2.
  74
  75 definition confluent1 (A) (B): relation2 (relation2 A B) (relation A) ≝
  76            λR1,R2. ∀a1,b. R1 a1 b → ∀a2. R2 a1 a2 → R1 a2 b.
  77
  78 definition bi_confluent (A) (B) (R: bi_relation A B): Prop ≝
  79            ∀a0,a1,b0,b1. R a0 b0 a1 b1 → ∀a2,b2. R a0 b0 a2 b2 →
  80            ∃∃a,b. R a1 b1 a b & R a2 b2 a b.
  81
  82 definition lsub_trans (A) (B): relation2 (A→relation B) (relation A) ≝
  83            λR1,R2.
  84            ∀L2,T1,T2. R1 L2 T1 T2 → ∀L1. R2 L1 L2 → R1 L1 T1 T2.
  85
  86 definition s_r_confluent1 (A) (B): relation2 (A→relation B) (B→relation A) ≝
  87            λR1,R2.
  88            ∀L1,T1,T2. R1 L1 T1 T2 → ∀L2. R2 T1 L1 L2 → R2 T2 L1 L2.
  89
  90 definition is_mono (B:Type[0]): predicate (predicate B) ≝
  91            λR. ∀b1. R b1 → ∀b2. R b2 → b1 = b2.
  92
  93 definition is_inj2 (A,B:Type[0]): predicate (relation2 A B) ≝
  94            λR. ∀a1,b. R a1 b → ∀a2. R a2 b → a1 = a2.
  95
  96 (* Main properties of equality **********************************************)
  97
  98 theorem canc_sn_eq (A): left_cancellable A (eq …).
  99 // qed-.
 100
 101 theorem canc_dx_eq (A): right_cancellable A (eq …).
 102 // qed-.
 103
 104 (* Normal form and strong normalization *************************************)
 105
 106 definition NF (A): relation A → relation A → predicate A ≝
 107            λR,S,a1. ∀a2. R a1 a2 → S a1 a2.
 108
 109 definition NF_dec (A): relation A → relation A → Prop ≝
 110            λR,S. ∀a1. NF A R S a1 ∨
 111            ∃∃a2. R … a1 a2 & (S a1 a2 → ⊥).
 112
 113 inductive SN (A) (R,S:relation A): predicate A ≝
 114 | SN_intro: ∀a1. (∀a2. R a1 a2 → (S a1 a2 → ⊥) → SN A R S a2) → SN A R S a1
 115 .
 116
 117 lemma NF_to_SN (A) (R) (S): ∀a. NF A R S a → SN A R S a.
 118 #A #R #S #a1 #Ha1
 119 @SN_intro #a2 #HRa12 #HSa12
 120 elim HSa12 -HSa12 /2 width=1 by/
 121 qed.
 122
 123 definition NF_sn (A): relation A → relation A → predicate A ≝
 124    λR,S,a2. ∀a1. R a1 a2 → S a1 a2.
 125
 126 inductive SN_sn (A) (R,S:relation A): predicate A ≝
 127 | SN_sn_intro: ∀a2. (∀a1. R a1 a2 → (S a1 a2 → ⊥) → SN_sn A R S a1) → SN_sn A R S a2
 128 .
 129
 130 lemma NF_to_SN_sn (A) (R) (S): ∀a. NF_sn A R S a → SN_sn A R S a.
 131 #A #R #S #a2 #Ha2
 132 @SN_sn_intro #a1 #HRa12 #HSa12
 133 elim HSa12 -HSa12 /2 width=1 by/
 134 qed.
 135
 136 (* Relations on unboxed triples *********************************************)
 137
 138 definition tri_RC (A,B,C): tri_relation A B C → tri_relation A B C ≝
 139            λR,a1,b1,c1,a2,b2,c2.
 140            ∨∨ R … a1 b1 c1 a2 b2 c2
 141             | ∧∧ a1 = a2 & b1 = b2 & c1 = c2.
 142
 143 lemma tri_RC_reflexive (A) (B) (C): ∀R. tri_reflexive A B C (tri_RC … R).
 144 /3 width=1 by and3_intro, or_intror/ qed.