matita/matita/contribs/lambdadelta/ground/relocation/gr_after_ist.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/relocation/gr_pat_lt.ma".
  16 include "ground/relocation/gr_ist.ma".
  17 include "ground/relocation/gr_after_pat.ma".
  18
  19 (* RELATIONAL COMPOSITION FOR GENERIC RELOCATION MAPS ***********************************************************)
  20
  21 (* Forward lemmas on istot **************************************************)
  22
  23 (*** after_istot_fwd *)
  24 lemma gr_after_ist_des:
  25       ∀f2,f1,f. f2 ⊚ f1 ≘ f → 𝐓❪f2❫ → 𝐓❪f1❫ → 𝐓❪f❫.
  26 #f2 #f1 #f #Hf #Hf2 #Hf1 #i1 elim (Hf1 i1) -Hf1
  27 #i2 #Hf1 elim (Hf2 i2) -Hf2
  28 /3 width=7 by gr_after_des_pat, ex_intro/
  29 qed-.
  30
  31 (*** after_fwd_istot_dx *)
  32 lemma gr_after_des_ist_dx:
  33       ∀f2,f1,f. f2 ⊚ f1 ≘ f → 𝐓❪f❫ → 𝐓❪f1❫.
  34 #f2 #f1 #f #H #Hf #i1 elim (Hf i1) -Hf
  35 #i2 #Hf elim (gr_after_pat_des … Hf … H) -f /2 width=2 by ex_intro/
  36 qed-.
  37
  38 (*** after_fwd_istot_sn *)
  39 lemma gr_after_des_ist_sn:
  40       ∀f2,f1,f. f2 ⊚ f1 ≘ f → 𝐓❪f❫ → 𝐓❪f2❫.
  41 #f2 #f1 #f #H #Hf #i1 elim (Hf i1) -Hf
  42 #i #Hf elim (gr_after_pat_des … Hf … H) -f
  43 #i2 #Hf1 #Hf2 lapply (gr_pat_increasing … Hf1) -f1
  44 #Hi12 elim (gr_pat_le_ex … Hf2 … Hi12) -i2 /2 width=2 by ex_intro/
  45 qed-.
  46
  47 (*** after_at1_fwd *)
  48 lemma gr_after_des_ist_pat:
  49       ∀f1,i1,i2. @❪i1, f1❫ ≘ i2 → ∀f2. 𝐓❪f2❫ → ∀f. f2 ⊚ f1 ≘ f →
  50       ∃∃i. @❪i2, f2❫ ≘ i & @❪i1, f❫ ≘ i.
  51 #f1 #i1 #i2 #Hf1 #f2 #Hf2 #f #Hf elim (Hf2 i2) -Hf2
  52 /3 width=8 by gr_after_des_pat, ex2_intro/
  53 qed-.
  54
  55 (* Inversions with gr_ist *)
  56
  57 (*** after_inv_istot *)
  58 lemma gr_after_inv_ist:
  59       ∀f2,f1,f. f2 ⊚ f1 ≘ f → 𝐓❪f❫ → ∧∧ 𝐓❪f2❫ & 𝐓❪f1❫.
  60 /3 width=4 by gr_after_des_ist_sn, gr_after_des_ist_dx, conj/ qed-.