matita/matita/contribs/lambdadelta/ground/relocation/mr2_minus.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/xoa/ex_3_1.ma".
  16 include "ground/notation/relations/rminus_3.ma".
  17 include "ground/arith/nat_plus.ma".
  18 include "ground/arith/nat_minus.ma".
  19 include "ground/arith/nat_lt.ma".
  20 include "ground/relocation/mr2.ma".
  21
  22 (* MULTIPLE RELOCATION WITH PAIRS *******************************************)
  23
  24 inductive minuss: nat → relation mr2 ≝
  25 | minuss_nil: ∀i. minuss i (◊) (◊)
  26 | minuss_lt : ∀cs1,cs2,l,m,i. i < l → minuss i cs1 cs2 →
  27               minuss i (❨l, m❩;cs1) (❨l - i, m❩;cs2)
  28 | minuss_ge : ∀cs1,cs2,l,m,i. l ≤ i → minuss (m + i) cs1 cs2 →
  29               minuss i (❨l, m❩;cs1) cs2
  30 .
  31
  32 interpretation "minus (multiple relocation with pairs)"
  33    'RMinus cs1 i cs2 = (minuss i cs1 cs2).
  34
  35 (* Basic inversion lemmas ***************************************************)
  36
  37 fact minuss_inv_nil1_aux: ∀cs1,cs2,i. cs1 ▭ i ≘ cs2 → cs1 = ◊ → cs2 = ◊.
  38 #cs1 #cs2 #i * -cs1 -cs2 -i
  39 [ //
  40 | #cs1 #cs2 #l #m #i #_ #_ #H destruct
  41 | #cs1 #cs2 #l #m #i #_ #_ #H destruct
  42 ]
  43 qed-.
  44
  45 lemma minuss_inv_nil1: ∀cs2,i. ◊ ▭ i ≘ cs2 → cs2 = ◊.
  46 /2 width=4 by minuss_inv_nil1_aux/ qed-.
  47
  48 fact minuss_inv_cons1_aux: ∀cs1,cs2,i. cs1 ▭ i ≘ cs2 →
  49                            ∀l,m,cs. cs1 = ❨l, m❩;cs →
  50                            l ≤ i ∧ cs ▭ m + i ≘ cs2 ∨
  51                            ∃∃cs0. i < l & cs ▭ i ≘ cs0 &
  52                                    cs2 = ❨l - i, m❩;cs0.
  53 #cs1 #cs2 #i * -cs1 -cs2 -i
  54 [ #i #l #m #cs #H destruct
  55 | #cs1 #cs #l1 #m1 #i1 #Hil1 #Hcs #l2 #m2 #cs2 #H destruct /3 width=3 by ex3_intro, or_intror/
  56 | #cs1 #cs #l1 #m1 #i1 #Hli1 #Hcs #l2 #m2 #cs2 #H destruct /3 width=1 by or_introl, conj/
  57 ]
  58 qed-.
  59
  60 lemma minuss_inv_cons1: ∀cs1,cs2,l,m,i. ❨l, m❩;cs1 ▭ i ≘ cs2 →
  61                         l ≤ i ∧ cs1 ▭ m + i ≘ cs2 ∨
  62                         ∃∃cs. i < l & cs1 ▭ i ≘ cs &
  63                                cs2 = ❨l - i, m❩;cs.
  64 /2 width=3 by minuss_inv_cons1_aux/ qed-.
  65
  66 lemma minuss_inv_cons1_ge: ∀cs1,cs2,l,m,i. ❨l, m❩;cs1 ▭ i ≘ cs2 →
  67                            l ≤ i → cs1 ▭ m + i ≘ cs2.
  68 #cs1 #cs2 #l #m #i #H
  69 elim (minuss_inv_cons1 … H) -H * // #cs #Hil #_ #_ #Hli
  70 elim (nlt_ge_false … Hil Hli)
  71 qed-.
  72
  73 lemma minuss_inv_cons1_lt: ∀cs1,cs2,l,m,i. ❨l, m❩;cs1 ▭ i ≘ cs2 →
  74                            i < l →
  75                            ∃∃cs. cs1 ▭ i ≘ cs & cs2 = ❨l - i, m❩;cs.
  76 #cs1 #cs2 #l #m #i #H elim (minuss_inv_cons1 … H) -H * /2 width=3 by ex2_intro/
  77 #Hli #_ #Hil elim (nlt_ge_false … Hil Hli)
  78 qed-.