matita/matita/contribs/lambdadelta/ground/steps/rtc_isrt_max.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/xoa/ex_3_2.ma".
  16 include "ground/steps/rtc_max.ma".
  17 include "ground/steps/rtc_isrt.ma".
  18
  19 (* RT-TRANSITION COUNTER ****************************************************)
  20
  21 (* Properties with test for constrained rt-transition counter ***************)
  22
  23 lemma isrt_max: ∀n1,n2,c1,c2. 𝐑𝐓❪n1,c1❫ → 𝐑𝐓❪n2,c2❫ → 𝐑𝐓❪n1∨n2,c1∨c2❫.
  24 #n1 #n2 #c1 #c2 * #ri1 #rs1 #H1 * #ri2 #rs2 #H2 destruct
  25 /2 width=3 by ex1_2_intro/
  26 qed.
  27
  28 lemma isrt_max_O1: ∀n,c1,c2. 𝐑𝐓❪0,c1❫ → 𝐑𝐓❪n,c2❫ → 𝐑𝐓❪n,c1∨c2❫.
  29 /2 width=1 by isrt_max/ qed.
  30
  31 lemma isrt_max_O2: ∀n,c1,c2. 𝐑𝐓❪n,c1❫ → 𝐑𝐓❪0,c2❫ → 𝐑𝐓❪n,c1∨c2❫.
  32 #n #c1 #c2 #H1 #H2 >(max_O2 n) /2 width=1 by isrt_max/
  33 qed.
  34
  35 lemma isrt_max_idem1: ∀n,c1,c2. 𝐑𝐓❪n,c1❫ → 𝐑𝐓❪n,c2❫ → 𝐑𝐓❪n,c1∨c2❫.
  36 #n #c1 #c2 #H1 #H2 >(idempotent_max n) /2 width=1 by isrt_max/
  37 qed.
  38
  39 (* Inversion properties with test for constrained rt-transition counter *****)
  40
  41 lemma isrt_inv_max: ∀n,c1,c2. 𝐑𝐓❪n,c1 ∨ c2❫ →
  42                     ∃∃n1,n2. 𝐑𝐓❪n1,c1❫ & 𝐑𝐓❪n2,c2❫ & (n1 ∨ n2) = n.
  43 #n #c1 #c2 * #ri #rs #H
  44 elim (max_inv_dx … H) -H #ri1 #rs1 #ti1 #ts1 #ri2 #rs2 #ti2 #ts2 #_ #_ #H1 #H2 #H3 #H4
  45 elim (max_inv_O3 … H1) -H1 /3 width=5 by ex3_2_intro, ex1_2_intro/
  46 qed-.
  47
  48 lemma isrt_O_inv_max: ∀c1,c2. 𝐑𝐓❪0,c1 ∨ c2❫ → ∧∧ 𝐑𝐓❪0,c1❫ & 𝐑𝐓❪0,c2❫.
  49 #c1 #c2 #H
  50 elim (isrt_inv_max … H) -H #n1 #n2 #Hn1 #Hn2 #H
  51 elim (max_inv_O3 … H) -H #H1 #H2 destruct
  52 /2 width=1 by conj/
  53 qed-.
  54
  55 lemma isrt_inv_max_O_dx: ∀n,c1,c2. 𝐑𝐓❪n,c1 ∨ c2❫ → 𝐑𝐓❪0,c2❫ → 𝐑𝐓❪n,c1❫.
  56 #n #c1 #c2 #H #H2
  57 elim (isrt_inv_max … H) -H #n1 #n2 #Hn1 #Hn2 #H destruct
  58 lapply (isrt_inj … Hn2 H2) -c2 #H destruct //
  59 qed-.
  60
  61 lemma isrt_inv_max_eq_t: ∀n,c1,c2. 𝐑𝐓❪n,c1 ∨ c2❫ → eq_t c1 c2 →
  62                          ∧∧ 𝐑𝐓❪n,c1❫ & 𝐑𝐓❪n,c2❫.
  63 #n #c1 #c2 #H #Hc12
  64 elim (isrt_inv_max … H) -H #n1 #n2 #Hc1 #Hc2 #H destruct
  65 lapply (isrt_eq_t_trans … Hc1 … Hc12) -Hc12 #H
  66 <(isrt_inj … H … Hc2) -Hc2
  67 <idempotent_max /2 width=1 by conj/
  68 qed-.