matita/matita/contribs/lambdadelta/ground/ynat/ynat_le.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/ynat/ynat_succ.ma".
  16
  17 (* NATURAL NUMBERS WITH INFINITY ********************************************)
  18
  19 (* order relation *)
  20 inductive yle: relation ynat ≝
  21 | yle_inj: ∀m,n. m ≤ n → yle m n
  22 | yle_Y  : ∀m. yle m (∞)
  23 .
  24
  25 interpretation "ynat 'less or equal to'" 'leq x y = (yle x y).
  26
  27 (* Basic inversion lemmas ***************************************************)
  28
  29 fact yle_inv_inj2_aux: ∀x,y. x ≤ y → ∀n. y = yinj n →
  30                        ∃∃m. m ≤ n & x = yinj m.
  31 #x #y * -x -y
  32 [ #x #y #Hxy #n #Hy destruct /2 width=3 by ex2_intro/
  33 | #x #n #Hy destruct
  34 ]
  35 qed-.
  36
  37 lemma yle_inv_inj2: ∀x,n. x ≤ yinj n → ∃∃m. m ≤ n & x = yinj m.
  38 /2 width=3 by yle_inv_inj2_aux/ qed-.
  39
  40 lemma yle_inv_inj: ∀m,n. yinj m ≤ yinj n → m ≤ n.
  41 #m #n #H elim (yle_inv_inj2 … H) -H
  42 #x #Hxn #H destruct //
  43 qed-.
  44
  45 fact yle_inv_O2_aux: ∀m:ynat. ∀x:ynat. m ≤ x → x = 0 → m = 0.
  46 #m #x * -m -x
  47 [ #m #n #Hmn #H destruct /3 width=1 by le_n_O_to_eq, eq_f/
  48 | #m #H destruct
  49 ]
  50 qed-.
  51
  52 lemma yle_inv_O2: ∀m:ynat. m ≤ 0 → m = 0.
  53 /2 width =3 by yle_inv_O2_aux/ qed-.
  54
  55 fact yle_inv_Y1_aux: ∀x,n. x ≤ n → x = ∞ → n = ∞.
  56 #x #n * -x -n //
  57 #x #n #_ #H destruct
  58 qed-.
  59
  60 lemma yle_inv_Y1: ∀n. ∞ ≤ n → n = ∞.
  61 /2 width=3 by yle_inv_Y1_aux/ qed-.
  62
  63 lemma yle_antisym: ∀y,x. x ≤ y → y ≤ x → x = y.
  64 #x #y #H elim H -x -y
  65 /4 width=1 by yle_inv_Y1, yle_inv_inj, le_to_le_to_eq, eq_f/
  66 qed-.
  67
  68 (* Basic properties *********************************************************)
  69
  70 lemma le_O1: ∀n:ynat. 0 ≤ n.
  71 * /2 width=1 by yle_inj/
  72 qed.
  73
  74 lemma yle_refl: reflexive … yle.
  75 * /2 width=1 by le_n, yle_inj/
  76 qed.
  77
  78 lemma yle_split: ∀x,y:ynat. x ≤ y ∨ y ≤ x.
  79 * /2 width=1 by or_intror/
  80 #x * /2 width=1 by or_introl/
  81 #y elim (le_or_ge x y) /3 width=1 by yle_inj, or_introl, or_intror/
  82 qed-.
  83
  84 (* Inversion lemmas on successor ********************************************)
  85
  86 fact yle_inv_succ1_aux: ∀x,y:ynat. x ≤ y → ∀m. x = ↑m → m ≤ ↓y ∧ ↑↓y = y.
  87 #x #y * -x -y
  88 [ #x #y #Hxy #m #H elim (ysucc_inv_inj_sn … H) -H
  89   #n #H1 #H2 destruct elim (le_inv_S1 … Hxy) -Hxy
  90   #m #Hnm #H destruct /3 width=1 by yle_inj, conj/
  91 | #x #y #H destruct /2 width=1 by yle_Y, conj/
  92 ]
  93 qed-.
  94
  95 lemma yle_inv_succ1: ∀m,y:ynat. ↑m ≤ y → m ≤ ↓y ∧ ↑↓y = y.
  96 /2 width=3 by yle_inv_succ1_aux/ qed-.
  97
  98 lemma yle_inv_succ: ∀m,n. ↑m ≤ ↑n → m ≤ n.
  99 #m #n #H elim (yle_inv_succ1 … H) -H //
 100 qed-.
 101
 102 lemma yle_inv_succ2: ∀x,y. x ≤ ↑y → ↓x ≤ y.
 103 #x #y #Hxy elim (ynat_cases x)
 104 [ #H destruct //
 105 | * #m #H destruct /2 width=1 by yle_inv_succ/
 106 ]
 107 qed-.
 108
 109 (* Properties on predecessor ************************************************)
 110
 111 lemma yle_pred_sn: ∀m,n. m ≤ n → ↓m ≤ n.
 112 #m #n * -m -n /3 width=3 by transitive_le, yle_inj/
 113 qed.
 114
 115 lemma yle_refl_pred_sn: ∀x. ↓x ≤ x.
 116 /2 width=1 by yle_refl, yle_pred_sn/ qed.
 117
 118 lemma yle_pred: ∀m,n. m ≤ n → ↓m ≤ ↓n.
 119 #m #n * -m -n /3 width=1 by yle_inj, monotonic_pred/
 120 qed.
 121
 122 (* Properties on successor **************************************************)
 123
 124 lemma yle_succ: ∀m,n. m ≤ n → ↑m ≤ ↑n.
 125 #m #n * -m -n /3 width=1 by yle_inj, le_S_S/
 126 qed.
 127
 128 lemma yle_succ_dx: ∀m,n. m ≤ n → m ≤ ↑n.
 129 #m #n * -m -n /3 width=1 by le_S, yle_inj/
 130 qed.
 131
 132 lemma yle_refl_S_dx: ∀x. x ≤ ↑x.
 133 /2 width=1 by yle_succ_dx/ qed.
 134
 135 lemma yle_refl_SP_dx: ∀x. x ≤ ↑↓x.
 136 * // * //
 137 qed.
 138
 139 lemma yle_succ2: ∀x,y. ↓x ≤ y → x ≤ ↑y.
 140 #x #y #Hxy elim (ynat_cases x)
 141 [ #H destruct //
 142 | * #m #H destruct /2 width=1 by yle_succ/
 143 ]
 144 qed-.
 145
 146 (* Main properties **********************************************************)
 147
 148 theorem yle_trans: Transitive … yle.
 149 #x #y * -x -y
 150 [ #x #y #Hxy * //
 151   #z #H lapply (yle_inv_inj … H) -H
 152   /3 width=3 by transitive_le, yle_inj/ (**) (* full auto too slow *)
 153 | #x #z #H lapply (yle_inv_Y1 … H) //
 154 ]
 155 qed-.