matita/matita/contribs/lambdadelta/ground/relocation/gr_isu.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/notation/relations/predicate_u_1.ma".
  16 include "ground/relocation/gr_isi.ma".
  17
  18 (* UNIFORMITY CONDITION FOR GENERIC RELOCATION MAPS *************************)
  19
  20 (*** isuni *)
  21 inductive gr_isu: predicate gr_map ≝
  22 (*** isuni_isid *)
  23 | gr_isu_isi (f): 𝐈❪f❫ → gr_isu f
  24 (*** isuni_next *)
  25 | gr_isu_next (f): gr_isu f → ∀g. ↑f = g → gr_isu g
  26 .
  27
  28 interpretation
  29   "uniformity condition (generic relocation maps)"
  30   'PredicateU f = (gr_isu f).
  31
  32 (* Basic inversions *********************************************************)
  33
  34 (*** isuni_inv_push *)
  35 lemma gr_isu_inv_push (g): 𝐔❪g❫ → ∀f. ⫯f = g → 𝐈❪f❫.
  36 #g * -g
  37 [ /2 width=3 by gr_isi_inv_push/
  38 | #f #_ #g #H #x #Hx destruct
  39   elim (eq_inv_gr_push_next … Hx)
  40 ]
  41 qed-.
  42
  43 (*** isuni_inv_next *)
  44 lemma gr_isu_inv_next (g): 𝐔❪g❫ → ∀f. ↑f = g → 𝐔❪f❫.
  45 #g * -g #f #Hf
  46 [ #x #Hx elim (gr_isi_inv_next … Hf … Hx)
  47 | #g #H #x #Hx destruct
  48   >(eq_inv_gr_next_bi … Hx) -x //
  49 ]
  50 qed-.
  51
  52 (* Basic destructions *******************************************************)
  53
  54 (*** isuni_fwd_push *)
  55 lemma gr_isu_fwd_push (g): 𝐔❪g❫ → ∀f. ⫯f = g → 𝐔❪f❫.
  56 /3 width=3 by gr_isu_inv_push, gr_isu_isi/ qed-.