matita/matita/contribs/lambdadelta/ground_2/lib/arith.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "arithmetics/nat.ma".
  16 include "ground_2/xoa/ex_3_1.ma".
  17 include "ground_2/xoa/or_3.ma".
  18 include "ground_2/notation/functions/uparrow_1.ma".
  19 include "ground_2/notation/functions/downarrow_1.ma".
  20 include "ground_2/pull/pull_2.ma".
  21 include "ground_2/lib/relations.ma".
  22
  23 (* ARITHMETICAL PROPERTIES **************************************************)
  24
  25 interpretation "nat successor" 'UpArrow m = (S m).
  26
  27 interpretation "nat predecessor" 'DownArrow m = (pred m).
  28
  29 interpretation "nat min" 'and x y = (min x y).
  30
  31 interpretation "nat max" 'or x y = (max x y).
  32
  33 (* Iota equations ***********************************************************)
  34
  35 lemma pred_O: pred 0 = 0.
  36 normalize // qed.
  37
  38 lemma pred_S: ∀m. pred (S m) = m.
  39 // qed.
  40
  41 lemma plus_S1: ∀x,y. ↑(x+y) = (↑x) + y.
  42 // qed.
  43
  44 lemma max_O1: ∀n. n = (0 ∨ n).
  45 // qed.
  46
  47 lemma max_O2: ∀n. n = (n ∨ 0).
  48 // qed.
  49
  50 lemma max_SS: ∀n1,n2. ↑(n1∨n2) = (↑n1 ∨ ↑n2).
  51 #n1 #n2 elim (decidable_le n1 n2) #H normalize
  52 [ >(le_to_leb_true … H) | >(not_le_to_leb_false … H) ] -H //
  53 qed.
  54
  55 (* Equalities ***************************************************************)
  56
  57 lemma plus_SO_sn (n): 1 + n = ↑n.
  58 // qed-.
  59
  60 lemma plus_SO_dx (n): n + 1 = ↑n.
  61 // qed.
  62
  63 lemma minus_plus_m_m_commutative: ∀n,m:nat. n = m + n - m.
  64 // qed-.
  65
  66 lemma plus_minus_m_m_commutative (n) (m): m ≤ n → n = m+(n-m).
  67 /2 width=1 by plus_minus_associative/ qed-.
  68
  69 lemma plus_to_minus_2: ∀m1,m2,n1,n2. n1 ≤ m1 → n2 ≤ m2 →
  70                        m1+n2 = m2+n1 → m1-n1 = m2-n2.
  71 #m1 #m2 #n1 #n2 #H1 #H2 #H
  72 @plus_to_minus >plus_minus_associative //
  73 qed-.
  74
  75 (* Note: uses minus_minus_comm, minus_plus_m_m, commutative_plus, plus_minus *)
  76 lemma plus_minus_minus_be: ∀x,y,z. y ≤ z → z ≤ x → (x - z) + (z - y) = x - y.
  77 #x #z #y #Hzy #Hyx >plus_minus // >commutative_plus >plus_minus //
  78 qed-.
  79
  80 lemma lt_succ_pred: ∀m,n. n < m → m = ↑↓m.
  81 #m #n #Hm >S_pred /2 width=2 by ltn_to_ltO/
  82 qed-.
  83
  84 fact plus_minus_minus_be_aux: ∀i,x,y,z. y ≤ z → z ≤ x → i = z - y → x - z + i = x - y.
  85 /2 width=1 by plus_minus_minus_be/ qed-.
  86
  87 lemma le_plus_minus: ∀m,n,p. p ≤ n → m + n - p = m + (n - p).
  88 /2 by plus_minus/ qed-.
  89
  90 lemma le_plus_minus_comm: ∀n,m,p. p ≤ m → m + n - p = m - p + n.
  91 /2 by plus_minus/ qed-.
  92
  93 lemma minus_minus_comm3: ∀n,x,y,z. n-x-y-z = n-y-z-x.
  94 // qed.
  95
  96 lemma idempotent_max: ∀n:nat. n = (n ∨ n).
  97 #n normalize >le_to_leb_true //
  98 qed.
  99
 100 lemma associative_max: associative … max.
 101 #x #y #z normalize
 102 @(leb_elim x y) normalize #Hxy
 103 @(leb_elim y z) normalize #Hyz //
 104 [1,2: >le_to_leb_true /2 width=3 by transitive_le/
 105 | >not_le_to_leb_false /4 width=3 by lt_to_not_le, not_le_to_lt, transitive_lt/
 106   >not_le_to_leb_false //
 107 ]
 108 qed.
 109
 110 (* Properties ***************************************************************)
 111
 112 lemma eq_nat_dec: ∀n1,n2:nat. Decidable (n1 = n2).
 113 #n1 elim n1 -n1 [| #n1 #IHn1 ] * [2,4: #n2 ]
 114 [1,4: @or_intror #H destruct
 115 | elim (IHn1 n2) -IHn1 /3 width=1 by or_intror, or_introl/
 116 | /2 width=1 by or_introl/
 117 ]
 118 qed-.
 119
 120 lemma lt_or_eq_or_gt: ∀m,n. ∨∨ m < n | n = m | n < m.
 121 #m #n elim (lt_or_ge m n) /2 width=1 by or3_intro0/
 122 #H elim H -m /2 width=1 by or3_intro1/
 123 #m #Hm * /3 width=1 by not_le_to_lt, le_S_S, or3_intro2/
 124 qed-.
 125
 126 lemma monotonic_le_minus_l2: ∀x1,x2,y,z. x1 ≤ x2 → x1 - y - z ≤ x2 - y - z.
 127 /3 width=1 by monotonic_le_minus_l/ qed.
 128
 129 lemma minus_le_trans_sn: ∀x1,x2. x1 ≤ x2 → ∀x. x1-x ≤ x2.
 130 /2 width=3 by transitive_le/ qed.
 131
 132 lemma le_plus_to_minus_l: ∀a,b,c. a + b ≤ c → b ≤ c-a.
 133 /2 width=1 by le_plus_to_minus_r/
 134 qed-.
 135
 136 lemma le_plus_to_minus_comm: ∀n,m,p. n ≤ p+m → n-p ≤ m.
 137 /2 width=1 by le_plus_to_minus/ qed-.
 138
 139 lemma le_inv_S1: ∀m,n. ↑m ≤ n → ∃∃p. m ≤ p & ↑p = n.
 140 #m *
 141 [ #H lapply (le_n_O_to_eq … H) -H
 142   #H destruct
 143 | /3 width=3 by monotonic_pred, ex2_intro/
 144 ]
 145 qed-.
 146
 147 (* Note: this might interfere with nat.ma *)
 148 lemma monotonic_lt_pred: ∀m,n. m < n → 0 < m → pred m < pred n.
 149 #m #n #Hmn #Hm whd >(S_pred … Hm)
 150 @le_S_S_to_le >S_pred /2 width=3 by transitive_lt/
 151 qed.
 152
 153 lemma lt_S_S: ∀x,y. x < y → ↑x < ↑y.
 154 /2 width=1 by le_S_S/ qed.
 155
 156 lemma lt_S: ∀n,m. n < m → n < ↑m.
 157 /2 width=1 by le_S/ qed.
 158
 159 lemma monotonic_lt_minus_r:
 160 ∀p,q,n. q < n -> q < p → n-p < n-q.
 161 #p #q #n #Hn #H
 162 lapply (monotonic_le_minus_r … n H) -H #H
 163 @(le_to_lt_to_lt … H) -H
 164 /2 width=1 by lt_plus_to_minus/
 165 qed.
 166
 167 lemma max_S1_le_S: ∀n1,n2,n. (n1 ∨ n2) ≤ n → (↑n1 ∨ n2) ≤ ↑n.
 168 /4 width=2 by to_max, le_maxr, le_S_S, le_S/ qed-.
 169
 170 lemma max_S2_le_S: ∀n1,n2,n. (n1 ∨ n2) ≤ n → (n1 ∨ ↑n2) ≤ ↑n.
 171 /2 width=1 by max_S1_le_S/ qed-.
 172
 173 (* Inversion & forward lemmas ***********************************************)
 174
 175 lemma lt_refl_false: ∀n. n < n → ⊥.
 176 #n #H elim (lt_to_not_eq … H) -H /2 width=1 by/
 177 qed-.
 178
 179 lemma lt_zero_false: ∀n. n < 0 → ⊥.
 180 #n #H elim (lt_to_not_le … H) -H /2 width=1 by/
 181 qed-.
 182
 183 lemma lt_le_false: ∀x,y. x < y → y ≤ x → ⊥.
 184 /3 width=4 by lt_refl_false, lt_to_le_to_lt/ qed-.
 185
 186 lemma le_dec (n) (m): Decidable (n≤m).
 187 #n elim n -n [ /2 width=1 by or_introl/ ]
 188 #n #IH * [ /3 width=2 by lt_zero_false, or_intror/ ]
 189 #m elim (IH m) -IH
 190 [ /3 width=1 by or_introl, le_S_S/
 191 | /4 width=1 by or_intror, le_S_S_to_le/
 192 ]
 193 qed-.
 194
 195 lemma succ_inv_refl_sn: ∀x. ↑x = x → ⊥.
 196 #x #H @(lt_le_false x (↑x)) //
 197 qed-.
 198
 199 lemma le_plus_xSy_O_false: ∀x,y. x + S y ≤ 0 → ⊥.
 200 #x #y #H lapply (le_n_O_to_eq … H) -H <plus_n_Sm #H destruct
 201 qed-.
 202
 203 lemma le_plus_xySz_x_false: ∀y,z,x. x + y + S z ≤ x → ⊥.
 204 #y #z #x elim x -x /3 width=1 by le_S_S_to_le/
 205 #H elim (le_plus_xSy_O_false … H)
 206 qed-.
 207
 208 lemma plus_xySz_x_false: ∀z,x,y. x + y + S z = x → ⊥.
 209 /2 width=4 by le_plus_xySz_x_false/ qed-.
 210
 211 lemma plus_xSy_x_false: ∀y,x. x + S y = x → ⊥.
 212 /2 width=4 by plus_xySz_x_false/ qed-.
 213
 214 lemma pred_inv_fix_sn: ∀x. ↓x = x → 0 = x.
 215 * // #x <pred_Sn #H
 216 elim (succ_inv_refl_sn x) //
 217 qed-.
 218
 219 lemma discr_plus_xy_y: ∀x,y. x + y = y → x = 0.
 220 // qed-.
 221
 222 lemma discr_plus_x_xy: ∀x,y. x = x + y → y = 0.
 223 /2 width=2 by le_plus_minus_comm/ qed-.
 224
 225 lemma plus2_inv_le_sn: ∀m1,m2,n1,n2. m1 + n1 = m2 + n2 → m1 ≤ m2 → n2 ≤ n1.
 226 #m1 #m2 #n1 #n2 #H #Hm
 227 lapply (monotonic_le_plus_l n1 … Hm) -Hm >H -H
 228 /2 width=2 by le_plus_to_le/
 229 qed-.
 230
 231 lemma lt_S_S_to_lt: ∀x,y. ↑x < ↑y → x < y.
 232 /2 width=1 by le_S_S_to_le/ qed-.
 233
 234 (* Note this should go in nat.ma *)
 235 lemma discr_x_minus_xy: ∀x,y. x = x - y → x = 0 ∨ y = 0.
 236 #x @(nat_ind_plus … x) -x /2 width=1 by or_introl/
 237 #x #_ #y @(nat_ind_plus … y) -y /2 width=1 by or_intror/
 238 #y #_ >minus_plus_plus_l
 239 #H lapply (discr_plus_xy_minus_xz … H) -H
 240 #H destruct
 241 qed-.
 242
 243 lemma lt_inv_O1: ∀n. 0 < n → ∃m. ↑m = n.
 244 * /2 width=2 by ex_intro/
 245 #H cases (lt_le_false … H) -H //
 246 qed-.
 247
 248 lemma lt_inv_S1: ∀m,n. ↑m < n → ∃∃p. m < p & ↑p = n.
 249 #m * /3 width=3 by lt_S_S_to_lt, ex2_intro/
 250 #H cases (lt_le_false … H) -H //
 251 qed-.
 252
 253 lemma lt_inv_gen: ∀y,x. x < y → ∃∃z. x ≤ z & ↑z = y.
 254 * /3 width=3 by le_S_S_to_le, ex2_intro/
 255 #x #H elim (lt_le_false … H) -H //
 256 qed-.
 257
 258 lemma plus_inv_O3: ∀x,y. x + y = 0 → x = 0 ∧ y = 0.
 259 /2 width=1 by plus_le_0/ qed-.
 260
 261 lemma plus_inv_S3_sn: ∀x1,x2,x3. x1+x2 = ↑x3 →
 262                       ∨∨ ∧∧ x1 = 0 & x2 = ↑x3
 263                        | ∃∃y1. x1 = ↑y1 & y1 + x2 = x3.
 264 * /3 width=1 by or_introl, conj/
 265 #x1 #x2 #x3 <plus_S1 #H destruct
 266 /3 width=3 by ex2_intro, or_intror/
 267 qed-.
 268
 269 lemma plus_inv_S3_dx: ∀x2,x1,x3. x1+x2 = ↑x3 →
 270                       ∨∨ ∧∧ x2 = 0 & x1 = ↑x3
 271                        | ∃∃y2. x2 = ↑y2 & x1 + y2 = x3.
 272 * /3 width=1 by or_introl, conj/
 273 #x2 #x1 #x3 <plus_n_Sm #H destruct
 274 /3 width=3 by ex2_intro, or_intror/
 275 qed-.
 276
 277 lemma max_inv_O3: ∀x,y. (x ∨ y) = 0 → 0 = x ∧ 0 = y.
 278 /4 width=2 by le_maxr, le_maxl, le_n_O_to_eq, conj/
 279 qed-.
 280
 281 lemma zero_eq_plus: ∀x,y. 0 = x + y → 0 = x ∧ 0 = y.
 282 * /2 width=1 by conj/ #x #y normalize #H destruct
 283 qed-.
 284
 285 lemma nat_split: ∀x. x = 0 ∨ ∃y. ↑y = x.
 286 * /3 width=2 by ex_intro, or_introl, or_intror/
 287 qed-.
 288
 289 lemma lt_elim: ∀R:relation nat.
 290                (∀n2. R O (↑n2)) →
 291                (∀n1,n2. R n1 n2 → R (↑n1) (↑n2)) →
 292                ∀n2,n1. n1 < n2 → R n1 n2.
 293 #R #IH1 #IH2 #n2 elim n2 -n2
 294 [ #n1 #H elim (lt_le_false … H) -H //
 295 | #n2 #IH * /4 width=1 by lt_S_S_to_lt/
 296 ]
 297 qed-.
 298
 299 lemma le_elim: ∀R:relation nat.
 300                (∀n2. R O (n2)) →
 301                (∀n1,n2. R n1 n2 → R (↑n1) (↑n2)) →
 302                ∀n1,n2. n1 ≤ n2 → R n1 n2.
 303 #R #IH1 #IH2 #n1 #n2 @(nat_elim2 … n1 n2) -n1 -n2
 304 /4 width=1 by monotonic_pred/ -IH1 -IH2
 305 #n1 #H elim (lt_le_false … H) -H //
 306 qed-.
 307
 308 lemma nat_elim_le_sn (Q:relation …):
 309       (∀m1,m2. (∀m. m < m2-m1 → Q (m2-m) m2) → m1 ≤ m2 → Q m1 m2) →
 310       ∀n1,n2. n1 ≤ n2 → Q n1 n2.
 311 #Q #IH #n1 #n2 #Hn
 312 <(minus_minus_m_m … Hn) -Hn
 313 lapply (minus_le n2 n1)
 314 let d ≝ (n2-n1)
 315 @(nat_elim1 … d) -d -n1 #d
 316 @pull_2 #Hd
 317 <(minus_minus_m_m … Hd) in ⊢ (%→?); -Hd
 318 let n1 ≝ (n2-d) #IHd
 319 @IH -IH [| // ] #m #Hn
 320 /4 width=3 by lt_to_le, lt_to_le_to_lt/
 321 qed-.
 322
 323 (* Iterators ****************************************************************)
 324
 325 (* Note: see also: lib/arithemetics/bigops.ma *)
 326 rec definition iter (n:nat) (B:Type[0]) (op: B → B) (nil: B) ≝
 327   match n with
 328    [ O   ⇒ nil
 329    | S k ⇒ op (iter k B op nil)
 330    ].
 331
 332 interpretation "iterated function" 'exp op n = (iter n ? op).
 333
 334 lemma iter_O: ∀B:Type[0]. ∀f:B→B.∀b. f^0 b = b.
 335 // qed.
 336
 337 lemma iter_S: ∀B:Type[0]. ∀f:B→B.∀b,l. f^(S l) b = f (f^l b).
 338 // qed.
 339
 340 lemma iter_n_Sm: ∀B:Type[0]. ∀f:B→B. ∀b,l. f^l (f b) = f (f^l b).
 341 #B #f #b #l elim l -l normalize //
 342 qed.
 343
 344 lemma iter_plus: ∀B:Type[0]. ∀f:B→B. ∀b,l1,l2. f^(l1+l2) b = f^l1 (f^l2 b).
 345 #B #f #b #l1 elim l1 -l1 normalize //
 346 qed.
 347
 348 (* Trichotomy operator ******************************************************)
 349
 350 (* Note: this is "if eqb n1 n2 then a2 else if leb n1 n2 then a1 else a3" *)
 351 rec definition tri (A:Type[0]) n1 n2 a1 a2 a3 on n1 : A ≝
 352   match n1 with
 353   [ O    ⇒ match n2 with [ O ⇒ a2 | S n2 ⇒ a1 ]
 354   | S n1 ⇒ match n2 with [ O ⇒ a3 | S n2 ⇒ tri A n1 n2 a1 a2 a3 ]
 355   ].
 356
 357 lemma tri_lt: ∀A,a1,a2,a3,n2,n1. n1 < n2 → tri A n1 n2 a1 a2 a3 = a1.
 358 #A #a1 #a2 #a3 #n2 elim n2 -n2
 359 [ #n1 #H elim (lt_zero_false … H)
 360 | #n2 #IH #n1 elim n1 -n1 /3 width=1 by monotonic_lt_pred/
 361 ]
 362 qed.
 363
 364 lemma tri_eq: ∀A,a1,a2,a3,n. tri A n n a1 a2 a3 = a2.
 365 #A #a1 #a2 #a3 #n elim n -n normalize //
 366 qed.
 367
 368 lemma tri_gt: ∀A,a1,a2,a3,n1,n2. n2 < n1 → tri A n1 n2 a1 a2 a3 = a3.
 369 #A #a1 #a2 #a3 #n1 elim n1 -n1
 370 [ #n2 #H elim (lt_zero_false … H)
 371 | #n1 #IH #n2 elim n2 -n2 /3 width=1 by monotonic_lt_pred/
 372 ]
 373 qed.
 374
 375 (* Decidability of predicates ***********************************************)
 376
 377 lemma dec_lt (R:predicate nat):
 378       (∀n. Decidable … (R n)) →
 379       ∀n. Decidable … (∃∃m. m < n & R m).
 380 #R #HR #n elim n -n [| #n * ]
 381 [ @or_intror * /2 width=2 by lt_zero_false/
 382 | * /4 width=3 by lt_S, or_introl, ex2_intro/
 383 | #H0 elim (HR n) -HR
 384   [ /3 width=3 by or_introl, ex2_intro/
 385   | #Hn @or_intror * #m #Hmn #Hm
 386     elim (le_to_or_lt_eq … Hmn) -Hmn #H destruct [ -Hn | -H0 ]
 387     /4 width=3 by lt_S_S_to_lt, ex2_intro/
 388   ]
 389 ]
 390 qed-.
 391
 392 lemma dec_min (R:predicate nat):
 393       (∀n. Decidable … (R n)) → ∀n. R n →
 394       ∃∃m. m ≤ n & R m & (∀p. p < m → R p → ⊥).
 395 #R #HR #n
 396 @(nat_elim1 n) -n #n #IH #Hn
 397 elim (dec_lt … HR n) -HR [ -Hn | -IH ]
 398 [ * #p #Hpn #Hp
 399   elim (IH … Hpn Hp) -IH -Hp #m #Hmp #Hm #HNm
 400   @(ex3_intro … Hm HNm) -HNm
 401   /3 width=3 by lt_to_le, le_to_lt_to_lt/
 402 | /4 width=4 by ex3_intro, ex2_intro/
 403 ]
 404 qed-.