matita/matita/contribs/lambdadelta/ground/relocation/gr_isd_eq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/relocation/gr_tl_eq_eq.ma".
  16 include "ground/relocation/gr_isd.ma".
  17
  18 (* DIVERGENCE CONDITION FOR GENERIC RELOCATION MAPS *************************)
  19
  20 (* Constructions with gr_eq *************************************************)
  21
  22 (*** isdiv_eq_repl_back *)
  23 corec lemma gr_isd_eq_repl_back:
  24             gr_eq_repl_back … gr_isd.
  25 #f1 #H cases (gr_isd_inv_gen … H) -H
  26 #g1 #Hg1 #H1 #f2 #Hf cases (gr_eq_inv_next_sn … Hf … H1) -f1
  27 /3 width=3 by gr_isd_next/
  28 qed-.
  29
  30 (*** isdiv_eq_repl_fwd *)
  31 lemma gr_isd_eq_repl_fwd:
  32       gr_eq_repl_fwd … gr_isd.
  33 /3 width=3 by gr_isd_eq_repl_back, gr_eq_repl_sym/ qed-.
  34
  35 (* Main inversions with gr_eq ***********************************************)
  36
  37 (*** isdiv_inv_eq_repl *)
  38 corec theorem gr_isd_inv_eq_repl (g1) (g2): 𝛀❪g1❫ → 𝛀❪g2❫ → g1 ≡ g2.
  39 #H1 #H2
  40 cases (gr_isd_inv_gen … H1) -H1
  41 cases (gr_isd_inv_gen … H2) -H2
  42 /3 width=5 by gr_eq_next/
  43 qed-.
  44
  45 (* Alternative definition with gr_eq ****************************************)
  46
  47 (*** eq_next_isdiv *)
  48 corec lemma gr_eq_next_isd (f): ↑f ≡ f → 𝛀❪f❫.
  49 #H cases (gr_eq_inv_next_sn … H) -H
  50 /4 width=3 by gr_isd_next, gr_eq_trans/
  51 qed.
  52
  53 (*** eq_next_inv_isdiv *)
  54 corec lemma gr_eq_next_inv_isd (g): 𝛀❪g❫ → ↑g ≡ g.
  55 * -g #f #g #Hf *
  56 /3 width=5 by gr_eq_next/
  57 qed-.