matita/matita/contribs/lambdadelta/ground/relocation/gr_uni_eq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/arith/nat_pred_succ.ma".
  16 include "ground/relocation/gr_tl_eq.ma".
  17 include "ground/relocation/gr_uni.ma".
  18
  19 (* UNIFORM ELEMENTS FOR GENERIC RELOCATION MAPS *****************************)
  20
  21 (* Inversions with gr_eq ****************************************************)
  22
  23 (*** uni_inv_push_dx *)
  24 lemma gr_eq_inv_uni_push (n) (g):  𝐮❨n❩ ≡ ⫯g → ∧∧ 𝟎 = n & 𝐢 ≡ g.
  25 #n @(nat_ind_succ … n) -n
  26 [ /3 width=5 by gr_eq_inv_push_bi, conj/
  27 | #n #_ #f <gr_uni_succ #H elim (gr_eq_inv_next_push … H) -H //
  28 ]
  29 qed-.
  30
  31 (*** uni_inv_push_sn *)
  32 lemma gr_eq_inv_push_uni (n) (g): ⫯g ≡ 𝐮❨n❩ → ∧∧ 𝟎 = n & 𝐢 ≡ g.
  33 /3 width=1 by gr_eq_inv_uni_push, gr_eq_sym/ qed-.
  34
  35 (*** uni_inv_next_dx *)
  36 lemma gr_eq_inv_uni_next (n) (g): 𝐮❨n❩ ≡ ↑g → ∧∧ 𝐮❨↓n❩ ≡ g & ↑↓n = n.
  37 #n @(nat_ind_succ … n) -n
  38 [ #g <gr_uni_zero <gr_id_unfold #H elim (gr_eq_inv_push_next … H) -H //
  39 | #n #_ #g <gr_uni_succ /3 width=5 by gr_eq_inv_next_bi, conj/
  40 ]
  41 qed-.
  42
  43 (*** uni_inv_next_sn *)
  44 lemma gr_eq_inv_next_uni (n) (g): ↑g ≡ 𝐮❨n❩ → ∧∧ 𝐮❨↓n❩ ≡ g & ↑↓n = n.
  45 /3 width=1 by gr_eq_inv_uni_next, gr_eq_sym/ qed-.
  46
  47 (* Inversions with gr_id and gr_eq ******************************************)
  48
  49 (*** uni_inv_id_dx *)
  50 lemma gr_eq_inv_uni_id (n): 𝐮❨n❩ ≡ 𝐢 → 𝟎 = n.
  51 #n <gr_id_unfold #H elim (gr_eq_inv_uni_push … H) -H //
  52 qed-.
  53
  54 (*** uni_inv_id_sn *)
  55 lemma gr_eq_inv_id_uni (n):  𝐢 ≡ 𝐮❨n❩ → 𝟎 = n.
  56 /3 width=1 by gr_eq_inv_uni_id, gr_eq_sym/ qed-.