matita/matita/contribs/lambdadelta/ground/relocation/gr_ist.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/notation/relations/predicate_t_1.ma".
  16 include "ground/relocation/gr_pat.ma".
  17
  18 (* TOTALITY CONDITION FOR GENERIC RELOCATION MAPS ***************************)
  19
  20 (*** istot *)
  21 definition gr_ist: predicate gr_map ≝
  22            λf. ∀i. ∃j. @❪i,f❫ ≘ j.
  23
  24 interpretation
  25   "totality condition (generic relocation maps)"
  26   'PredicateT f = (gr_ist f).
  27
  28 (* Basic inversions *********************************************************)
  29
  30 (*** istot_inv_push *)
  31 lemma gr_ist_inv_push (g): 𝐓❪g❫ → ∀f. ⫯f = g → 𝐓❪f❫.
  32 #g #Hg #f #H #i elim (Hg (↑i)) -Hg
  33 #j #Hg elim (gr_pat_inv_succ_push … Hg … H) -Hg -H /2 width=3 by ex_intro/
  34 qed-.
  35
  36 (*** istot_inv_next *)
  37 lemma gr_ist_inv_next (g): 𝐓❪g❫ → ∀f. ↑f = g → 𝐓❪f❫.
  38 #g #Hg #f #H #i elim (Hg i) -Hg
  39 #j #Hg elim (gr_pat_inv_next … Hg … H) -Hg -H /2 width=2 by ex_intro/
  40 qed-.
  41
  42 (* Constructions with gr_tl *************************************************)
  43
  44 (*** istot_tl *)
  45 lemma gr_ist_tl (f): 𝐓❪f❫ → 𝐓❪⫱f❫.
  46 #f cases (gr_map_split_tl f) *
  47 /2 width=3 by gr_ist_inv_next, gr_ist_inv_push/
  48 qed.