matita/matita/contribs/lambdadelta/ground/relocation/pr_after_ist.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/relocation/pr_pat_lt.ma".
  16 include "ground/relocation/pr_nat.ma".
  17 include "ground/relocation/pr_ist.ma".
  18 include "ground/relocation/pr_after_pat.ma".
  19
  20 (* RELATIONAL COMPOSITION FOR PARTIAL RELOCATION MAPS ***********************)
  21
  22 (* Destructions with pr_ist *************************************************)
  23
  24 (*** after_istot_fwd *)
  25 lemma pr_after_ist_des:
  26       ∀f2,f1,f. f2 ⊚ f1 ≘ f → 𝐓❨f2❩ → 𝐓❨f1❩ → 𝐓❨f❩.
  27 #f2 #f1 #f #Hf #Hf2 #Hf1 #i1 elim (Hf1 i1) -Hf1
  28 #i2 #Hf1 elim (Hf2 i2) -Hf2
  29 /3 width=7 by pr_after_des_pat, ex_intro/
  30 qed-.
  31
  32 (*** after_fwd_istot_dx *)
  33 lemma pr_after_des_ist_dx:
  34       ∀f2,f1,f. f2 ⊚ f1 ≘ f → 𝐓❨f❩ → 𝐓❨f1❩.
  35 #f2 #f1 #f #H #Hf #i1 elim (Hf i1) -Hf
  36 #i2 #Hf elim (pr_after_pat_des … Hf … H) -f /2 width=2 by ex_intro/
  37 qed-.
  38
  39 (*** after_fwd_istot_sn *)
  40 lemma pr_after_des_ist_sn:
  41       ∀f2,f1,f. f2 ⊚ f1 ≘ f → 𝐓❨f❩ → 𝐓❨f2❩.
  42 #f2 #f1 #f #H #Hf #i1 elim (Hf i1) -Hf
  43 #i #Hf elim (pr_after_pat_des … Hf … H) -f
  44 #i2 #Hf1 #Hf2 lapply (pr_pat_increasing … Hf1) -f1
  45 #Hi12 elim (pr_pat_le_ex … Hf2 … Hi12) -i2 /2 width=2 by ex_intro/
  46 qed-.
  47
  48 (*** after_at1_fwd *)
  49 lemma pr_after_des_ist_pat:
  50       ∀f1,i1,i2. ＠⧣❨i1, f1❩ ≘ i2 → ∀f2. 𝐓❨f2❩ → ∀f. f2 ⊚ f1 ≘ f →
  51       ∃∃i. ＠⧣❨i2, f2❩ ≘ i & ＠⧣❨i1, f❩ ≘ i.
  52 #f1 #i1 #i2 #Hf1 #f2 #Hf2 #f #Hf elim (Hf2 i2) -Hf2
  53 /3 width=8 by pr_after_des_pat, ex2_intro/
  54 qed-.
  55
  56 lemma pr_after_des_ist_nat:
  57       ∀f1,l1,l2. ＠§❨l1, f1❩ ≘ l2 → ∀f2. 𝐓❨f2❩ → ∀f. f2 ⊚ f1 ≘ f →
  58       ∃∃l. ＠§❨l2, f2❩ ≘ l & ＠§❨l1, f❩ ≘ l.
  59 #f1 #l1 #l2 #H1 #f2 #H2 #f #Hf
  60 elim (pr_after_des_ist_pat … H1 … H2 … Hf) -f1 -H2
  61 /2 width=3 by ex2_intro/
  62 qed-.
  63
  64 (* Inversions with pr_ist ***************************************************)
  65
  66 (*** after_inv_istot *)
  67 lemma pr_after_inv_ist:
  68       ∀f2,f1,f. f2 ⊚ f1 ≘ f → 𝐓❨f❩ → ∧∧ 𝐓❨f2❩ & 𝐓❨f1❩.
  69 /3 width=4 by pr_after_des_ist_sn, pr_after_des_ist_dx, conj/ qed-.