matita/matita/contribs/lambdadelta/ground/relocation/gr_isi.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/notation/relations/predicate_i_1.ma".
  16 include "ground/relocation/gr_map.ma".
  17
  18 (* IDENTITY CONDITION FOR GENERIC RELOCATION MAPS ***************************)
  19
  20 (*** isid *)
  21 coinductive gr_isi: predicate gr_map ≝
  22 (*** isid_push *)
  23 | gr_isi_push (f) (g):
  24   gr_isi f → ⫯f = g → gr_isi g
  25 .
  26
  27 interpretation
  28   "identity condition (generic relocation maps)"
  29   'PredicateI f = (gr_isi f).
  30
  31 (* Basic inversions *********************************************************)
  32
  33 (*** isid_inv_gen *)
  34 lemma gr_isi_inv_gen (g): 𝐈❪g❫ → ∃∃f. 𝐈❪f❫ & ⫯f = g.
  35 #g * -g
  36 #f #g #Hf /2 width=3 by ex2_intro/
  37 qed-.
  38
  39 (* Advanced inversions ******************************************************)
  40
  41 (*** isid_inv_push *)
  42 lemma gr_isi_inv_push (g): 𝐈❪g❫ → ∀f. ⫯f = g → 𝐈❪f❫.
  43 #g #H
  44 elim (gr_isi_inv_gen … H) -H #f #Hf
  45 * -g #g #H
  46 >(eq_inv_gr_push_bi … H) -H //
  47 qed-.
  48
  49 (*** isid_inv_next *)
  50 lemma gr_isi_inv_next (g): 𝐈❪g❫ → ∀f. ↑f = g → ⊥.
  51 #g #H
  52 elim (gr_isi_inv_gen … H) -H #f #Hf
  53 * -g #g #H elim (eq_inv_gr_next_push … H)
  54 qed-.