matita/matita/contribs/lambdadelta/ground/relocation/gr_isd.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/notation/relations/predicate_omega_1.ma".
  16 include "ground/relocation/gr_map.ma".
  17
  18 (* DIVERGENCE CONDITION FOR GENERIC RELOCATION MAPS ***********************************************************)
  19
  20 (*** isdiv *)
  21 coinductive gr_isd: predicate gr_map ≝
  22 (*** isdiv_next *)
  23 | gr_isd_next (f) (g):
  24   gr_isd f → ↑f = g → gr_isd g
  25 .
  26
  27 interpretation
  28   "divergence condition (generic relocation maps)"
  29   'PredicateOmega f = (gr_isd f).
  30
  31 (* Basic inversion lemmas ***************************************************)
  32
  33 (*** isdiv_inv_gen *)
  34 lemma gr_isd_inv_gen (g): 𝛀❪g❫ → ∃∃f. 𝛀❪f❫ & ↑f = g.
  35 #g * -g
  36 #f #g #Hf * /2 width=3 by ex2_intro/
  37 qed-.
  38
  39 (* Advanced inversion lemmas ************************************************)
  40
  41 (*** isdiv_inv_next *)
  42 lemma gr_isd_inv_next (g): 𝛀❪g❫ → ∀f. ↑f = g → 𝛀❪f❫.
  43 #g #H elim (gr_isd_inv_gen … H) -H
  44 #f #Hf * -g #g #H >(eq_inv_gr_next_bi … H) -H //
  45 qed-.
  46
  47 (*** isdiv_inv_push *)
  48 lemma gr_isd_inv_push (g): 𝛀❪g❫ → ∀f. ⫯f = g → ⊥.
  49 #g #H elim (gr_isd_inv_gen … H) -H
  50 #f #Hf * -g #g #H elim (eq_inv_gr_push_next … H)
  51 qed-.