matita/matita/contribs/lambdadelta/ground_2/lib/arith.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/notation/functions/uparrow_1.ma".
  16 include "ground_2/notation/functions/downarrow_1.ma".
  17 include "arithmetics/nat.ma".
  18 include "ground_2/lib/relations.ma".
  19
  20 (* ARITHMETICAL PROPERTIES **************************************************)
  21
  22 interpretation "nat successor" 'UpArrow m = (S m).
  23
  24 interpretation "nat predecessor" 'DownArrow m = (pred m).
  25
  26 interpretation "nat min" 'and x y = (min x y).
  27
  28 interpretation "nat max" 'or x y = (max x y).
  29
  30 (* Iota equations ***********************************************************)
  31
  32 lemma pred_O: pred 0 = 0.
  33 normalize // qed.
  34
  35 lemma pred_S: ∀m. pred (S m) = m.
  36 // qed.
  37
  38 lemma plus_S1: ∀x,y. ↑(x+y) = (↑x) + y.
  39 // qed.
  40
  41 lemma max_O1: ∀n. n = (0 ∨ n).
  42 // qed.
  43
  44 lemma max_O2: ∀n. n = (n ∨ 0).
  45 // qed.
  46
  47 lemma max_SS: ∀n1,n2. ↑(n1∨n2) = (↑n1 ∨ ↑n2).
  48 #n1 #n2 elim (decidable_le n1 n2) #H normalize
  49 [ >(le_to_leb_true … H) | >(not_le_to_leb_false … H) ] -H //
  50 qed.
  51
  52 (* Equalities ***************************************************************)
  53
  54 lemma plus_SO_sn (n): 1 + n = ↑n.
  55 // qed-.
  56
  57 lemma plus_SO_dx (n): n + 1 = ↑n.
  58 // qed.
  59
  60 lemma minus_plus_m_m_commutative: ∀n,m:nat. n = m + n - m.
  61 // qed-.
  62
  63 lemma plus_minus_m_m_commutative (n) (m): m ≤ n → n = m+(n-m).
  64 /2 width=1 by plus_minus_associative/ qed-.
  65
  66 lemma plus_to_minus_2: ∀m1,m2,n1,n2. n1 ≤ m1 → n2 ≤ m2 →
  67                        m1+n2 = m2+n1 → m1-n1 = m2-n2.
  68 #m1 #m2 #n1 #n2 #H1 #H2 #H
  69 @plus_to_minus >plus_minus_associative //
  70 qed-.
  71
  72 (* Note: uses minus_minus_comm, minus_plus_m_m, commutative_plus, plus_minus *)
  73 lemma plus_minus_minus_be: ∀x,y,z. y ≤ z → z ≤ x → (x - z) + (z - y) = x - y.
  74 #x #z #y #Hzy #Hyx >plus_minus // >commutative_plus >plus_minus //
  75 qed-.
  76
  77 lemma lt_succ_pred: ∀m,n. n < m → m = ↑↓m.
  78 #m #n #Hm >S_pred /2 width=2 by ltn_to_ltO/
  79 qed-.
  80
  81 fact plus_minus_minus_be_aux: ∀i,x,y,z. y ≤ z → z ≤ x → i = z - y → x - z + i = x - y.
  82 /2 width=1 by plus_minus_minus_be/ qed-.
  83
  84 lemma le_plus_minus: ∀m,n,p. p ≤ n → m + n - p = m + (n - p).
  85 /2 by plus_minus/ qed-.
  86
  87 lemma le_plus_minus_comm: ∀n,m,p. p ≤ m → m + n - p = m - p + n.
  88 /2 by plus_minus/ qed-.
  89
  90 lemma minus_minus_comm3: ∀n,x,y,z. n-x-y-z = n-y-z-x.
  91 // qed.
  92
  93 lemma idempotent_max: ∀n:nat. n = (n ∨ n).
  94 #n normalize >le_to_leb_true //
  95 qed.
  96
  97 lemma associative_max: associative … max.
  98 #x #y #z normalize
  99 @(leb_elim x y) normalize #Hxy
 100 @(leb_elim y z) normalize #Hyz //
 101 [1,2: >le_to_leb_true /2 width=3 by transitive_le/
 102 | >not_le_to_leb_false /4 width=3 by lt_to_not_le, not_le_to_lt, transitive_lt/
 103   >not_le_to_leb_false //
 104 ]
 105 qed.
 106
 107 (* Properties ***************************************************************)
 108
 109 lemma eq_nat_dec: ∀n1,n2:nat. Decidable (n1 = n2).
 110 #n1 elim n1 -n1 [| #n1 #IHn1 ] * [2,4: #n2 ]
 111 [1,4: @or_intror #H destruct
 112 | elim (IHn1 n2) -IHn1 /3 width=1 by or_intror, or_introl/
 113 | /2 width=1 by or_introl/
 114 ]
 115 qed-.
 116
 117 lemma lt_or_eq_or_gt: ∀m,n. ∨∨ m < n | n = m | n < m.
 118 #m #n elim (lt_or_ge m n) /2 width=1 by or3_intro0/
 119 #H elim H -m /2 width=1 by or3_intro1/
 120 #m #Hm * /3 width=1 by not_le_to_lt, le_S_S, or3_intro2/
 121 qed-.
 122
 123 lemma monotonic_le_minus_l2: ∀x1,x2,y,z. x1 ≤ x2 → x1 - y - z ≤ x2 - y - z.
 124 /3 width=1 by monotonic_le_minus_l/ qed.
 125
 126 lemma minus_le_trans_sn: ∀x1,x2. x1 ≤ x2 → ∀x. x1-x ≤ x2.
 127 /2 width=3 by transitive_le/ qed.
 128
 129 lemma le_plus_to_minus_l: ∀a,b,c. a + b ≤ c → b ≤ c-a.
 130 /2 width=1 by le_plus_to_minus_r/
 131 qed-.
 132
 133 lemma le_plus_to_minus_comm: ∀n,m,p. n ≤ p+m → n-p ≤ m.
 134 /2 width=1 by le_plus_to_minus/ qed-.
 135
 136 lemma le_inv_S1: ∀m,n. ↑m ≤ n → ∃∃p. m ≤ p & ↑p = n.
 137 #m *
 138 [ #H lapply (le_n_O_to_eq … H) -H
 139   #H destruct
 140 | /3 width=3 by monotonic_pred, ex2_intro/
 141 ]
 142 qed-.
 143
 144 (* Note: this might interfere with nat.ma *)
 145 lemma monotonic_lt_pred: ∀m,n. m < n → 0 < m → pred m < pred n.
 146 #m #n #Hmn #Hm whd >(S_pred … Hm)
 147 @le_S_S_to_le >S_pred /2 width=3 by transitive_lt/
 148 qed.
 149
 150 lemma lt_S_S: ∀x,y. x < y → ↑x < ↑y.
 151 /2 width=1 by le_S_S/ qed.
 152
 153 lemma lt_S: ∀n,m. n < m → n < ↑m.
 154 /2 width=1 by le_S/ qed.
 155
 156 lemma max_S1_le_S: ∀n1,n2,n. (n1 ∨ n2) ≤ n → (↑n1 ∨ n2) ≤ ↑n.
 157 /4 width=2 by to_max, le_maxr, le_S_S, le_S/ qed-.
 158
 159 lemma max_S2_le_S: ∀n1,n2,n. (n1 ∨ n2) ≤ n → (n1 ∨ ↑n2) ≤ ↑n.
 160 /2 width=1 by max_S1_le_S/ qed-.
 161
 162 (* Inversion & forward lemmas ***********************************************)
 163
 164 lemma lt_refl_false: ∀n. n < n → ⊥.
 165 #n #H elim (lt_to_not_eq … H) -H /2 width=1 by/
 166 qed-.
 167
 168 lemma lt_zero_false: ∀n. n < 0 → ⊥.
 169 #n #H elim (lt_to_not_le … H) -H /2 width=1 by/
 170 qed-.
 171
 172 lemma lt_le_false: ∀x,y. x < y → y ≤ x → ⊥.
 173 /3 width=4 by lt_refl_false, lt_to_le_to_lt/ qed-.
 174
 175 lemma le_dec (n) (m): Decidable (n≤m).
 176 #n elim n -n [ /2 width=1 by or_introl/ ]
 177 #n #IH * [ /3 width=2 by lt_zero_false, or_intror/ ]
 178 #m elim (IH m) -IH
 179 [ /3 width=1 by or_introl, le_S_S/
 180 | /4 width=1 by or_intror, le_S_S_to_le/
 181 ]
 182 qed-.
 183
 184 lemma succ_inv_refl_sn: ∀x. ↑x = x → ⊥.
 185 #x #H @(lt_le_false x (↑x)) //
 186 qed-.
 187
 188 lemma le_plus_xSy_O_false: ∀x,y. x + S y ≤ 0 → ⊥.
 189 #x #y #H lapply (le_n_O_to_eq … H) -H <plus_n_Sm #H destruct
 190 qed-.
 191
 192 lemma le_plus_xySz_x_false: ∀y,z,x. x + y + S z ≤ x → ⊥.
 193 #y #z #x elim x -x /3 width=1 by le_S_S_to_le/
 194 #H elim (le_plus_xSy_O_false … H)
 195 qed-.
 196
 197 lemma plus_xySz_x_false: ∀z,x,y. x + y + S z = x → ⊥.
 198 /2 width=4 by le_plus_xySz_x_false/ qed-.
 199
 200 lemma plus_xSy_x_false: ∀y,x. x + S y = x → ⊥.
 201 /2 width=4 by plus_xySz_x_false/ qed-.
 202
 203 lemma pred_inv_fix_sn: ∀x. ↓x = x → 0 = x.
 204 * // #x <pred_Sn #H
 205 elim (succ_inv_refl_sn x) //
 206 qed-.
 207
 208 lemma discr_plus_xy_y: ∀x,y. x + y = y → x = 0.
 209 // qed-.
 210
 211 lemma discr_plus_x_xy: ∀x,y. x = x + y → y = 0.
 212 /2 width=2 by le_plus_minus_comm/ qed-.
 213
 214 lemma plus2_inv_le_sn: ∀m1,m2,n1,n2. m1 + n1 = m2 + n2 → m1 ≤ m2 → n2 ≤ n1.
 215 #m1 #m2 #n1 #n2 #H #Hm
 216 lapply (monotonic_le_plus_l n1 … Hm) -Hm >H -H
 217 /2 width=2 by le_plus_to_le/
 218 qed-.
 219
 220 lemma lt_S_S_to_lt: ∀x,y. ↑x < ↑y → x < y.
 221 /2 width=1 by le_S_S_to_le/ qed-.
 222
 223 (* Note this should go in nat.ma *)
 224 lemma discr_x_minus_xy: ∀x,y. x = x - y → x = 0 ∨ y = 0.
 225 #x @(nat_ind_plus … x) -x /2 width=1 by or_introl/
 226 #x #_ #y @(nat_ind_plus … y) -y /2 width=1 by or_intror/
 227 #y #_ >minus_plus_plus_l
 228 #H lapply (discr_plus_xy_minus_xz … H) -H
 229 #H destruct
 230 qed-.
 231
 232 lemma lt_inv_O1: ∀n. 0 < n → ∃m. ↑m = n.
 233 * /2 width=2 by ex_intro/
 234 #H cases (lt_le_false … H) -H //
 235 qed-.
 236
 237 lemma lt_inv_S1: ∀m,n. ↑m < n → ∃∃p. m < p & ↑p = n.
 238 #m * /3 width=3 by lt_S_S_to_lt, ex2_intro/
 239 #H cases (lt_le_false … H) -H //
 240 qed-.
 241
 242 lemma lt_inv_gen: ∀y,x. x < y → ∃∃z. x ≤ z & ↑z = y.
 243 * /3 width=3 by le_S_S_to_le, ex2_intro/
 244 #x #H elim (lt_le_false … H) -H //
 245 qed-.
 246
 247 lemma plus_inv_O3: ∀x,y. x + y = 0 → x = 0 ∧ y = 0.
 248 /2 width=1 by plus_le_0/ qed-.
 249
 250 lemma plus_inv_S3_sn: ∀x1,x2,x3. x1+x2 = ↑x3 →
 251                       ∨∨ ∧∧ x1 = 0 & x2 = ↑x3
 252                        | ∃∃y1. x1 = ↑y1 & y1 + x2 = x3.
 253 * /3 width=1 by or_introl, conj/
 254 #x1 #x2 #x3 <plus_S1 #H destruct
 255 /3 width=3 by ex2_intro, or_intror/
 256 qed-.
 257
 258 lemma plus_inv_S3_dx: ∀x2,x1,x3. x1+x2 = ↑x3 →
 259                       ∨∨ ∧∧ x2 = 0 & x1 = ↑x3
 260                        | ∃∃y2. x2 = ↑y2 & x1 + y2 = x3.
 261 * /3 width=1 by or_introl, conj/
 262 #x2 #x1 #x3 <plus_n_Sm #H destruct
 263 /3 width=3 by ex2_intro, or_intror/
 264 qed-.
 265
 266 lemma max_inv_O3: ∀x,y. (x ∨ y) = 0 → 0 = x ∧ 0 = y.
 267 /4 width=2 by le_maxr, le_maxl, le_n_O_to_eq, conj/
 268 qed-.
 269
 270 lemma zero_eq_plus: ∀x,y. 0 = x + y → 0 = x ∧ 0 = y.
 271 * /2 width=1 by conj/ #x #y normalize #H destruct
 272 qed-.
 273
 274 lemma nat_split: ∀x. x = 0 ∨ ∃y. ↑y = x.
 275 * /3 width=2 by ex_intro, or_introl, or_intror/
 276 qed-.
 277
 278 lemma lt_elim: ∀R:relation nat.
 279                (∀n2. R O (↑n2)) →
 280                (∀n1,n2. R n1 n2 → R (↑n1) (↑n2)) →
 281                ∀n2,n1. n1 < n2 → R n1 n2.
 282 #R #IH1 #IH2 #n2 elim n2 -n2
 283 [ #n1 #H elim (lt_le_false … H) -H //
 284 | #n2 #IH * /4 width=1 by lt_S_S_to_lt/
 285 ]
 286 qed-.
 287
 288 lemma le_elim: ∀R:relation nat.
 289                (∀n2. R O (n2)) →
 290                (∀n1,n2. R n1 n2 → R (↑n1) (↑n2)) →
 291                ∀n1,n2. n1 ≤ n2 → R n1 n2.
 292 #R #IH1 #IH2 #n1 #n2 @(nat_elim2 … n1 n2) -n1 -n2
 293 /4 width=1 by monotonic_pred/ -IH1 -IH2
 294 #n1 #H elim (lt_le_false … H) -H //
 295 qed-.
 296
 297 (* Iterators ****************************************************************)
 298
 299 (* Note: see also: lib/arithemetics/bigops.ma *)
 300 rec definition iter (n:nat) (B:Type[0]) (op: B → B) (nil: B) ≝
 301   match n with
 302    [ O   ⇒ nil
 303    | S k ⇒ op (iter k B op nil)
 304    ].
 305
 306 interpretation "iterated function" 'exp op n = (iter n ? op).
 307
 308 lemma iter_O: ∀B:Type[0]. ∀f:B→B.∀b. f^0 b = b.
 309 // qed.
 310
 311 lemma iter_S: ∀B:Type[0]. ∀f:B→B.∀b,l. f^(S l) b = f (f^l b).
 312 // qed.
 313
 314 lemma iter_n_Sm: ∀B:Type[0]. ∀f:B→B. ∀b,l. f^l (f b) = f (f^l b).
 315 #B #f #b #l elim l -l normalize //
 316 qed.
 317
 318 lemma iter_plus: ∀B:Type[0]. ∀f:B→B. ∀b,l1,l2. f^(l1+l2) b = f^l1 (f^l2 b).
 319 #B #f #b #l1 elim l1 -l1 normalize //
 320 qed.
 321
 322 (* Trichotomy operator ******************************************************)
 323
 324 (* Note: this is "if eqb n1 n2 then a2 else if leb n1 n2 then a1 else a3" *)
 325 rec definition tri (A:Type[0]) n1 n2 a1 a2 a3 on n1 : A ≝
 326   match n1 with
 327   [ O    ⇒ match n2 with [ O ⇒ a2 | S n2 ⇒ a1 ]
 328   | S n1 ⇒ match n2 with [ O ⇒ a3 | S n2 ⇒ tri A n1 n2 a1 a2 a3 ]
 329   ].
 330
 331 lemma tri_lt: ∀A,a1,a2,a3,n2,n1. n1 < n2 → tri A n1 n2 a1 a2 a3 = a1.
 332 #A #a1 #a2 #a3 #n2 elim n2 -n2
 333 [ #n1 #H elim (lt_zero_false … H)
 334 | #n2 #IH #n1 elim n1 -n1 /3 width=1 by monotonic_lt_pred/
 335 ]
 336 qed.
 337
 338 lemma tri_eq: ∀A,a1,a2,a3,n. tri A n n a1 a2 a3 = a2.
 339 #A #a1 #a2 #a3 #n elim n -n normalize //
 340 qed.
 341
 342 lemma tri_gt: ∀A,a1,a2,a3,n1,n2. n2 < n1 → tri A n1 n2 a1 a2 a3 = a3.
 343 #A #a1 #a2 #a3 #n1 elim n1 -n1
 344 [ #n2 #H elim (lt_zero_false … H)
 345 | #n1 #IH #n2 elim n2 -n2 /3 width=1 by monotonic_lt_pred/
 346 ]
 347 qed.
 348
 349 (* Decidability of predicates ***********************************************)
 350
 351 lemma dec_lt (R:predicate nat):
 352       (∀n. Decidable … (R n)) →
 353       ∀n. Decidable … (∃∃m. m < n & R m).
 354 #R #HR #n elim n -n [| #n * ]
 355 [ @or_intror * /2 width=2 by lt_zero_false/
 356 | * /4 width=3 by lt_S, or_introl, ex2_intro/
 357 | #H0 elim (HR n) -HR
 358   [ /3 width=3 by or_introl, ex2_intro/
 359   | #Hn @or_intror * #m #Hmn #Hm
 360     elim (le_to_or_lt_eq … Hmn) -Hmn #H destruct [ -Hn | -H0 ]
 361     /4 width=3 by lt_S_S_to_lt, ex2_intro/
 362   ]
 363 ]
 364 qed-.
 365
 366 lemma dec_min (R:predicate nat):
 367       (∀n. Decidable … (R n)) → ∀n. R n →
 368       ∃∃m. m ≤ n & R m & (∀p. p < m → R p → ⊥).
 369 #R #HR #n
 370 @(nat_elim1 n) -n #n #IH #Hn
 371 elim (dec_lt … HR n) -HR [ -Hn | -IH ]
 372 [ * #p #Hpn #Hp
 373   elim (IH … Hpn Hp) -IH -Hp #m #Hmp #Hm #HNm
 374   @(ex3_intro … Hm HNm) -HNm
 375   /3 width=3 by lt_to_le, le_to_lt_to_lt/
 376 | /4 width=4 by ex3_intro, ex2_intro/
 377 ]
 378 qed-.