matita/matita/contribs/lambdadelta/ground/relocation/gr_isi_eq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/relocation/gr_tl_eq_eq.ma".
  16 include "ground/relocation/gr_isi.ma".
  17
  18 (* IDENTITY CONDITION FOR GENERIC RELOCATION MAPS ***************************)
  19
  20 (* Constructions with gr_eq *************************************************)
  21
  22 (*** isid_eq_repl_back *)
  23 corec lemma gr_isi_eq_repl_back:
  24             gr_eq_repl_back … gr_isi.
  25 #f1 #H
  26 cases (gr_isi_inv_gen … H) -H #g1 #Hg1 #H1 #f2 #Hf
  27 cases (gr_eq_inv_push_sn … Hf … H1) -f1
  28 /3 width=3 by gr_isi_push/
  29 qed-.
  30
  31 (*** isid_eq_repl_fwd *)
  32 lemma gr_isi_eq_repl_fwd:
  33       gr_eq_repl_fwd … gr_isi.
  34 /3 width=3 by gr_isi_eq_repl_back, gr_eq_repl_sym/ qed-.
  35
  36 (* Main inversions with gr_eq ***********************************************)
  37
  38 (*** isid_inv_eq_repl *)
  39 corec theorem gr_isi_inv_eq_repl (g1) (g2): 𝐈❪g1❫ → 𝐈❪g2❫ → g1 ≡ g2.
  40 #H1 #H2
  41 cases (gr_isi_inv_gen … H1) -H1
  42 cases (gr_isi_inv_gen … H2) -H2
  43 /3 width=5 by gr_eq_push/
  44 qed-.
  45
  46 (* Alternative definition with gr_eq ****************************************)
  47
  48 (*** eq_push_isid *)
  49 corec lemma gr_eq_push_isi (f): ⫯f ≡ f → 𝐈❪f❫.
  50 #H cases (gr_eq_inv_push_sn … H) -H
  51 /4 width=3 by gr_isi_push, gr_eq_trans/
  52 qed.
  53
  54 (*** eq_push_inv_isid *)
  55 corec lemma gr_isi_inv_eq_push (g): 𝐈❪g❫ → ⫯g ≡ g.
  56 * -g #f #g #Hf *
  57 /3 width=5 by gr_eq_push/
  58 qed-.