matita/matita/contribs/lambdadelta/ground/relocation/gr_after_isu.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/relocation/gr_isu_uni.ma".
  16 include "ground/relocation/gr_after_uni.ma".
  17
  18 (* RELATIONAL COMPOSITION FOR GENERIC RELOCATION MAPS ***********************)
  19
  20 (* Constructions with gr_isu ************************************************)
  21
  22 (*** after_isid_isuni *)
  23 lemma gr_after_isu_isi_next:
  24       ∀f1,f2. 𝐈❪f2❫ → 𝐔❪f1❫ → f1 ⊚ ↑f2 ≘ ↑f1.
  25 #f1 #f2 #Hf2 #H
  26 elim (gr_isu_inv_uni … H) -H #h #H
  27 /5 width=7 by gr_after_uni_isi_next, gr_after_eq_repl_back, gr_after_eq_repl_back_sn, gr_eq_next/
  28 qed.
  29
  30 (*** after_uni_next2 *)
  31 lemma gr_after_isu_next_sn:
  32       ∀f2. 𝐔❪f2❫ → ∀f1,f. ↑f2 ⊚ f1 ≘ f → f2 ⊚ ↑f1 ≘ f.
  33 #f2 #H #f1 #f #Hf
  34 elim (gr_isu_inv_uni … H) -H #h #H
  35 /5 width=7 by gr_after_uni_next_sn, gr_after_eq_repl_fwd_sn, gr_after_eq_repl_back_sn, gr_eq_next/
  36 qed.