matita/matita/contribs/lambdadelta/ground_2/lib/arith.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/notation/functions/uparrow_1.ma".
  16 include "ground_2/notation/functions/downarrow_1.ma".
  17 include "arithmetics/nat.ma".
  18 include "ground_2/lib/relations.ma".
  19
  20 (* ARITHMETICAL PROPERTIES **************************************************)
  21
  22 interpretation "nat successor" 'UpArrow m = (S m).
  23
  24 interpretation "nat predecessor" 'DownArrow m = (pred m).
  25
  26 interpretation "nat min" 'and x y = (min x y).
  27
  28 interpretation "nat max" 'or x y = (max x y).
  29
  30 (* Iota equations ***********************************************************)
  31
  32 lemma pred_O: pred 0 = 0.
  33 normalize // qed.
  34
  35 lemma pred_S: ∀m. pred (S m) = m.
  36 // qed.
  37
  38 lemma plus_S1: ∀x,y. ↑(x+y) = (↑x) + y.
  39 // qed.
  40
  41 lemma max_O1: ∀n. n = (0 ∨ n).
  42 // qed.
  43
  44 lemma max_O2: ∀n. n = (n ∨ 0).
  45 // qed.
  46
  47 lemma max_SS: ∀n1,n2. ↑(n1∨n2) = (↑n1 ∨ ↑n2).
  48 #n1 #n2 elim (decidable_le n1 n2) #H normalize
  49 [ >(le_to_leb_true … H) | >(not_le_to_leb_false … H) ] -H //
  50 qed.
  51
  52 (* Equalities ***************************************************************)
  53
  54 lemma plus_SO: ∀n. n + 1 = ↑n.
  55 // qed.
  56
  57 lemma minus_plus_m_m_commutative: ∀n,m:nat. n = m + n - m.
  58 // qed-.
  59
  60 lemma plus_minus_m_m_commutative (n) (m): m ≤ n → n = m+(n-m).
  61 /2 width=1 by plus_minus_associative/ qed-.
  62
  63 lemma plus_to_minus_2: ∀m1,m2,n1,n2. n1 ≤ m1 → n2 ≤ m2 →
  64                        m1+n2 = m2+n1 → m1-n1 = m2-n2.
  65 #m1 #m2 #n1 #n2 #H1 #H2 #H
  66 @plus_to_minus >plus_minus_associative //
  67 qed-.
  68
  69 (* Note: uses minus_minus_comm, minus_plus_m_m, commutative_plus, plus_minus *)
  70 lemma plus_minus_minus_be: ∀x,y,z. y ≤ z → z ≤ x → (x - z) + (z - y) = x - y.
  71 #x #z #y #Hzy #Hyx >plus_minus // >commutative_plus >plus_minus //
  72 qed-.
  73
  74 lemma lt_succ_pred: ∀m,n. n < m → m = ↑↓m.
  75 #m #n #Hm >S_pred /2 width=2 by ltn_to_ltO/
  76 qed-.
  77
  78 fact plus_minus_minus_be_aux: ∀i,x,y,z. y ≤ z → z ≤ x → i = z - y → x - z + i = x - y.
  79 /2 width=1 by plus_minus_minus_be/ qed-.
  80
  81 lemma le_plus_minus: ∀m,n,p. p ≤ n → m + n - p = m + (n - p).
  82 /2 by plus_minus/ qed-.
  83
  84 lemma le_plus_minus_comm: ∀n,m,p. p ≤ m → m + n - p = m - p + n.
  85 /2 by plus_minus/ qed-.
  86
  87 lemma minus_minus_comm3: ∀n,x,y,z. n-x-y-z = n-y-z-x.
  88 // qed.
  89
  90 lemma idempotent_max: ∀n:nat. n = (n ∨ n).
  91 #n normalize >le_to_leb_true //
  92 qed.
  93
  94 lemma associative_max: associative … max.
  95 #x #y #z normalize
  96 @(leb_elim x y) normalize #Hxy
  97 @(leb_elim y z) normalize #Hyz //
  98 [1,2: >le_to_leb_true /2 width=3 by transitive_le/
  99 | >not_le_to_leb_false /4 width=3 by lt_to_not_le, not_le_to_lt, transitive_lt/
 100   >not_le_to_leb_false //
 101 ]
 102 qed.
 103
 104 (* Properties ***************************************************************)
 105
 106 lemma eq_nat_dec: ∀n1,n2:nat. Decidable (n1 = n2).
 107 #n1 elim n1 -n1 [| #n1 #IHn1 ] * [2,4: #n2 ]
 108 [1,4: @or_intror #H destruct
 109 | elim (IHn1 n2) -IHn1 /3 width=1 by or_intror, or_introl/
 110 | /2 width=1 by or_introl/
 111 ]
 112 qed-.
 113
 114 lemma lt_or_eq_or_gt: ∀m,n. ∨∨ m < n | n = m | n < m.
 115 #m #n elim (lt_or_ge m n) /2 width=1 by or3_intro0/
 116 #H elim H -m /2 width=1 by or3_intro1/
 117 #m #Hm * /3 width=1 by not_le_to_lt, le_S_S, or3_intro2/
 118 qed-.
 119
 120 lemma monotonic_le_minus_l2: ∀x1,x2,y,z. x1 ≤ x2 → x1 - y - z ≤ x2 - y - z.
 121 /3 width=1 by monotonic_le_minus_l/ qed.
 122
 123 lemma minus_le_trans_sn: ∀x1,x2. x1 ≤ x2 → ∀x. x1-x ≤ x2.
 124 /2 width=3 by transitive_le/ qed.
 125
 126 lemma le_plus_to_minus_l: ∀a,b,c. a + b ≤ c → b ≤ c-a.
 127 /2 width=1 by le_plus_to_minus_r/
 128 qed-.
 129
 130 lemma le_plus_to_minus_comm: ∀n,m,p. n ≤ p+m → n-p ≤ m.
 131 /2 width=1 by le_plus_to_minus/ qed-.
 132
 133 lemma le_inv_S1: ∀m,n. ↑m ≤ n → ∃∃p. m ≤ p & ↑p = n.
 134 #m *
 135 [ #H lapply (le_n_O_to_eq … H) -H
 136   #H destruct
 137 | /3 width=3 by monotonic_pred, ex2_intro/
 138 ]
 139 qed-.
 140
 141 (* Note: this might interfere with nat.ma *)
 142 lemma monotonic_lt_pred: ∀m,n. m < n → 0 < m → pred m < pred n.
 143 #m #n #Hmn #Hm whd >(S_pred … Hm)
 144 @le_S_S_to_le >S_pred /2 width=3 by transitive_lt/
 145 qed.
 146
 147 lemma lt_S_S: ∀x,y. x < y → ↑x < ↑y.
 148 /2 width=1 by le_S_S/ qed.
 149
 150 lemma lt_S: ∀n,m. n < m → n < ↑m.
 151 /2 width=1 by le_S/ qed.
 152
 153 lemma max_S1_le_S: ∀n1,n2,n. (n1 ∨ n2) ≤ n → (↑n1 ∨ n2) ≤ ↑n.
 154 /4 width=2 by to_max, le_maxr, le_S_S, le_S/ qed-.
 155
 156 lemma max_S2_le_S: ∀n1,n2,n. (n1 ∨ n2) ≤ n → (n1 ∨ ↑n2) ≤ ↑n.
 157 /2 width=1 by max_S1_le_S/ qed-.
 158
 159 (* Inversion & forward lemmas ***********************************************)
 160
 161 lemma lt_refl_false: ∀n. n < n → ⊥.
 162 #n #H elim (lt_to_not_eq … H) -H /2 width=1 by/
 163 qed-.
 164
 165 lemma lt_zero_false: ∀n. n < 0 → ⊥.
 166 #n #H elim (lt_to_not_le … H) -H /2 width=1 by/
 167 qed-.
 168
 169 lemma lt_le_false: ∀x,y. x < y → y ≤ x → ⊥.
 170 /3 width=4 by lt_refl_false, lt_to_le_to_lt/ qed-.
 171
 172 lemma le_dec (n) (m): Decidable (n≤m).
 173 #n elim n -n [ /2 width=1 by or_introl/ ]
 174 #n #IH * [ /3 width=2 by lt_zero_false, or_intror/ ]
 175 #m elim (IH m) -IH
 176 [ /3 width=1 by or_introl, le_S_S/
 177 | /4 width=1 by or_intror, le_S_S_to_le/
 178 ]
 179 qed-.
 180
 181 lemma succ_inv_refl_sn: ∀x. ↑x = x → ⊥.
 182 #x #H @(lt_le_false x (↑x)) //
 183 qed-.
 184
 185 lemma le_plus_xSy_O_false: ∀x,y. x + S y ≤ 0 → ⊥.
 186 #x #y #H lapply (le_n_O_to_eq … H) -H <plus_n_Sm #H destruct
 187 qed-.
 188
 189 lemma le_plus_xySz_x_false: ∀y,z,x. x + y + S z ≤ x → ⊥.
 190 #y #z #x elim x -x /3 width=1 by le_S_S_to_le/
 191 #H elim (le_plus_xSy_O_false … H)
 192 qed-.
 193
 194 lemma plus_xySz_x_false: ∀z,x,y. x + y + S z = x → ⊥.
 195 /2 width=4 by le_plus_xySz_x_false/ qed-.
 196
 197 lemma plus_xSy_x_false: ∀y,x. x + S y = x → ⊥.
 198 /2 width=4 by plus_xySz_x_false/ qed-.
 199
 200 lemma pred_inv_fix_sn: ∀x. ↓x = x → 0 = x.
 201 * // #x <pred_Sn #H
 202 elim (succ_inv_refl_sn x) //
 203 qed-.
 204
 205 lemma discr_plus_xy_y: ∀x,y. x + y = y → x = 0.
 206 // qed-.
 207
 208 lemma discr_plus_x_xy: ∀x,y. x = x + y → y = 0.
 209 /2 width=2 by le_plus_minus_comm/ qed-.
 210
 211 lemma plus2_inv_le_sn: ∀m1,m2,n1,n2. m1 + n1 = m2 + n2 → m1 ≤ m2 → n2 ≤ n1.
 212 #m1 #m2 #n1 #n2 #H #Hm
 213 lapply (monotonic_le_plus_l n1 … Hm) -Hm >H -H
 214 /2 width=2 by le_plus_to_le/
 215 qed-.
 216
 217 lemma lt_S_S_to_lt: ∀x,y. ↑x < ↑y → x < y.
 218 /2 width=1 by le_S_S_to_le/ qed-.
 219
 220 (* Note this should go in nat.ma *)
 221 lemma discr_x_minus_xy: ∀x,y. x = x - y → x = 0 ∨ y = 0.
 222 #x @(nat_ind_plus … x) -x /2 width=1 by or_introl/
 223 #x #_ #y @(nat_ind_plus … y) -y /2 width=1 by or_intror/
 224 #y #_ >minus_plus_plus_l
 225 #H lapply (discr_plus_xy_minus_xz … H) -H
 226 #H destruct
 227 qed-.
 228
 229 lemma lt_inv_O1: ∀n. 0 < n → ∃m. ↑m = n.
 230 * /2 width=2 by ex_intro/
 231 #H cases (lt_le_false … H) -H //
 232 qed-.
 233
 234 lemma lt_inv_S1: ∀m,n. ↑m < n → ∃∃p. m < p & ↑p = n.
 235 #m * /3 width=3 by lt_S_S_to_lt, ex2_intro/
 236 #H cases (lt_le_false … H) -H //
 237 qed-.
 238
 239 lemma lt_inv_gen: ∀y,x. x < y → ∃∃z. x ≤ z & ↑z = y.
 240 * /3 width=3 by le_S_S_to_le, ex2_intro/
 241 #x #H elim (lt_le_false … H) -H //
 242 qed-.
 243
 244 lemma plus_inv_O3: ∀x,y. x + y = 0 → x = 0 ∧ y = 0.
 245 /2 width=1 by plus_le_0/ qed-.
 246
 247 lemma plus_inv_S3_sn: ∀x1,x2,x3. x1+x2 = ↑x3 →
 248                       ∨∨ ∧∧ x1 = 0 & x2 = ↑x3
 249                        | ∃∃y1. x1 = ↑y1 & y1 + x2 = x3.
 250 * /3 width=1 by or_introl, conj/
 251 #x1 #x2 #x3 <plus_S1 #H destruct
 252 /3 width=3 by ex2_intro, or_intror/
 253 qed-.
 254
 255 lemma plus_inv_S3_dx: ∀x2,x1,x3. x1+x2 = ↑x3 →
 256                       ∨∨ ∧∧ x2 = 0 & x1 = ↑x3
 257                        | ∃∃y2. x2 = ↑y2 & x1 + y2 = x3.
 258 * /3 width=1 by or_introl, conj/
 259 #x2 #x1 #x3 <plus_n_Sm #H destruct
 260 /3 width=3 by ex2_intro, or_intror/
 261 qed-.
 262
 263 lemma max_inv_O3: ∀x,y. (x ∨ y) = 0 → 0 = x ∧ 0 = y.
 264 /4 width=2 by le_maxr, le_maxl, le_n_O_to_eq, conj/
 265 qed-.
 266
 267 lemma zero_eq_plus: ∀x,y. 0 = x + y → 0 = x ∧ 0 = y.
 268 * /2 width=1 by conj/ #x #y normalize #H destruct
 269 qed-.
 270
 271 lemma nat_split: ∀x. x = 0 ∨ ∃y. ↑y = x.
 272 * /3 width=2 by ex_intro, or_introl, or_intror/
 273 qed-.
 274
 275 lemma lt_elim: ∀R:relation nat.
 276                (∀n2. R O (↑n2)) →
 277                (∀n1,n2. R n1 n2 → R (↑n1) (↑n2)) →
 278                ∀n2,n1. n1 < n2 → R n1 n2.
 279 #R #IH1 #IH2 #n2 elim n2 -n2
 280 [ #n1 #H elim (lt_le_false … H) -H //
 281 | #n2 #IH * /4 width=1 by lt_S_S_to_lt/
 282 ]
 283 qed-.
 284
 285 lemma le_elim: ∀R:relation nat.
 286                (∀n2. R O (n2)) →
 287                (∀n1,n2. R n1 n2 → R (↑n1) (↑n2)) →
 288                ∀n1,n2. n1 ≤ n2 → R n1 n2.
 289 #R #IH1 #IH2 #n1 #n2 @(nat_elim2 … n1 n2) -n1 -n2
 290 /4 width=1 by monotonic_pred/ -IH1 -IH2
 291 #n1 #H elim (lt_le_false … H) -H //
 292 qed-.
 293
 294 (* Iterators ****************************************************************)
 295
 296 (* Note: see also: lib/arithemetics/bigops.ma *)
 297 rec definition iter (n:nat) (B:Type[0]) (op: B → B) (nil: B) ≝
 298   match n with
 299    [ O   ⇒ nil
 300    | S k ⇒ op (iter k B op nil)
 301    ].
 302
 303 interpretation "iterated function" 'exp op n = (iter n ? op).
 304
 305 lemma iter_O: ∀B:Type[0]. ∀f:B→B.∀b. f^0 b = b.
 306 // qed.
 307
 308 lemma iter_S: ∀B:Type[0]. ∀f:B→B.∀b,l. f^(S l) b = f (f^l b).
 309 // qed.
 310
 311 lemma iter_n_Sm: ∀B:Type[0]. ∀f:B→B. ∀b,l. f^l (f b) = f (f^l b).
 312 #B #f #b #l elim l -l normalize //
 313 qed.
 314
 315 lemma iter_plus: ∀B:Type[0]. ∀f:B→B. ∀b,l1,l2. f^(l1+l2) b = f^l1 (f^l2 b).
 316 #B #f #b #l1 elim l1 -l1 normalize //
 317 qed.
 318
 319 (* Trichotomy operator ******************************************************)
 320
 321 (* Note: this is "if eqb n1 n2 then a2 else if leb n1 n2 then a1 else a3" *)
 322 rec definition tri (A:Type[0]) n1 n2 a1 a2 a3 on n1 : A ≝
 323   match n1 with
 324   [ O    ⇒ match n2 with [ O ⇒ a2 | S n2 ⇒ a1 ]
 325   | S n1 ⇒ match n2 with [ O ⇒ a3 | S n2 ⇒ tri A n1 n2 a1 a2 a3 ]
 326   ].
 327
 328 lemma tri_lt: ∀A,a1,a2,a3,n2,n1. n1 < n2 → tri A n1 n2 a1 a2 a3 = a1.
 329 #A #a1 #a2 #a3 #n2 elim n2 -n2
 330 [ #n1 #H elim (lt_zero_false … H)
 331 | #n2 #IH #n1 elim n1 -n1 /3 width=1 by monotonic_lt_pred/
 332 ]
 333 qed.
 334
 335 lemma tri_eq: ∀A,a1,a2,a3,n. tri A n n a1 a2 a3 = a2.
 336 #A #a1 #a2 #a3 #n elim n -n normalize //
 337 qed.
 338
 339 lemma tri_gt: ∀A,a1,a2,a3,n1,n2. n2 < n1 → tri A n1 n2 a1 a2 a3 = a3.
 340 #A #a1 #a2 #a3 #n1 elim n1 -n1
 341 [ #n2 #H elim (lt_zero_false … H)
 342 | #n1 #IH #n2 elim n2 -n2 /3 width=1 by monotonic_lt_pred/
 343 ]
 344 qed.
 345
 346 (* Decidability of predicates ***********************************************)
 347
 348 lemma dec_lt (R:predicate nat):
 349       (∀n. Decidable … (R n)) →
 350       ∀n. Decidable … (∃∃m. m < n & R m).
 351 #R #HR #n elim n -n [| #n * ]
 352 [ @or_intror * /2 width=2 by lt_zero_false/
 353 | * /4 width=3 by lt_S, or_introl, ex2_intro/
 354 | #H0 elim (HR n) -HR
 355   [ /3 width=3 by or_introl, ex2_intro/
 356   | #Hn @or_intror * #m #Hmn #Hm
 357     elim (le_to_or_lt_eq … Hmn) -Hmn #H destruct [ -Hn | -H0 ]
 358     /4 width=3 by lt_S_S_to_lt, ex2_intro/
 359   ]
 360 ]
 361 qed-.
 362
 363 lemma dec_min (R:predicate nat):
 364       (∀n. Decidable … (R n)) → ∀n. R n →
 365       ∃∃m. m ≤ n & R m & (∀p. p < m → R p → ⊥).
 366 #R #HR #n
 367 @(nat_elim1 n) -n #n #IH #Hn
 368 elim (dec_lt … HR n) -HR [ -Hn | -IH ]
 369 [ * #p #Hpn #Hp
 370   elim (IH … Hpn Hp) -IH -Hp #m #Hmp #Hm #HNm
 371   @(ex3_intro … Hm HNm) -HNm
 372   /3 width=3 by lt_to_le, le_to_lt_to_lt/
 373 | /4 width=4 by ex3_intro, ex2_intro/
 374 ]
 375 qed-.