matita/matita/contribs/lambdadelta/ground/ynat/ynat_lt.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/ynat/ynat_le.ma".
  16
  17 (* NATURAL NUMBERS WITH INFINITY ********************************************)
  18
  19 (* strict order relation *)
  20 inductive ylt: relation ynat ≝
  21 | ylt_inj: ∀m,n. m < n → ylt m n
  22 | ylt_Y  : ∀m:nat. ylt m (∞)
  23 .
  24
  25 interpretation "ynat 'less than'" 'lt x y = (ylt x y).
  26
  27 (* Basic forward lemmas *****************************************************)
  28
  29 lemma ylt_fwd_gen: ∀x,y. x < y → ∃m. x = yinj m.
  30 #x #y * -x -y /2 width=2 by ex_intro/
  31 qed-.
  32
  33 lemma ylt_fwd_lt_O1: ∀x,y:ynat. x < y → 0 < y.
  34 #x #y #H elim H -x -y /3 width=2 by ylt_inj, ltn_to_ltO/
  35 qed-.
  36
  37 (* Basic inversion lemmas ***************************************************)
  38
  39 fact ylt_inv_inj2_aux: ∀x,y. x < y → ∀n. y = yinj n →
  40                        ∃∃m. m < n & x = yinj m.
  41 #x #y * -x -y
  42 [ #x #y #Hxy #n #Hy elim (le_inv_S1 … Hxy) -Hxy
  43   #m #Hm #H destruct /3 width=3 by le_S_S, ex2_intro/
  44 | #x #n #Hy destruct
  45 ]
  46 qed-.
  47
  48 lemma ylt_inv_inj2: ∀x,n. x < yinj n →
  49                     ∃∃m. m < n & x = yinj m.
  50 /2 width=3 by ylt_inv_inj2_aux/ qed-.
  51
  52 lemma ylt_inv_inj: ∀m,n. yinj m < yinj n → m < n.
  53 #m #n #H elim (ylt_inv_inj2 … H) -H
  54 #x #Hx #H destruct //
  55 qed-.
  56
  57 lemma ylt_inv_Y1: ∀n. ∞ < n → ⊥.
  58 #n #H elim (ylt_fwd_gen … H) -H
  59 #y #H destruct
  60 qed-.
  61
  62 lemma ylt_inv_Y2: ∀x:ynat. x < ∞ → ∃n. x = yinj n.
  63 * /2 width=2 by ex_intro/
  64 #H elim (ylt_inv_Y1 … H)
  65 qed-.
  66
  67 lemma ylt_inv_O1: ∀n:ynat. 0 < n → ↑↓n = n.
  68 * // #n #H lapply (ylt_inv_inj … H) -H normalize
  69 /3 width=1 by S_pred, eq_f/
  70 qed-.
  71
  72 (* Inversion lemmas on successor ********************************************)
  73
  74 fact ylt_inv_succ1_aux: ∀x,y:ynat. x < y → ∀m. x = ↑m → m < ↓y ∧ ↑↓y = y.
  75 #x #y * -x -y
  76 [ #x #y #Hxy #m #H elim (ysucc_inv_inj_sn … H) -H
  77   #n #H1 #H2 destruct elim (le_inv_S1 … Hxy) -Hxy
  78   #m #Hnm #H destruct /3 width=1 by ylt_inj, conj/
  79 | #x #y #H elim (ysucc_inv_inj_sn … H) -H
  80   #m #H #_ destruct /2 width=1 by ylt_Y, conj/
  81 ]
  82 qed-.
  83
  84 lemma ylt_inv_succ1: ∀m,y:ynat. ↑m < y → m < ↓y ∧ ↑↓y = y.
  85 /2 width=3 by ylt_inv_succ1_aux/ qed-.
  86
  87 lemma ylt_inv_succ: ∀m,n. ↑m < ↑n → m < n.
  88 #m #n #H elim (ylt_inv_succ1 … H) -H //
  89 qed-.
  90
  91 (* Forward lemmas on successor **********************************************)
  92
  93 fact ylt_fwd_succ2_aux: ∀x,y. x < y → ∀n. y = ↑n → x ≤ n.
  94 #x #y * -x -y
  95 [ #x #y #Hxy #m #H elim (ysucc_inv_inj_sn … H) -H
  96   #n #H1 #H2 destruct /3 width=1 by yle_inj, le_S_S_to_le/
  97 | #x #n #H lapply (ysucc_inv_Y_sn … H) -H //
  98 ]
  99 qed-.
 100
 101 lemma ylt_fwd_succ2: ∀m,n. m < ↑n → m ≤ n.
 102 /2 width=3 by ylt_fwd_succ2_aux/ qed-.
 103
 104 (* inversion and forward lemmas on order ************************************)
 105
 106 lemma ylt_fwd_le_succ1: ∀m,n. m < n → ↑m ≤ n.
 107 #m #n * -m -n /2 width=1 by yle_inj/
 108 qed-.
 109
 110 lemma ylt_fwd_le_pred2: ∀x,y:ynat. x < y → x ≤ ↓y.
 111 #x #y #H elim H -x -y /3 width=1 by yle_inj, monotonic_pred/
 112 qed-.
 113
 114 lemma ylt_fwd_le: ∀m:ynat. ∀n:ynat. m < n → m ≤ n.
 115 #m #n * -m -n /3 width=1 by lt_to_le, yle_inj/
 116 qed-.
 117
 118 lemma ylt_yle_false: ∀m:ynat. ∀n:ynat. m < n → n ≤ m → ⊥.
 119 #m #n * -m -n
 120 [ #m #n #Hmn #H lapply (yle_inv_inj … H) -H
 121   #H elim (lt_refl_false n) /2 width=3 by le_to_lt_to_lt/
 122 | #m #H lapply (yle_inv_Y1 … H) -H
 123   #H destruct
 124 ]
 125 qed-.
 126
 127 lemma ylt_inv_le: ∀x,y. x < y → x < ∞ ∧ ↑x ≤ y.
 128 #x #y #H elim H -x -y /3 width=1 by yle_inj, conj/
 129 qed-.
 130
 131 (* Basic properties *********************************************************)
 132
 133 lemma ylt_O1: ∀x:ynat. ↑↓x = x → 0 < x.
 134 * // * /2 width=1 by ylt_inj/ normalize
 135 #H destruct
 136 qed.
 137
 138 lemma yle_inv_succ_sn_lt (x:ynat) (y:ynat):
 139       ↑x ≤ y → ∧∧ x ≤ ↓y & 0 < y.
 140 #x #y #H elim (yle_inv_succ1 … H) -H /3 width=2 by ylt_O1, conj/
 141 qed-.
 142
 143 (* Properties on predecessor ************************************************)
 144
 145 lemma ylt_pred: ∀m,n:ynat. m < n → 0 < m → ↓m < ↓n.
 146 #m #n * -m -n
 147 /4 width=1 by ylt_inv_inj, ylt_inj, monotonic_lt_pred/
 148 qed.
 149
 150 (* Properties on successor **************************************************)
 151
 152 lemma ylt_O_succ: ∀x:ynat. 0 < ↑x.
 153 * /2 width=1 by ylt_inj/
 154 qed.
 155
 156 lemma ylt_succ: ∀m,n. m < n → ↑m < ↑n.
 157 #m #n #H elim H -m -n /3 width=1 by ylt_inj, le_S_S/
 158 qed.
 159
 160 lemma ylt_succ_Y: ∀x. x < ∞ → ↑x < ∞.
 161 * /2 width=1 by/ qed.
 162
 163 lemma yle_succ1_inj: ∀x. ∀y:ynat. ↑yinj x ≤ y → x < y.
 164 #x * /3 width=1 by yle_inv_inj, ylt_inj/
 165 qed.
 166
 167 lemma ylt_succ2_refl: ∀x,y:ynat. x < y → x < ↑x.
 168 #x #y #H elim (ylt_fwd_gen … H) -y /2 width=1 by ylt_inj/
 169 qed.
 170
 171 (* Properties on order ******************************************************)
 172
 173 lemma yle_split_eq: ∀m,n:ynat. m ≤ n → m < n ∨ m = n.
 174 #m #n * -m -n
 175 [ #m #n #Hmn elim (le_to_or_lt_eq … Hmn) -Hmn
 176   /3 width=1 by or_introl, ylt_inj/
 177 | * /2 width=1 by or_introl, ylt_Y/
 178 ]
 179 qed-.
 180
 181 lemma ylt_split: ∀m,n:ynat. m < n ∨ n ≤ m.
 182 #m #n elim (yle_split m n) /2 width=1 by or_intror/
 183 #H elim (yle_split_eq … H) -H /2 width=1 by or_introl, or_intror/
 184 qed-.
 185
 186 lemma ylt_split_eq: ∀m,n:ynat. ∨∨ m < n | n = m | n < m.
 187 #m #n elim (ylt_split m n) /2 width=1 by or3_intro0/
 188 #H elim (yle_split_eq … H) -H /2 width=1 by or3_intro1, or3_intro2/
 189 qed-.
 190
 191 lemma ylt_yle_trans: ∀x:ynat. ∀y:ynat. ∀z:ynat. y ≤ z → x < y → x < z.
 192 #x #y #z * -y -z
 193 [ #y #z #Hyz #H elim (ylt_inv_inj2 … H) -H
 194   #m #Hm #H destruct /3 width=3 by ylt_inj, lt_to_le_to_lt/
 195 | #y * //
 196 ]
 197 qed-.
 198
 199 lemma yle_ylt_trans: ∀x:ynat. ∀y:ynat. ∀z:ynat. y < z → x ≤ y → x < z.
 200 #x #y #z * -y -z
 201 [ #y #z #Hyz #H elim (yle_inv_inj2 … H) -H
 202   #m #Hm #H destruct /3 width=3 by ylt_inj, le_to_lt_to_lt/
 203 | #y #H elim (yle_inv_inj2 … H) -H //
 204 ]
 205 qed-.
 206
 207 lemma le_ylt_trans (x) (y) (z): x ≤ y → yinj y < z → yinj x < z.
 208 /3 width=3 by yle_ylt_trans, yle_inj/
 209 qed-.
 210
 211 lemma yle_inv_succ1_lt: ∀x,y:ynat. ↑x ≤ y → 0 < y ∧ x ≤ ↓y.
 212 #x #y #H elim (yle_inv_succ1 … H) -H /3 width=1 by ylt_O1, conj/
 213 qed-.
 214
 215 lemma yle_lt: ∀x,y. x < ∞ → ↑x ≤ y → x < y.
 216 #x * // #y #H elim (ylt_inv_Y2 … H) -H #n #H destruct
 217 /3 width=1 by ylt_inj, yle_inv_inj/
 218 qed-.
 219
 220 (* Main properties **********************************************************)
 221
 222 theorem ylt_trans: Transitive … ylt.
 223 #x #y * -x -y
 224 [ #x #y #Hxy * //
 225   #z #H lapply (ylt_inv_inj … H) -H
 226   /3 width=3 by transitive_lt, ylt_inj/ (**) (* full auto too slow *)
 227 | #x #z #H elim (ylt_yle_false … H) //
 228 ]
 229 qed-.
 230
 231 lemma lt_ylt_trans (x) (y) (z): x < y → yinj y < z → yinj x < z.
 232 /3 width=3 by ylt_trans, ylt_inj/
 233 qed-.
 234
 235 (* Elimination principles ***************************************************)
 236
 237 fact ynat_ind_lt_le_aux: ∀R:predicate ynat.
 238                          (∀y. (∀x. x < y → R x) → R y) →
 239                          ∀y:nat. ∀x. x ≤ y → R x.
 240 #R #IH #y elim y -y
 241 [ #x #H >(yle_inv_O2 … H) -x
 242   @IH -IH #x #H elim (ylt_yle_false … H) -H //
 243 | /5 width=3 by ylt_yle_trans, ylt_fwd_succ2/
 244 ]
 245 qed-.
 246
 247 fact ynat_ind_lt_aux: ∀R:predicate ynat.
 248                       (∀y. (∀x. x < y → R x) → R y) →
 249                       ∀y:nat. R y.
 250 /4 width=2 by ynat_ind_lt_le_aux/ qed-.
 251
 252 lemma ynat_ind_lt: ∀R:predicate ynat.
 253                    (∀y. (∀x. x < y → R x) → R y) →
 254                    ∀y. R y.
 255 #R #IH * /4 width=1 by ynat_ind_lt_aux/
 256 @IH #x #H elim (ylt_inv_Y2 … H) -H
 257 #n #H destruct /4 width=1 by ynat_ind_lt_aux/
 258 qed-.
 259
 260 fact ynat_f_ind_aux: ∀A. ∀f:A→ynat. ∀R:predicate A.
 261                      (∀x. (∀a. f a < x → R a) → ∀a. f a = x → R a) →
 262                      ∀x,a. f a = x → R a.
 263 #A #f #R #IH #x @(ynat_ind_lt … x) -x
 264 /3 width=3 by/
 265 qed-.
 266
 267 lemma ynat_f_ind: ∀A. ∀f:A→ynat. ∀R:predicate A.
 268                   (∀x. (∀a. f a < x → R a) → ∀a. f a = x → R a) → ∀a. R a.
 269 #A #f #R #IH #a
 270 @(ynat_f_ind_aux … IH) -IH [2: // | skip ]
 271 qed-.